-
Notifications
You must be signed in to change notification settings - Fork 0
/
testing.jai
252 lines (189 loc) · 6.33 KB
/
testing.jai
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
/// Compile-time testing
/*
Testing is comprised of:
- Suites: groups of tests under a single name
- Test: a name and a test procedure
Suites are declared like so:
#run suite("my test suite", #code {
// ...
});
Note, this *must* be run at compile-time.
Tests within a suite are declared like so:
#run suite("my test suite", #code {
test("some test", (t: *Test) {
// ...
});
test("this also works", (t) => {
// ...
});
});
This module provides (at this time) one procedure
to check correctness: 'expect'.
'expect' is almost a drop-in replacement for 'assert'.
The only noticeable differences are that it requires a
'*Test' to be passed as its first parameter, and it
can only be called within a test procedure.
#run suite("my test suite", #code {
test("some test", (t: *Test) {
expect(t, 1 == 1, "1 was not equal to 1?");
expect(t, 2 % 2 == 0);
});
});
For more examples, take a look at the tests defined
in other modules.
*/
Test :: struct {
name: string;
suite: *Suite;
}
suite :: ($name: string, tests: Code, loc := #caller_location) #expand {
suite(name, true, true, true, tests, loc);
}
suite :: ($name: string, $enabled: bool, $verbose: bool, $halt_on_fail: bool, tests: Code, loc := #caller_location) #expand {
#if !enabled return;
set_build_options_dc(.{ do_output = false });
suite: Suite;
suite.name = name;
suite.location = loc;
#insert,scope() tests;
test_word := pluralize("test", suite.tests.count);
color_print(".. Group @bold{%} @blue{(% %)}\n", suite.name, suite.tests.count, test_word);
longest_name := 0;
for suite.tests if it.name.count > longest_name {
longest_name = it.name.count;
}
start := current_time_monotonic();
for * suite.tests {
suite.current = it;
test: Test;
test.name = it.name;
test.suite = *suite;
dots: string;
{
builder: String_Builder;
for 0..(longest_name - test.name.count) + 2 append(*builder, ".");
dots = builder_to_string(*builder);
}
color_print(" Test @bold{%0%} ", test.name, dots);
begin := current_time_monotonic();
it.proc(*test);
end := current_time_monotonic();
it.duration_in_sec = to_float64_seconds(end - begin);
if it.status == {
case .Pass;
suite.passed += 1;
color_print("@green{pass} ");
#if verbose {
color_print("@blue{(took %s)}", it.duration_in_sec);
}
case .Fail;
suite.failed += 1;
color_print("@red{fail} at @bold{%}", to_string(it.location));
#if verbose {
print("\n");
builder: String_Builder;
root := compiler_get_nodes(it.original_expr);
proc := New(Code_Procedure_Call);
proc.kind = .PROCEDURE_CALL;
ident := New(Code_Ident);
ident.kind = .IDENT;
ident.name = it.last_call;
proc.procedure_expression = ident;
args: [1]Code_Argument;
args[0].expression = root;
proc.arguments_unsorted = args;
print_expression(*builder, proc);
expr_str := replace(builder_to_string(*builder), "%", "%%");
if it.error_message.count {
color_print("\t @italic{%} @bold{in} ", it.error_message);
}
else {
print("\t Failed call was ");
}
color_print("@red{%}", expr_str);
}
else {
if it.error_message.count {
print(": %", it.error_message);
}
}
}
print("\n");
}
end := current_time_monotonic();
color_print(".. Group @bold{%} ", suite.name);
#if halt_on_fail defer {
if suite.failed exit(1);
}
if suite.failed {
color_print("@red{failed} %/% % ", suite.failed, suite.tests.count, test_word);
}
else {
color_print("@green{passed} ");
}
#if verbose {
color_print("@blue{(took %s)}", to_float64_seconds(end - start));
}
print("\n\n");
}
test :: (name: string, proc: Test_Context.Proc, loc := #caller_location) #expand {
test := array_add(*`suite.tests);
test.name = name;
test.location = loc;
test.proc = proc;
}
expect :: (test: *Test, expr: Code, format_string := "", args: ..Any, loc := #caller_location) #expand {
if !within_test(test) return;
ctx := test.suite.current;
if ctx.has_already_failed return;
expr_as_bool := cast(bool)(#insert expr);
if expr_as_bool {
ctx.status = .Pass;
}
else {
ctx.status = .Fail;
ctx.last_call = "expect";
ctx.original_expr = expr;
ctx.has_already_failed = true;
if format_string.count {
ctx.error_message = sprint(format_string, ..args);
}
}
}
#scope_file
Test_Context :: struct {
name: string;
location: Source_Code_Location;
proc: Test_Context.Proc;
last_call: string;
error_message: string;
original_expr: Code;
duration_in_sec: float64;
has_already_failed: bool;
status: Test_Context.Status;
Status :: enum {
Pass;
Fail;
}
Proc :: #type (*Test);
}
Suite :: struct {
name: string;
location: Source_Code_Location;
passed: int;
failed: int;
tests: [..]Test_Context;
current: *Test_Context;
}
within_test :: (test: *Test, loc := #caller_location) -> bool #expand {
if !test || !test.suite.current {
compiler_report("'expect' was called outside of a test!", loc = loc);
return false;
}
return test.suite.current.status != .Fail;
}
#import,file "color-print.jai";
#import,file "utilities.jai";
#import "Basic";
#import "Program_Print";
#import "Compiler";