Missileguidance - Add MCLOS seeker type

addons/missileguidance/ACE_GuidanceConfig.hpp

@@ -80,6 +80,14 @@ class GVAR(SeekerTypes) {
         functionName = QFUNC(seekerType_SACLOS);
         onFired = QFUNC(SACLOS_onFired);
     };
+    class MCLOS {
+        name = "";
+        visualName = "";
+        description = "";
+
+        functionName = QFUNC(seekerType_MCLOS);
+        onFired = QFUNC(MCLOS_onFired);
+    };
     class MillimeterWaveRadar {
         name = "";
         visualName = "";

addons/missileguidance/XEH_PREP.hpp

@@ -20,6 +20,8 @@ PREP(handleHandoff);
 
 //re-enable after feature merge - PREP(shouldFilterRadarHit);
 
+PREP(MCLOS_buttonPressed);
+
 // Attack Profiles
 PREP(attackProfile_AIR);
 PREP(attackProfile_DIR);
@@ -46,6 +48,7 @@ PREP(navigationType_direct);
 PREP(seekerType_SALH);
 PREP(seekerType_Optic);
 PREP(seekerType_SACLOS);
+PREP(seekerType_MCLOS);
 //re-enable after feature merge - PREP(seekerType_Doppler);
 PREP(seekerType_MWR);
 
@@ -54,6 +57,7 @@ PREP(wire_onFired);
 
 // Seeker OnFired
 PREP(SACLOS_onFired);
+PREP(MCLOS_onFired);
 PREP(mwr_onFired);
 
 // Navigation OnFired

addons/missileguidance/XEH_postInit.sqf

@@ -1,11 +1,40 @@
 #include "script_component.hpp"
+#include "\a3\ui_f\hpp\defineDIKCodes.inc"
 
 [QGVAR(handoff), LINKFUNC(handleHandoff)] call CBA_fnc_addEventHandler;
 
-["ACE3 Weapons", QGVAR(cycleFireMode), localize LSTRING(CycleFireMode), {
-    [] call FUNC(cycleAttackProfileKeyDown);
-    false
+["ACE3 Weapons", QGVAR(cycleFireMode), LLSTRING(CycleFireMode), {
+    [] call FUNC(cycleAttackProfileKeyDown)
 }, {
-    false
 },
-[15, [false, true, false]], false] call CBA_fnc_addKeybind;  //Ctrl+Tab Key
+[DIK_TAB, [false, true, false]], false] call CBA_fnc_addKeybind;  //Ctrl+Tab Key
+
+
+// Each MCLOS argument is the vector which acceleration will be applied
+["ACE3 Weapons", QGVAR(mclosUp), LLSTRING(mclosUp), {
+    [[0, 0, 1], ACE_player] call FUNC(MCLOS_buttonPressed)
+}, {
+    [[0, 0, -1], ACE_player] call FUNC(MCLOS_buttonPressed)
+},
+[DIK_NUMPAD8, [false, false, false]], false, 0] call CBA_fnc_addKeybind;  // Numpad 8
+
+["ACE3 Weapons", QGVAR(mclosDown), LLSTRING(mclosDown), {
+    [[0, 0, -1], ACE_player] call FUNC(MCLOS_buttonPressed)
+}, {
+    [[0, 0, 1], ACE_player] call FUNC(MCLOS_buttonPressed)
+},
+[DIK_NUMPAD2, [false, false, false]], false, 0] call CBA_fnc_addKeybind;  // Numpad 2
+
+["ACE3 Weapons", QGVAR(mclosLeft), LLSTRING(mclosLeft), {
+    [[1, 0, 0], ACE_player] call FUNC(MCLOS_buttonPressed)
+}, {
+    [[-1, 0, 0], ACE_player] call FUNC(MCLOS_buttonPressed)
+},
+[DIK_NUMPAD6, [false, false, false]], false, 0] call CBA_fnc_addKeybind;  // Numpad 6
+
+["ACE3 Weapons", QGVAR(mclosRight), LLSTRING(mclosRight), {
+    [[-1, 0, 0], ACE_player] call FUNC(MCLOS_buttonPressed)
+}, {
+    [[1, 0, 0], ACE_player] call FUNC(MCLOS_buttonPressed)
+},
+[DIK_NUMPAD4, [false, false, false]], false, 0] call CBA_fnc_addKeybind;  // Numpad 4

addons/missileguidance/functions/fnc_MCLOS_buttonPressed.sqf

@@ -0,0 +1,42 @@
+#include "..\script_component.hpp"
+/*
+ * Author: tcvm
+ * Handles MCLOS guidance via keyboard keys
+ *
+ * Arguments:
+ * 0: Acceleration vector <ARRAY>
+ * 1: Unit <OBJECT>
+ *
+ * Return Value:
+ * If the button is pressed with an MCLOS context
+ *
+ * Example:
+ * [[0, 0, 1], player] call ace_missileguidance_fnc_MCLOS_buttonPressed
+ *
+ * Public: No
+ */
+
+params ["_accelerationDirection", "_player"];
+
+private _inMclosControlled = false;
+
+private _shooter = vehicle _player;
+if (getNumber ((configOf _shooter) >> QGVAR(hasMCLOSControl)) == 1) then {
+    playSound "ACE_Sound_Click";
+
+    private _currentDirection = _shooter getVariable [QGVAR(MCLOS_direction), [0, 0, 0]];
+    // Send data across network for handling non-local projectiles
+    // This is the case in a wanted development for a proper Malyutka implementation where projectiles will
+    // have their locality change via script
+    _shooter setVariable [QGVAR(MCLOS_direction), _currentDirection vectorAdd _accelerationDirection, true];
+
+    // Shouldn't have too many projectiles sent across the network. Planned max is 4 at a time
+    private _controlled = _shooter getVariable [QGVAR(mclos_projectiles), []];
+    _controlled = _controlled select { !isNull _x };
+    _shooter setVariable [QGVAR(mclos_projectiles), _controlled, true];
+
+    // if we are controlling missiles, we want the input to be captured
+    _inMclosControlled = _controlled isNotEqualTo [];
+};
+
+_inMclosControlled

addons/missileguidance/functions/fnc_MCLOS_onFired.sqf

@@ -0,0 +1,27 @@
+#include "..\script_component.hpp"
+/*
+ * Author: tcvm
+ * Sets up MCLOS state arrays (called from missileGuidance's onFired).
+ *
+ * Arguments:
+ * Guidance Arg Array <ARRAY>
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [] call ace_missileguidance_fnc_MCLOS_onFired
+ *
+ * Public: No
+ */
+params ["_firedEH", "", "", "", "_stateParams"];
+_firedEH params ["_shooter","_weapon","","","","","_projectile"];
+_stateParams params ["", "_seekerStateParams"];
+
+private _source = vehicle _shooter;
+
+private _controlled = _source getVariable [QGVAR(mclos_projectiles), []];
+_controlled pushBack _projectile;
+_source setVariable [QGVAR(mclos_projectiles), _controlled];
+
+_projectile setVariable [QGVAR(source), _source];

addons/missileguidance/functions/fnc_seekerType_MCLOS.sqf

@@ -0,0 +1,33 @@
+#include "..\script_component.hpp"
+/*
+ * Author: tcvm
+ * MCLOS seeker
+ *
+ * Arguments:
+ * 1: Guidance Arg Array <ARRAY>
+ * 2: Seeker State <ARRAY>
+ *
+ * Return Value:
+ * Position of wanted missile pos relative to the camera direction <ARRAY>
+ *
+ * Example:
+ * [] call ace_missileguidance_fnc_seekerType_MCLOS
+ *
+ * Public: No
+ */
+params ["", "_args"];
+_args params ["_firedEH", "", "_flightParams"];
+_firedEH params ["","","","","","","_projectile","_gunner"];
+_flightParams params ["_pitchRate", "_yawRate"];
+
+private _projectilePos = getPosASLVisual _projectile;
+private _source = _projectile getVariable [QGVAR(source), _projectile];
+
+private _accelerationDirection = _projectile vectorModelToWorldVisual (_source getVariable [QGVAR(MCLOS_direction), [0, 0, 0]]);
+private _returnPos = _projectilePos vectorAdd (_accelerationDirection vectorMultiply (_pitchRate max _yawRate));
+
+_targetData set [0, _projectilePos vectorFromTo _returnPos];
+_targetData set [2, _returnPos distance _projectilePos];
+
+_returnPos
+

addons/missileguidance/stringtable.xml

@@ -205,6 +205,18 @@
             <Chinese>循環切換開火模式</Chinese>
             <Turkish>Ateşleme Modunu Değiştir</Turkish>
         </Key>
+        <Key ID="STR_ACE_MissileGuidance_mclosUp">
+            <English>MCLOS Up</English>
+        </Key>
+        <Key ID="STR_ACE_MissileGuidance_mclosDown">
+            <English>MCLOS Down</English>
+        </Key>
+        <Key ID="STR_ACE_MissileGuidance_mclosRight">
+            <English>MCLOS Right</English>
+        </Key>
+        <Key ID="STR_ACE_MissileGuidance_mclosLeft">
+            <English>MCLOS Left</English>
+        </Key>
         <Key ID="STR_ACE_MissileGuidance_Hydra70_DAGR_6x">
             <English>6x DAGR [ACE]</English>
             <French>6x DAGR [ACE]</French>