-
Notifications
You must be signed in to change notification settings - Fork 0
/
configure.ac.in
213 lines (190 loc) · 6.88 KB
/
configure.ac.in
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
dnl
dnl Copyright (c) 2003-2009
dnl os-cillation e.K. All rights reserved.
dnl
dnl Written by Benedikt Meurer <[email protected]>.
dnl
dnl ***************************
dnl *** Version information ***
dnl ***************************
m4_define([terminal_version_major], [0])
m4_define([terminal_version_minor], [4])
m4_define([terminal_version_micro], [5])
m4_define([terminal_version_nano], [])
m4_define([terminal_version_build], [@REVISION@])
m4_define([terminal_version_tag], [git])
m4_define([terminal_version_dbus], [4])
m4_define([terminal_version], [terminal_version_major().terminal_version_minor().terminal_version_micro()ifelse(terminal_version_nano(), [], [], [.terminal_version_nano()])ifelse(terminal_version_tag(), [git], [terminal_version_tag()-terminal_version_build()], [terminal_version_tag()])])
dnl *******************************************
dnl *** Debugging support for GIT snapshots ***
dnl *******************************************
m4_define([terminal_debug_default], [ifelse(terminal_version_tag(), [git], [yes], [minimum])])
dnl ***************************
dnl *** Initialize autoconf ***
dnl ***************************
AC_COPYRIGHT([Copyright (c) 2003-2009
os-cillation e.K. All rights reserved.
Written by Benedikt Meurer <[email protected]>.])
AC_INIT([Terminal], [terminal_version], [http://bugzilla.xfce.org/], [Terminal])
AC_REVISION([@REVISION@])
AC_PREREQ([2.50])
AC_ARG_PROGRAM()
dnl ***************************
dnl *** Initialize automake ***
dnl ***************************
AM_INIT_AUTOMAKE([1.8 dist-bzip2 tar-ustar])
AM_CONFIG_HEADER([config.h])
AM_MAINTAINER_MODE()
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
dnl ***********************************
dnl *** Subst D-BUS service version ***
dnl ***********************************
TERMINAL_VERSION_DBUS=terminal_version_dbus()
AC_SUBST([TERMINAL_VERSION_DBUS])
dnl *******************************
dnl *** Check for UNIX variants ***
dnl *******************************
AC_AIX()
AC_ISC_POSIX()
dnl ********************************
dnl *** Check for basic programs ***
dnl ********************************
AC_PROG_CC()
AM_PROG_CC_C_O()
AC_PROG_INSTALL()
AC_PROG_INTLTOOL([0.31], [no-xml])
AC_PROG_LIBTOOL()
dnl **********************************
dnl *** Check for standard headers ***
dnl **********************************
AC_CHECK_HEADERS([ctype.h errno.h limits.h pwd.h signal.h time.h])
dnl ******************************
dnl *** Check for i18n support ***
dnl ******************************
XDT_I18N([@LINGUAS@])
dnl ********************************
dnl *** Check for X11 (optional) ***
dnl ********************************
XDT_CHECK_LIBX11()
dnl ***********************************
dnl *** Check for required packages ***
dnl ***********************************
XDT_CHECK_PACKAGE([EXO], [exo-0.3], [0.3.4], [],
[XDT_CHECK_PACKAGE([EXO], [exo-1], [0.5.0])])
XDT_CHECK_PACKAGE([GTK], [gtk+-2.0], [2.14.0])
XDT_CHECK_PACKAGE([VTE], [vte], [0.17.1])
XDT_CHECK_PACKAGE([GIO], [gio-2.0], [2.16.0])
dnl **********************************
dnl *** Optional support for D-BUS ***
dnl **********************************
XDT_CHECK_OPTIONAL_PACKAGE([DBUS], [dbus-glib-1], [0.22],
[dbus], [D-BUS GLib bindings])
if test x"$DBUS_FOUND" = x"yes"; then
AC_MSG_CHECKING([whether to use new D-BUS API])
if $PKG_CONFIG --atleast-version 0.31 dbus-1 >/dev/null 2>&1; then
AC_DEFINE([DBUS_USE_NEW_API], [1], [Define to use new D-BUS API])
AC_MSG_RESULT([yes])
else
AC_MSG_RESULT([no])
fi
fi
dnl ***************************************************
dnl *** Check if we need to build the documentation ***
dnl ***************************************************
AC_ARG_ENABLE([gen-doc], [AC_HELP_STRING([--enable-gen-doc],
[Generate HTML documentation (requires xsltproc, xml2po and xmllint) [default=no]])],, [enable_gen_doc=no])
if test x"$enable_gen_doc" = x"yes"; then
AC_PATH_PROG([XSLTPROC], [xsltproc], [no])
if test x"$XSLTPROC" = x"no"; then
enable_gen_doc=no
fi
AC_PATH_PROG([XML2PO], [xml2po], [no])
if test x"$XML2PO" = x"no"; then
enable_gen_doc=no
fi
AC_PATH_PROG([XMLLINT], [xmllint], [no])
if test x"$XML2PO" = x"no"; then
enable_gen_doc=no
fi
if test x"$enable_gen_doc" = x"no"; then
AC_MSG_ERROR([Compiling with --enable-gen-doc but one of xml2po, xsltproc or xmllint not found.])
fi
fi
AM_CONDITIONAL([GENERATE_DOCUMENTATION], [test x"$enable_gen_doc" = x"yes"])
dnl ****************************************
dnl *** Register in Gnome Control Center ***
dnl ****************************************
AC_ARG_WITH([gnome-default-appsdir],
[AC_HELP_STRING([--with-gnome-default-appsdir=PATH],
[Specify where to install the Gnome default applications file (default=autodetect)])],
[gnome_default_appsdir="$withval"])
AC_MSG_CHECKING([for Gnome default applications dir])
if test x"$gnome_default_appsdir" = x""; then
GNOME_DEFAULT_APPSDIR="`$PKG_CONFIG --variable=defappsdir gnome-default-applications`"
if test -n "$GNOME_DEFAULT_APPSDIR"; then
AC_MSG_RESULT([Using path supplied by gnome-control-center])
else
AC_MSG_RESULT([Using prefix of terminal])
fi
else
GNOME_DEFAULT_APPSDIR="$gnome_default_appsdir"
AC_MSG_RESULT([Using path supplied by user])
fi
AM_CONDITIONAL([HAVE_GNOME_DEFAULT_APPSDIR], [test -n "$GNOME_DEFAULT_APPSDIR"])
AC_SUBST([GNOME_DEFAULT_APPSDIR])
dnl ***********************************
dnl *** Check for debugging support ***
dnl ***********************************
XDT_FEATURE_DEBUG([terminal_debug_default])
dnl **************************************
dnl *** Check for linker optimizations ***
dnl **************************************
XDT_FEATURE_LINKER_OPTS()
dnl *********************************
dnl *** Substitute platform flags ***
dnl *********************************
AC_MSG_CHECKING([PLATFORM_CPPFLAGS])
AC_MSG_RESULT([$PLATFORM_CPPFLAGS])
AC_SUBST([PLATFORM_CPPFLAGS])
AC_MSG_CHECKING([PLATFORM_CFLAGS])
AC_MSG_RESULT([$PLATFORM_CFLAGS])
AC_SUBST([PLATFORM_CFLAGS])
AC_MSG_CHECKING([PLATFORM_LDFLAGS])
AC_MSG_RESULT([$PLATFORM_LDFLAGS])
AC_SUBST([PLATFORM_LDFLAGS])
AC_OUTPUT([
Makefile
Terminal.spec
doc/Makefile
doc/images/Makefile
doc/images/ja/Makefile
doc/po/Makefile
icons/Makefile
icons/16x16/Makefile
icons/24x24/Makefile
icons/48x48/Makefile
icons/scalable/Makefile
po/Makefile.in
terminal/Makefile
terminal/terminal-config.h
])
dnl ***************************
dnl *** Print configuration ***
dnl ***************************
echo
echo "Build Configuration:"
echo
if test x"$DBUS_FOUND" = x"yes"; then
echo "* D-Bus support: yes"
else
echo "* D-Bus support: no"
fi
echo "* Debug support: $enable_debug"
if test x"$enable_gen_doc" = x"yes"; then
echo "* Documentation: yes (generate)"
elif test -d "${srcdir}/doc/html"; then
echo "* Documentation: yes (in tarball)"
else
echo "* Documentation: no"
fi
echo