Avalanche treasury migration

src/AaveAvalancheTreasuryMigration_20230903/AaveAvalancheTreasuryMigration_20230903.sol

@@ -0,0 +1,81 @@
+// SPDX-License-Identifier: MIT
+
+/*
+   _      ΞΞΞΞ      _
+  /_;-.__ / _\  _.-;_\
+     `-._`'`_/'`.-'
+         `\   /`
+          |  /
+         /-.(
+         \_._\
+          \ \`;
+           > |/
+          / //
+          |//
+          \(\
+           ``
+     defijesus.eth
+*/
+
+pragma solidity ^0.8.0;
+
+import {IProposalGenericExecutor} from 'aave-helpers/interfaces/IProposalGenericExecutor.sol';
+import {AaveV2Avalanche, AaveV2AvalancheAssets} from 'aave-address-book/AaveV2Avalanche.sol';
+import {AaveV3Avalanche, AaveV3AvalancheAssets} from 'aave-address-book/AaveV3Avalanche.sol';
+import {IERC20} from 'solidity-utils/contracts/oz-common/interfaces/IERC20.sol';
+import {SafeERC20} from 'solidity-utils/contracts/oz-common/SafeERC20.sol';
+import {IMigrationHelper} from 'aave-address-book/common/IMigrationHelper.sol';
+
+/**
+ * @dev Redeem aTokens from Aave v2 Avalanche and deposit the underlying assets into Aave v3 Avalanche. 
+ * @author defijesus.eth - TokenLogic
+ * - Snapshot: https://snapshot.org/#/aave.eth/proposal/0x1b816c12b6f547a1982198ffd0e36412390b05828b560c9edee4e8a6903c4882
+ * - Discussion: https://governance.aave.com/t/arfc-migrate-consolidate-polygon-treasury/12248
+ */
+contract AaveAvalancheTreasuryMigration_20230903 is IProposalGenericExecutor {
+
+  function execute() external {
+    IMigrationHelper MIGRATION_HELPER = IMigrationHelper(AaveV2Avalanche.MIGRATION_HELPER);
+
+    address[] memory ASSETS_TO_MIGRATE = new address[](4);
+    ASSETS_TO_MIGRATE[0] = AaveV2AvalancheAssets.DAIe_UNDERLYING;
+    ASSETS_TO_MIGRATE[1] = AaveV2AvalancheAssets.WBTCe_UNDERLYING;
+    ASSETS_TO_MIGRATE[2] = AaveV2AvalancheAssets.WETHe_UNDERLYING;
+    ASSETS_TO_MIGRATE[3] = AaveV2AvalancheAssets.WAVAX_UNDERLYING;
+
+    IMigrationHelper.RepaySimpleInput[] memory POSITIONS_TO_REPAY = new IMigrationHelper.RepaySimpleInput[](0);
+    IMigrationHelper.PermitInput[] memory PERMITS = new IMigrationHelper.PermitInput[](0);
+    IMigrationHelper.CreditDelegationInput[] memory CREDIT_DELEGATION_PERMITS = new IMigrationHelper.CreditDelegationInput[](0);
+
+    uint256 i = 0;
+
+    for(;i < ASSETS_TO_MIGRATE.length;) {
+        address aToken = MIGRATION_HELPER.aTokens(ASSETS_TO_MIGRATE[i]);
+        uint256 amount = IERC20(aToken).balanceOf(address(AaveV2Avalanche.COLLECTOR));
+        AaveV2Avalanche.COLLECTOR.transfer(aToken, address(this), amount);
+        SafeERC20.forceApprove(IERC20(aToken), AaveV2Avalanche.MIGRATION_HELPER, amount);
+        unchecked {
+            i++;
+        }
+    }
+
+    MIGRATION_HELPER.migrate(ASSETS_TO_MIGRATE, POSITIONS_TO_REPAY, PERMITS, CREDIT_DELEGATION_PERMITS);
+
+    address[] memory NEW_ASSETS_MIGRATED = new address[](4);
+    NEW_ASSETS_MIGRATED[0] = AaveV3AvalancheAssets.DAIe_A_TOKEN;
+    NEW_ASSETS_MIGRATED[1] = AaveV3AvalancheAssets.WBTCe_A_TOKEN;
+    NEW_ASSETS_MIGRATED[2] = AaveV3AvalancheAssets.WETHe_A_TOKEN;
+    NEW_ASSETS_MIGRATED[3] = AaveV3AvalancheAssets.WAVAX_A_TOKEN;
+
+    for(i = 0; i < NEW_ASSETS_MIGRATED.length;) {
+        SafeERC20.safeTransfer(
+            IERC20(NEW_ASSETS_MIGRATED[i]), 
+            address(AaveV3Avalanche.COLLECTOR), 
+            IERC20(NEW_ASSETS_MIGRATED[i]).balanceOf(address(this))
+        );
+        unchecked {
+            i++;
+        }
+    }
+  }
+}

