diff --git a/terraform/ecr.tf b/terraform/ecr.tf
deleted file mode 100644
index 1f90869f6..000000000
--- a/terraform/ecr.tf
+++ /dev/null
@@ -1,70 +0,0 @@
-# ECR (Elastic Container Registry)
-#
-# All our code is run as tasks on ECS, which means they need repositories to
-# store the container images. Images are built and published to these
-# repositories by GitHub Actions.
-
-locals {
-  ecr_keep_10_images_policy = <<EOF
-    {
-      "rules": [
-        {
-          "rulePriority": 1,
-          "description": "Keep last 10 images",
-          "selection": {
-            "tagStatus": "any",
-            "countType": "imageCountMoreThan",
-            "countNumber": 10
-          },
-          "action": {
-            "type": "expire"
-          }
-        }
-      ]
-    }
-  EOF
-}
-
-resource "aws_ecr_repository" "server_repository" {
-  name                 = "univaf-server"
-  image_tag_mutability = "IMMUTABLE"
-
-  image_scanning_configuration {
-    scan_on_push = false
-  }
-}
-
-resource "aws_ecr_lifecycle_policy" "server_repository" {
-  repository = aws_ecr_repository.server_repository.name
-  policy     = local.ecr_keep_10_images_policy
-}
-
-resource "aws_ecr_repository" "loader_repository" {
-  name                 = "univaf-loader"
-  image_tag_mutability = "IMMUTABLE"
-
-  image_scanning_configuration {
-    scan_on_push = false
-  }
-}
-
-resource "aws_ecr_lifecycle_policy" "loader_repository" {
-  repository = aws_ecr_repository.loader_repository.name
-  policy     = local.ecr_keep_10_images_policy
-}
-
-# This repository is maintained only for historical reference. The seed image
-# should not actually ever be used in production.
-resource "aws_ecr_repository" "seed_repository" {
-  name                 = "univaf-db-seed"
-  image_tag_mutability = "IMMUTABLE"
-
-  image_scanning_configuration {
-    scan_on_push = false
-  }
-}
-
-resource "aws_ecr_lifecycle_policy" "seed_repository" {
-  repository = aws_ecr_repository.seed_repository.name
-  policy     = local.ecr_keep_10_images_policy
-}
diff --git a/terraform/ecs.tf b/terraform/ecs.tf
deleted file mode 100644
index 4bb65cbf0..000000000
--- a/terraform/ecs.tf
+++ /dev/null
@@ -1,77 +0,0 @@
-# ECS Cluster
-#
-# Most UNIVAF code is deployed as tasks that run on an ECS cluster, either as
-# scheduled cron-like scheduled tasks that run to completion, or as services
-# that the cluster will keep running. This file defines the cluster and
-# associated roles/policies needed to run tasks in it.
-
-resource "aws_ecs_cluster" "main" {
-  name = "univaf-cluster"
-
-  # Container Insights is *very* expensive for our configuration, but can be
-  # useful to turn on if granular metrics on cron job resource usage is needed.
-  setting {
-    name  = "containerInsights"
-    value = "disabled"
-  }
-}
-
-
-# Roles -----------------------------------------------------------------------
-
-# Things that need to execute tasks in the ECS cluster should use this role.
-resource "aws_iam_role" "ecs_task_execution_role" {
-  # TODO: consider using jsonencode and/or `inline_policy` blocks to put policy
-  #       definitions inline: https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/iam_role
-  name               = "univaf-ecs-task-execution"
-  assume_role_policy = data.aws_iam_policy_document.ecs_task_execution_role.json
-}
-
-# Gives the role access to things needed to execute tasks. The policy referenced
-# here is predefined by Amazon.
-resource "aws_iam_role_policy_attachment" "ecs_task_execution_role" {
-  role       = aws_iam_role.ecs_task_execution_role.name
-  policy_arn = "arn:aws:iam::aws:policy/service-role/AmazonECSTaskExecutionRolePolicy"
-}
-
-# Gives the role the ability to run actual tasks.
-resource "aws_iam_role_policy_attachment" "ecs_runtask_policy" {
-  role       = aws_iam_role.ecs_task_execution_role.name
-  policy_arn = aws_iam_policy.ecs_runtask_policy.arn
-}
-
-
-# Policies used in the role/attachments above ---------------------------------
-
-# Defines what resources are allowed to assume a given role.
-data "aws_iam_policy_document" "ecs_task_execution_role" {
-  version = "2012-10-17"
-  statement {
-    sid     = "1"
-    effect  = "Allow"
-    actions = ["sts:AssumeRole"]
-
-    principals {
-      type        = "Service"
-      identifiers = ["ecs-tasks.amazonaws.com", "events.amazonaws.com"]
-    }
-  }
-}
-
-# Defines the ability to run a task in ECS.
-data "aws_iam_policy_document" "ecs_task_additional_permissions" {
-  version = "2012-10-17"
-  statement {
-    sid     = "1"
-    effect  = "Allow"
-    actions = ["ecs:RunTask", "iam:PassRole"]
-    resources = [
-      "*" # TODO: lock this down
-    ]
-  }
-}
-resource "aws_iam_policy" "ecs_runtask_policy" {
-  name   = "runtask_policy"
-  path   = "/"
-  policy = data.aws_iam_policy_document.ecs_task_additional_permissions.json
-}
diff --git a/terraform/modules/task/main.tf b/terraform/modules/task/main.tf
deleted file mode 100644
index dae4ed1bc..000000000
--- a/terraform/modules/task/main.tf
+++ /dev/null
@@ -1,121 +0,0 @@
-
-/**
- * The task module creates an ECS task definition.
- *
- * Usage:
- *
- *     module "nginx" {
- *       source = "./modules/task"
- *       name   = "nginx"
- *       image  = "nginx"
- *     }
- *
- */
-
-/**
- * Define the two container definitions and the ultimate list we want to use
- */
-locals {
-  env_vars = merge(
-    { ENV = "production", NODE_ENV = "production", SENTRY_ENVIRONMENT = "ecs" },
-    var.env_vars
-  )
-
-  log_group_name = "/ecs/${var.name}"
-
-  datadog_container_def = {
-    name  = "datadog-agent"
-    image = "datadog/agent:latest"
-    environment = [
-      {
-        name  = "DD_API_KEY"
-        value = var.datadog_api_key
-      },
-      {
-        name  = "ECS_FARGATE",
-        value = "true"
-      }
-    ]
-  }
-
-  container_definition = {
-    cpu    = var.cpu
-    memory = var.memory
-
-    name  = var.name
-    image = var.image
-
-    environment = [for key, val in local.env_vars : { name = key, value = val }]
-    entryPoint  = var.entry_point
-    command     = var.command
-
-    essential   = true
-    networkMode = "awsvpc"
-    mountPoints = []
-    portMappings = [
-      {
-        containerPort = var.port
-        hostPort      = var.port
-      }
-    ]
-    logConfiguration = {
-      logDriver = "awslogs"
-      options = {
-        "awslogs-group"         = local.log_group_name
-        "awslogs-region"        = var.aws_region
-        "awslogs-stream-prefix" = "ecs"
-      }
-    }
-  }
-
-  encoded_containers = (
-    var.datadog_enabled
-    ? jsonencode([local.container_definition, local.datadog_container_def])
-    : jsonencode([local.container_definition])
-  )
-}
-
-/**
- * Resources.
- */
-
-# The ECS task definition.
-resource "aws_ecs_task_definition" "main" {
-  family             = var.name
-  execution_role_arn = var.role
-
-  lifecycle {
-    create_before_destroy = true
-  }
-
-  network_mode             = "awsvpc"
-  requires_compatibilities = ["FARGATE"]
-  cpu                      = var.cpu
-  memory                   = var.memory
-  container_definitions    = local.encoded_containers
-
-  # TODO: see about running on ARM for less power consumption. I *think* we
-  # need to build the images with:
-  #   docker buildx build --platform linux/amd64,linux/arm64 ...other-args...
-  # See also some tips in:
-  #   https://blog.thesparktree.com/docker-multi-arch-github-actions
-  # runtime_platform {
-  #   operating_system_family = "LINUX"
-  #   cpu_architecture        = "ARM64"
-  # }
-}
-
-# Set up CloudWatch group and log stream and retain logs for 30 days
-resource "aws_cloudwatch_log_group" "log_group" {
-  name              = local.log_group_name
-  retention_in_days = 30
-
-  tags = {
-    Name = var.name
-  }
-}
-
-resource "aws_cloudwatch_log_stream" "log_stream" {
-  name           = "${var.name}-log-stream"
-  log_group_name = aws_cloudwatch_log_group.log_group.name
-}
diff --git a/terraform/modules/task/outputs.tf b/terraform/modules/task/outputs.tf
deleted file mode 100644
index 54adec647..000000000
--- a/terraform/modules/task/outputs.tf
+++ /dev/null
@@ -1,23 +0,0 @@
-/**
- * Outputs.
- */
-
-// The created task definition name
-output "name" {
-  value = aws_ecs_task_definition.main.family
-}
-
-// The created task definition ARN
-output "arn" {
-  value = aws_ecs_task_definition.main.arn
-}
-
-// The task execution role ARN
-output "role" {
-  value = var.role
-}
-
-// The revision number of the task definition
-output "revision" {
-  value = aws_ecs_task_definition.main.revision
-}
diff --git a/terraform/modules/task/variables.tf b/terraform/modules/task/variables.tf
deleted file mode 100644
index 590f13eca..000000000
--- a/terraform/modules/task/variables.tf
+++ /dev/null
@@ -1,74 +0,0 @@
-/**
- * Required Variables.
- */
-
-variable "image" {
-  description = "The docker image name, e.g nginx"
-}
-
-variable "name" {
-  description = "The worker name, if empty the service name is defaulted to the image name"
-}
-
-variable "port" {
-  description = "The docker container port"
-  default     = 3000
-}
-
-/**
- * Optional Variables.
- */
-
-variable "cpu" {
-  description = "The number of cpu units to reserve for the container"
-  default     = 1024
-}
-
-variable "env_vars" {
-  description = "The raw json of the task env vars"
-  default     = {}
-}
-
-variable "command" {
-  description = "Command and arguments to run"
-  default     = []
-} # ["--state","NJ","vaccinespotter"]
-
-variable "entry_point" {
-  description = "The docker container entry point"
-  default     = []
-}
-
-variable "image_version" {
-  description = "The docker image version"
-  default     = "latest"
-}
-
-variable "memory" {
-  description = "The number of MiB of memory to reserve for the container"
-  default     = 2048
-}
-
-variable "log_driver" {
-  description = "The log driver to use use for the container"
-  default     = "awslogs"
-}
-
-variable "role" {
-  description = "The IAM Role to assign to the Container"
-  default     = ""
-}
-
-variable "aws_region" {
-  default = "us-west-2"
-}
-
-variable "datadog_enabled" {
-  description = "Should datadog be enabled for this task"
-  default     = false
-}
-
-variable "datadog_api_key" {
-  description = "The datadog api key to be used for this container"
-  default = ""
-}