src/AaveAvalancheTreasuryMigration_20230903/AaveAvalancheTreasuryMigration_20230903.t.sol

@@ -0,0 +1,60 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import 'forge-std/Test.sol';
+
+import {GovHelpers} from 'aave-helpers/GovHelpers.sol';
+import {AaveGovernanceV2} from 'aave-address-book/AaveGovernanceV2.sol';
+import {AaveV2Avalanche, AaveV2AvalancheAssets} from 'aave-address-book/AaveV2Avalanche.sol';
+import {AaveV3Avalanche, AaveV3AvalancheAssets} from 'aave-address-book/AaveV3Avalanche.sol';
+import {IERC20} from 'solidity-utils/contracts/oz-common/interfaces/IERC20.sol';
+import {AaveAvalancheTreasuryMigration_20230903} from './AaveAvalancheTreasuryMigration_20230903.sol';
+
+contract AaveAvalancheTreasuryMigration_20230903_Test is Test {
+  function setUp() public {
+    vm.createSelectFork(vm.rpcUrl('avalanche'), 35447142);
+  }
+
+  function testPayload() public {
+    address[] memory OLD_ASSETS_MIGRATED = new address[](4);
+    OLD_ASSETS_MIGRATED[0] = AaveV2AvalancheAssets.DAIe_A_TOKEN;
+    OLD_ASSETS_MIGRATED[1] = AaveV2AvalancheAssets.WBTCe_A_TOKEN;
+    OLD_ASSETS_MIGRATED[2] = AaveV2AvalancheAssets.WETHe_A_TOKEN;
+    OLD_ASSETS_MIGRATED[3] = AaveV2AvalancheAssets.WAVAX_A_TOKEN;
+
+    address[] memory NEW_ASSETS_MIGRATED = new address[](4);
+    NEW_ASSETS_MIGRATED[0] = AaveV3AvalancheAssets.DAIe_A_TOKEN;
+    NEW_ASSETS_MIGRATED[1] = AaveV3AvalancheAssets.WBTCe_A_TOKEN;
+    NEW_ASSETS_MIGRATED[2] = AaveV3AvalancheAssets.WETHe_A_TOKEN;
+    NEW_ASSETS_MIGRATED[3] = AaveV3AvalancheAssets.WAVAX_A_TOKEN;
+
+    uint256[] memory NEW_ASSETS_BEFORE_BALANCE = new uint256[](4);
+    uint256[] memory OLD_ASSETS_BEFORE_BALANCE = new uint256[](4);
+
+    uint256 i = 0;
+    uint256 payloadBalanceAfter;
+    uint256 collectorBalanceAfter;
+
+    for(; i < NEW_ASSETS_MIGRATED.length; i++) {
+      NEW_ASSETS_BEFORE_BALANCE[i] = IERC20(NEW_ASSETS_MIGRATED[i]).balanceOf(address(AaveV3Avalanche.COLLECTOR));
+      OLD_ASSETS_BEFORE_BALANCE[i] = IERC20(OLD_ASSETS_MIGRATED[i]).balanceOf(address(AaveV2Avalanche.COLLECTOR));
+    }
+
+    AaveAvalancheTreasuryMigration_20230903 payload = new AaveAvalancheTreasuryMigration_20230903();
+
+    GovHelpers.executePayload(vm, address(payload), AaveV3Avalanche.ACL_ADMIN);
+
+    for(i = 0; i < OLD_ASSETS_MIGRATED.length; i++) {
+      payloadBalanceAfter = IERC20(OLD_ASSETS_MIGRATED[i]).balanceOf(address(payload));
+      assertEq(payloadBalanceAfter, 0);
+      payloadBalanceAfter = IERC20(NEW_ASSETS_MIGRATED[i]).balanceOf(address(payload));
+      assertEq(payloadBalanceAfter, 0);
+    }
+
+    for(i = 0; i < NEW_ASSETS_MIGRATED.length; i++) {
+      collectorBalanceAfter = IERC20(NEW_ASSETS_MIGRATED[i]).balanceOf(address(AaveV3Avalanche.COLLECTOR));
+      /// 0.001e18 is 0.1%
+      assertApproxEqRel(NEW_ASSETS_BEFORE_BALANCE[i] + OLD_ASSETS_BEFORE_BALANCE[i], collectorBalanceAfter, 0.001e18);
+    }
+  }
+}

src/AaveAvalancheTreasuryMigration_20230903/DeployTreasuryMigration.s.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.16;
+import {AvalancheScript, EthereumScript} from 'aave-helpers/ScriptUtils.sol';
+import {GovHelpers} from 'aave-helpers/GovHelpers.sol';
+import {AaveAvalancheTreasuryMigration_20230903} from './AaveAvalancheTreasuryMigration_20230903.sol';
+
+/**
+ * @dev Deploy AaveAvalancheTreasuryMigration_20230903
+ * command: make deploy-ledger contract=src/AaveAvalancheTreasuryMigration_20230903/DeployTreasuryMigration.s.sol:DeployAvalancheV2TreasuryMigrationPayload chain=avalanche
+ */
+contract DeployAvalancheV2TreasuryMigrationPayload is AvalancheScript {
+  function run() external broadcast {
+    new AaveAvalancheTreasuryMigration_20230903();
+  }
+}

src/AaveAvalancheTreasuryMigration_20230903/MIGRATE_AVALANCHE_V2_TREASURY_TO_AVALANCHE_V3.md

@@ -0,0 +1,54 @@
+---
+title: Treasury Management - Avalanche v2 to v3 Migration
+discussions: https://governance.aave.com/t/arfc-treasury-management-avalanche-v2-to-v3-migration/14469
+author: TokenLogic
+---
+
+# Summary
+
+Redeem the Aave DAO funds on Aave v2 Avalanche and deposit underlying assets in Aave v3 Avalanche.
+
+# Motivation
+
+Aave DAO currently holds around $4.52M on Avalanche v2. There are several drivers for migrating Aave DAO's funds:
+
+* Higher deposit rates
+* wAVAX incentives
+* Encourage migration v2 to v3
+
+Most of these funds can be migrated to v3 with the exception of USDT. There is not enough liquidity to redeem the entire 541.51K of USDT. As a result, approximately 25% of the USDT will be redeemed and deposited into v3.
+
+# Specification
+
+Migrate the following holdings:
+
+| Asset | Migrate (%) |
+| --- | --- |
+|wBTC.e|100|
+|wETH.e|100|
+|DAI.e|100|
+|AVAX.e|100|
+
+Deposit wAVAX held passively in the Treasury into Aave v3.
+
+For reference, the Aave Avalanche v2 Treasury: [`0x5ba7fd868c40c16f7aDfAe6CF87121E13FC2F7a0`](https://snowtrace.io/address/0x5ba7fd868c40c16f7aDfAe6CF87121E13FC2F7a0)
+
+# Implementation
+
+A list of relevant links like for this proposal:
+
+* [Governance Forum Discussion](https://governance.aave.com/t/arfc-treasury-management-avalanche-v2-to-v3-migration/14469)
+* [Snapshot vote](https://snapshot.org/#/aave.eth/proposal/0x0be8229173181fe0aaf5ed1883e53752546efb810e55610e7ac8b991155ab788)
+* [Test Cases](https://github.com/bgd-labs/aave-proposals/tree/main/src/AaveAvalancheTreasuryMigration_20230903/AaveAvalancheTreasuryMigration_20230903.t.sol)
+* [Payload Implementation](https://github.com/bgd-labs/aave-proposals/tree/main/src/AaveAvalancheTreasuryMigration_20230903/AaveAvalancheTreasuryMigration_20230903.sol)
+* [Deployed Contracts](TODO)
+
+The proposal Payload was reviewed by [Bored Ghost Developing](https://bgdlabs.com/).
+
+# Disclaimer
+
+TokenLogic receives no payment from Aave DAO or any external source for the creation of this proposal. TokenLogic is a delegate within the Aave ecosystem.
+
+# Copyright
+
+Copyright and related rights waived via [CC0](https://creativecommons.org/publicdomain/zero/1.0/).