-
Notifications
You must be signed in to change notification settings - Fork 1
/
perror.s
1795 lines (1675 loc) · 41.4 KB
/
perror.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
XDEF IVarPError,VarPError,PSymTab,OutLst,OutMsg
XDEF UsrTxt,MsgTbl,TotErr,LstErr,TotWarn,LstWarn,CursPtr,CursW
XREF StrtTime,StopTime,FatalError,NoPrtEnd
XREF Sprintf,PrtLine,PrtNChar,GetShifts
XREF StartRoutines,Ligne
XREF FieldsPtr,maflags
XREF SrcCurName,IEnvFlg
XREF WarnFlg,CorrFlg,CorSaveA6,CoringFlg,TopStack
XREF LstSymFlg
XREF MacStuff,RetNor,RetMac
XREF EvalErrP
XREF FstModPtr,GloTbl,GloNb,EqusPtr,OptiNb
XREF IEnvPtr
include "comequ.s"
TAB_VALUE EQU 8
_MSGWARN equ 0
_MSGOPTI equ 1
_MSGEVAL equ 2
_MSGCORR equ 3
_MSGFATL equ 4
section TEXT
; #[ OutMsg:
OutMsg: move.w MSG_flags(a0),d0
btst #_MSGCORR,d0
seq nocorflg
btst #_MSGWARN,d0
bne.s pwarn
btst #_MSGOPTI,d0
bne.s pwarn
btst #_MSGEVAL,d0
bne peval
btst #_MSGFATL,d0
bne.s pfatal
bra.s perror
; #] OutMsg:
; #[ pwarn:
pwarn: tst.w WarnFlg
bne.s dowarn
clr.b UsrTxt ;ensure clean user message
endwarn: addq.l #1,TotWarn
rts
dowarn: movem.l d1-a4/a6,-(sp)
move.l a0,a4 ;error struct
lea -256(sp),sp
move.l sp,a6
IFNE BLINDOS
cmp.w #MAX_WARNNO,MSG_no(a4)
ble.s .ok
clr.w MSG_no(a4)
.ok:
ENDC ;BLINDOS
move.w MSG_no(a4),LstWarn
lea warntbl,a0
bsr setmsg
lea warn_txt,a0
bsr bldmsg
bsr PrintMsg
bsr PrintFrom
lea 256(sp),sp
movem.l (sp)+,d1-a4/a6
bra.s endwarn
; #] pwarn:
; #[ pfatal:
pfatal: bsr.s perror
jmp FatalError
; #] pfatal:
; #[ perror:
perror: movem.l d1-a4/a6,-(sp)
move.l a0,a4 ;error struct
lea -256(sp),sp
move.l sp,a6
IFNE BLINDOS
cmp.w #MAX_ERRNO,MSG_no(a4)
ble.s .ok
clr.w MSG_no(a4)
.ok:
ENDC ;BLINDOS
move.w MSG_no(a4),LstErr
lea MsgTbl,a0
bsr.s setmsg
lea error_txt,a0
bsr bldmsg
tst.w CorrFlg
beq.s .nocor
tst.b nocorflg
beq.s .docor
.nocor:
.pr: bsr PrintMsg
bsr PrintFrom
lea 256(sp),sp
movem.l (sp)+,d1-a4/a6
addq.l #1,TotErr
rts
.docor: bra DoCor
; #] perror:
; #[ bldmsg:
setmsg: move.w MSG_no(a4),d0
; IFNE _68000
add.w d0,d0
add.w d0,d0
move.l 0(a0,d0.w),d0
; ELSEIF
; move.l 0(a0,d0.w*4),d0
; ENDC ;_68000
bne.s .ok0
move.l #error_error_txt,d0
.ok0: move.l d0,MSG_msg1(a4)
move.l #UsrTxt,MSG_msg2(a4)
rts
;In:
;a0=mod @
;a1=buf @
bldmodname:
movem.l a0-a2,-(sp)
lea modnambuf,a1
move.l a0,d0
bne.s .l1
lea SrcCurName,a0
STRCPY
bra.s .end
.l1: move.l d0,a2
move.l MOD_orgnam(a2),a0
STRCPY
move.l MOD_father(a2),d0
beq.s .end
lea .nxt_txt(pc),a0
subq.w #1,a1
STRCPY
subq.w #1,a1
bra.s .l1
.end: tst.b modnambuf
movem.l (sp)+,a0-a2
rts
.nxt_txt: dc.b " <- ",0
even
bldmsg: movem.l d0-d2,-(sp)
move.l a0,a1
tst.b UsrTxt
bne.s .usr
move.l MSG_msg1(a4),-(sp) ;msg text
move.l MSG_mod(a4),a0
bsr bldmodname
bne.s .mod
move.w MSG_no(a4),-(sp) ;msgno
move.l a1,-(sp) ;msgtype
move.l a6,a0
lea msgfrst_txt,a1
bsr Sprintf
lea 10(sp),sp
bra.s .end
.mod: move.l MSG_lnb(a4),-(sp) ;line nb
pea modnambuf ;mod name
move.w MSG_no(a4),-(sp) ;msgno
move.l a1,-(sp) ;msgtype
move.l a6,a0
lea msgfile_txt,a1
bsr Sprintf
lea 18(sp),sp
.end: movem.l (sp)+,d0-d2
rts
.usr: pea UsrTxt ;user text
move.l MSG_msg1(a4),-(sp) ;msg text
move.l MSG_lnb(a4),-(sp) ;line nb
move.l MSG_mod(a4),a0 ;mod name
bsr bldmodname
pea modnambuf
move.w MSG_no(a4),-(sp) ;msgno
move.l a1,-(sp) ;msgtype
move.l a6,a0
lea msguser_txt,a1
bsr Sprintf
lea 22(sp),sp
bra.s .end
; #] bldmsg:
; #[ PrintMsg:
PrintMsg: tst.b IEnvFlg
bne.s .ienv
move.l a6,a0
tst.l MSG_ln(a4)
beq.s .print
bsr.s .print
move.l MSG_ln(a4),a0
lea errbuf,a1
bsr GetLine
lea errbuf,a0
.print: clr.b UsrTxt
jmp PrtLine
.ienv: move.l a4,a0
move.l IEnvPtr,a1
move.l IENV_outmsg(a1),a1
jsr (a1)
clr.b UsrTxt
tst.w d0
bne.s .ok
jmp NoPrtEnd
.ok: rts
; #] PrintMsg:
; #[ bldeval:
bldeval: move.w MSG_ev(a4),d0
IFNE _68000
lea MsgTbl,a1
add.w d0,d0
add.w d0,d0
move.l 0(a1,d0.w),d0
ELSEIF
move.l (MsgTbl,d0.w*4),d0
ENDC ;_68000
IFNE BLINDOS
beq.s .rmsg
ENDC
move.l d0,-(sp) ;ea txt
lea UsrTxt,a0
lea .fmt(pc),a1
bsr Sprintf
addq.w #4,sp
rts
IFNE BLINDOS
.rmsg: _Debugger
ENDC
.fmt: dc.b "in %s",0
even
; #] bldeval:
; #[ peval:
;a0=@ token end
;d0=gene errno
;d1=eval errno
;d2=offset
;+EvalErrP
peval: movem.l d1-a4/a6,-(sp)
move.l a0,a4 ;error struct
add.w #-eval_errno,MSG_no(a4)
move.w MSG_no(a4),LstErr
bsr bldeval
lea -256(sp),sp
move.l sp,a6
tst.w CorrFlg
beq.s .nocor
tst.b nocorflg
beq.s .docor
.nocor: lea MsgTbl,a0
bsr setmsg
lea error_txt,a0
bsr bldmsg
bsr PrintMsg
bsr.s PrintFrom
.end: addq.l #1,TotErr
lea 256(sp),sp
movem.l (sp)+,d1-a4/a6
rts
.docor: lea MsgTbl,a0
bsr setmsg
lea error_txt,a0
bsr bldmsg
bsr AskMsg ;affichage en trap 13 (ecran)
; jsr StopTime ;stop timer
lea errbuf,a0
bsr AskLine
movem.l (sp)+,d0-d2
bne.s .changed
lea MsgTbl,a0
bsr setmsg
lea error_txt,a0
bsr bldmsg
bsr PrintMsg
addq.l #1,TotErr
bra.s .end
.changed: bsr loopit
; jsr StrtTime
bra.s .end
; #] peval:
; #[ PrintFrom:
PrintFrom:
movem.l a4-a5,-(sp)
lea MacStuff,a5
tst.w MacNestCnt(a5)
beq.s .end
move.l MacStackPtr(a5),d0
beq.s .end
.nxmac: move.l d0,a4
move.l MACCTXT_lnb(a4),-(sp)
move.l MACCTXT_mod(a4),a0
bsr bldmodname
; bne.s .mod
; beq.s .nomod
; move.l d0,a1
; move.l MOD_orgnam(a1),d0
; beq.s .nomod
; move.l d0,a1
; bra.s .mod
;.nomod: lea SrcCurName,a1
;.mod: move.l a1,-(sp)
pea modnambuf ;mod name
lea msgfrom_txt,a1
move.l a6,a0
bsr Sprintf
addq.w #8,sp
move.l a6,a0
jsr PrtLine
move.l MACCTXT_lptr(a4),a0
move.l a6,a1
bsr GetLine
move.l a6,a0
jsr PrtLine
move.l MACCTXT_prev(a4),d0
bne.s .nxmac
.end: movem.l (sp)+,a4-a5
rts
; #] PrintFrom:
; #[ VarPError:
;In:
;a0=@ var
;d0=#
IVarPError:
movem.l d1-a4/a6,-(sp)
move.l a0,a3
lea -256(sp),sp ;ascii buffer
move.l sp,a4
move.w VAR_len(a3),-(sp) ;*
move.l sp,d2
move.l d0,-(sp) ;mdef #
move.l VAR_start(a3),-(sp) ;var name @
move.l d2,d1
move.l a4,a0
lea varmdef_txt,a1
bsr Sprintf
lea 10(sp),sp
move.l a4,a0
jsr PrtLine
lea 256(sp),sp
movem.l (sp)+,d1-a4/a6
;In:
;a0=@ var
VarPError:
movem.l d1-d7/a1-a4/a6,-(sp)
move.l a0,a3
move.l a3,a0
bsr.s gettypename
lea UsrTxt,a1
STRCPY
lea -MSG_SIZEOF(sp),sp
clr.w MSG_flags(sp)
move.w #-mdefany_errno,MSG_no(sp)
clr.w MSG_len(sp) ;no offset
move.w VAR_mod(a3),d0 ;mod #
bsr.s getmodptr
move.l a0,MSG_mod(sp) ;mod @
move.l VAR_lnb(a3),MSG_lnb(sp) ;line #
clr.l MSG_ln(sp) ;line @
move.l sp,a0
bsr OutMsg
lea MSG_SIZEOF(sp),sp
movem.l (sp)+,d1-d7/a1-a4/a6
rts
;In:
;d0=module #
;Out:
;a0=module @
getmodptr:
move.l FstModPtr,a0
subq.w #2,d0
bmi.s .this
.l1: move.l MOD_next(a0),a0
dbf d0,.l1
.this: rts
;In:
;a0 = var struct
;Out:
;d0 = var type
;a0 = type name
gettypename:
move.b VAR_type(a0),d0
andi.w #%1111,d0
IFNE _68000
move.w d0,d1
add.w d1,d1
add.w d1,d1
move.l .t(pc,d1.w),a0
ELSEIF
move.l .t(pc,d0.w*4),a0
ENDC
rts
.t: dc.l equ_txt,set_txt,equr_txt,reg_txt
dc.l glo_txt,xref_txt,xdef_txt,loc_txt
dc.l fequ_txt,fset_txt,fequr_txt,freg_txt
dc.l macro_txt
; #] VarPError:
; #[ PSymTab:
;In:
;a0 = var struct
;Out:
;a0 = sec text
getsecname:
moveq #0,d0
move.b VAR_sec(a0),d0
bmi.s .off
move.l .tab(pc,d0.w),a0
rts
.off: lea offset_txt,a0
rts
.tab: dc.l text_txt,data_txt,bss_txt,org_txt
psym: move.w VAR_len(a2),-(sp) ;*
move.l sp,d2
move.l a2,a0 ;sec name
bsr getsecname
move.l a0,-(sp)
move.l a2,a0
bsr gettypename ;type name
move.l a0,-(sp)
move.l VAR_value(a2),-(sp) ;value
move.l VAR_start(a2),-(sp) ;name
move.l d2,d1
move.l a4,a0
lea .fmt(pc),a1
bsr Sprintf
lea 18(sp),sp
move.l a4,a0
jmp PrtLine
.fmt: dc.b "%*s $%=lx %s %s",13,10,0
even
PSymTab: tst.b LstSymFlg
bne.s .dolst
rts
.dolst: movem.l d3-d7/a2-a4/a6,-(sp)
lea -256(sp),sp
move.l sp,a4
move.l GloTbl,a6
move.l GloNb,d7
beq.s .noglo
.l0: move.l (a6)+,a2
bsr psym
subq.l #1,d7
bgt.s .l0
.noglo: move.l EqusPtr,d0
beq.s .end
.l1: move.l d0,a6
move.w EQUL_nb(a6),d7
subq.w #1,d7
bmi.s .nxt
move.l EQUL_block(a6),a3
.l2: move.l (a3)+,a2
bsr psym
dbf d7,.l2
.nxt: move.l EQUL_next(a6),d0
bne.s .l1
.end: lea 256(sp),sp
movem.l (sp)+,d3-d7/a2-a4/a6
rts
; #] PSymTab:
; #[ OutLst: print a listing line
;In: a0=curline
OutLst: move.l a0,a1
lea -256(sp),sp
move.l sp,a0
moveq #13,d1
moveq #10,d2
.l1: move.b (a1)+,d0
beq.s .l2
move.b d0,(a0)+
cmp.b d2,d0
beq.s .l2
cmp.b d1,d0
bne.s .l1
.l2: IFNE ATARI
move.b d1,-1(a0) ;cr
move.b d2,(a0)+ ;lf
ENDC ;ATARI
IFNE AMIGA
move.b d2,-1(a0) ;lf
ENDC ;AMIGA
clr.b (a0)
move.l sp,a0
jsr PrtLine
lea 256(sp),sp
rts
; #] OutLst:
; #[ DoCor:
DoCor: bsr AskMsg ;affichage en trap 13 (ecran)
; jsr StopTime ;stop timer
lea errbuf,a0
bsr AskLine
bne.s .changed
lea MsgTbl,a0
bsr setmsg
lea error_txt,a0
bsr bldmsg
bsr PrintMsg
addq.l #1,TotErr
bra.s .end
.changed: move.l a6,CorSaveA6
st CoringFlg
bsr.s loopit
.end: ;jsr StrtTime
lea 256(sp),sp
movem.l (sp)+,d1-a4/a6
rts
loopit: move.l a6,-(sp)
lea tmperrbuf,a6
move.l TopStack,sp
tst.w MacStuff+MacNestCnt
bne.s .mac
jsr RetNor
move.l (sp)+,a6
rts
.mac: jsr RetMac
move.l (sp)+,a6
rts
jsr Ligne
move.w d6,d3
bmi.s .end ;pas d'opcode
beq.s .nooper
move.l FieldsPtr,FIELDPTR ;@ debut de l'operande
lea maflags,EAPTR ;@ modes d'adressage
.nooper:
move.w REF_opcode(REFPTR),d4 ;opcode
lea StartRoutines,a1
add.w REF_rout(REFPTR),a1
jsr (a1) ;jsr ([REF_rout,REFPTR],StartRoutines)
.end: rts
; #] DoCor:
; #[ AskMsg:
AskMsg: move.l a6,a0
bsr.s .prtline
move.l MSG_ln(a4),a0
lea errbuf,a1
bsr.s GetLine
lea errbuf,a0
.prtline: movem.l d0-d2/a0-a2,-(sp)
.loop: move.b (a0)+,d0
beq.s .end
bsr.s .putc
bra.s .loop
.end: movem.l (sp)+,d0-d2/a0-a2
rts
.putc: movem.l d3/a0,-(sp)
cmp.b #9,d0
bne.s .noexp
moveq #TAB_VALUE,d3
moveq #0,d1
move.l CursPtr,a0
move.w (a0),d1
divu d3,d1
swap d1
sub d1,d3
subq #1,d3
.expand: moveq #' ',d0
bsr PrtNChar
dbf d3,.expand
movem.l (sp)+,d3/a0
rts
.noexp: bsr PrtNChar
movem.l (sp)+,d3/a0
rts
; #] AskMsg:
; #[ GetLine:
;In:
;a0=from
;a1=to
GetLine: movem.l d0-d3/a0-a1,-(sp)
moveq #10,d1
moveq #13,d2
move.l a0,d0
beq.s .end2
move.w #256-2,d3
move.b (a0)+,d0
beq.s .end2
bra.s .nxt
.l1: move.b (a0)+,d0 ;et stocker
.nxt: move.b d0,(a1)+
beq.s .end2
cmp.b d1,d0
beq.s .end
cmp.b d2,d0
dbeq d3,.l1
.end: subq.w #1,a1
.end2: move.b d1,(a1)+
IFNE ATARI
move.b d2,(a1)+
ENDC
clr.b (a1)
movem.l (sp)+,d0-d3/a0-a1
rts
; #] GetLine:
; #[ AskLine:
AskLine: movem.l d3-d7/a3-a4,-(sp)
move.l a0,a3
moveq #0,d3
move.b MSG_off(a4),d3
lea .newline(pc),a0
bsr .prtline
lea .newline(pc),a0
bsr .prtline
lea .newline(pc),a0
bsr .prtline
lea .newline(pc),a0
bsr .prtline
lea .newline(pc),a0
bsr .prtline
lea .newline(pc),a0
bsr .prtline
lea .newline(pc),a0
bsr .prtline
lea .toup(pc),a0
bsr .prtline
lea .toup(pc),a0
bsr .prtline
lea .toup(pc),a0
bsr .prtline
lea .toup(pc),a0
bsr .prtline
lea .toup(pc),a0
bsr .prtline
lea .toup(pc),a0
bsr .prtline ;pour eviter de scroller en saisie.
bsr.s .init_saisie
bmi.s .abort ;ligne >255 chars
bsr .saisie
beq.s .abort
bsr .exit_saisie
beq.s .abort
moveq #-1,d0
.end: movem.l (sp)+,d3-d7/a3-a4
rts
.abort: moveq #0,d0
bra.s .end
.init_saisie:
moveq #0,d5 ;taille de la chaine
moveq #0,d6 ;offset physique
moveq #0,d7 ;offset logique
move.l a3,a0
move.l a3,a4 ;pour future comparaison
lea tmperrbuf,a3
.size:
move.b (a0)+,d0
beq.s .found_size
cmp.b #13,d0
beq.s .found_size
cmp.b #10,d0
beq.s .found_size
addq.b #1,d5
bcs.s .size_error
move.b d0,(a3)+
bra.s .size
.found_size:
sf (a3)
lea tmperrbuf,a3
move d5,d7
cmp.l d5,d3
bhi.s .pas_offset
move d3,d7
.pas_offset:
bsr .find_offset
move d0,d6
lea .cursoff(pc),a0
bsr .prtline
move.l a3,a0
bsr .prtline
bsr .home
move d6,d3
moveq #0,d6
subq #1,d3
bmi.s .no_offset
.skip:
bsr .go_to_right
addq #1,d6
dbf d3,.skip
.no_offset:
lea .curson(pc),a0
bsr .prtline
moveq #0,d0
rts
.size_error:
moveq #-1,d0
rts
.exit_saisie:
;
; Effacer tout l'affichage depuis l'affichage de l'erreur
;
bsr .home
moveq #0,d7
bsr .couper
lea .toup(pc),a0
bsr.s .prtline
lea .ctrld(pc),a0
bsr.s .prtline
lea .toup(pc),a0
bsr.s .prtline
lea .ctrld(pc),a0
bsr.s .prtline
lea .toup(pc),a0
bsr.s .prtline ;3 ligne d'erreurs affichees
lea .ctrld(pc),a0
bsr.s .prtline
;
move.l a4,a0
moveq #0,d4
.org_size:
move.b (a0)+,d0
beq.s ._size
cmp.b #13,d0
beq.s ._size
cmp.b #10,d0
beq.s ._size
addq.b #1,d4
bra.s .org_size
._size:
cmp d4,d5
bne.s .changed_line
subq #1,d4
.compare:
cmp.b (a4)+,(a3)+
dbne d4,.compare
bne.s .changed_line
.nochge: moveq #0,d0
rts
.changed_line:
moveq #-1,d0
rts
.find_offset:
moveq #0,d0
move d7,d4
beq.s .first
subq #1,d4
moveq #0,d1
.loop_offset:
cmp.b #9,0(a3,d1)
bne.s .not_tab
moveq #TAB_VALUE,d3
move.l d0,d2
divu d3,d2
swap d2
sub d2,d3
subq #1,d3
add d3,d0
.not_tab:
addq #1,d0
addq #1,d1
dbf d4,.loop_offset
.first: bra.s .nochge
.prtline: movem.l d0-d2/a0-a2,-(sp)
.lline: move.b (a0)+,d0
beq.s .endline
bsr.s .putchar
bra.s .lline
.endline: movem.l (sp)+,d0-d2/a0-a2
rts
.putchar: movem.l d3/a0,-(sp)
cmp.b #9,d0
bne.s .noexp
moveq #TAB_VALUE,d3
moveq #0,d1
move.l CursPtr,a0
move.w (a0),d1
divu d3,d1
swap d1
sub d1,d3
subq #1,d3
.expand: moveq #' ',d0
bsr PrtNChar
dbf d3,.expand
movem.l (sp)+,d3/a0
rts
.noexp: bsr PrtNChar
movem.l (sp)+,d3/a0
rts
.insert_char:
lea 0(a3,d7),a0
moveq #-1,d1
.count0:
tst.b (a0)+
dbeq d1,.count0
not d1
.copy0:
move.b -1(a0),(a0)
subq #1,a0
dbf d1,.copy0
move.b d0,(a0)
rts
.supress_char:
lea 0(a3,d7),a0
.delete:
move.b 1(a0),(a0)+
bne.s .delete
rts
;D7=position du curseur ds la ligne
.saisie: move #7,-(sp)
trap #1
addq #2,sp
move.l d0,-(sp)
bsr GetShifts
and.w #3,d0
movem.l (sp)+,d0
bne.s .shift
move.b d0,d1
and #$ff,d1
add d1,d1
move .jmp_table(pc,d1),d1
jmp .jmp_table(pc,d1)
.shift: cmp.l #$480038,d0
beq.s .saisie
cmp.l #$500032,d0
beq.s .saisie
cmp.l #$4b0034,d0
beq .s_left
cmp.l #$4d0036,d0
beq .s_right
move.b d0,d1
and #$ff,d1
add d1,d1
move .jmp_table(pc,d1),d1
jmp .jmp_table(pc,d1)
; #[ Jump table:
.jmp_table:
dc.w .special-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.end-.jmp_table,.cut-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table
dc.w .backspace-.jmp_table,.char-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.cr-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table
dc.w .saisie-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.inverse-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table
dc.w .saisie-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.escape-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table,.saisie-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.del-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
dc.w .char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table,.char-.jmp_table
; #] Jump table:
.cr: cmp.l #$72000d,d0
beq.s .enter
bsr .couper
lea 0(a3,d7),a0
moveq #-1,d0
.find_size3:
tst.b (a0)+
dbeq d0,.find_size3
add d0,d5
addq #1,d5
sf 0(a3,d7)
.enter: moveq #-1,d0
rts
.escape: moveq #0,d0
rts
.backspace:
tst.b d5
beq .saisie
tst d7
beq .saisie
lea .cursoff(pc),a0
bsr .prtline
bsr .one_to_left
bsr .couper
bsr .supress_char
lea .savecur(pc),a0
bsr .prtline
subq #1,d5
lea 0(a3,d7),a0
bsr .prtline
lea .restcur(pc),a0
bsr .prtline
lea .curson(pc),a0
bsr .prtline
bra .saisie
.del: tst.b d5
beq .saisie
tst.b 0(a3,d7)
beq .saisie
lea .cursoff(pc),a0
bsr .prtline
bsr .couper
bsr .supress_char
lea .savecur(pc),a0
bsr .prtline
subq #1,d5
lea 0(a3,d7),a0
bsr .prtline
lea .restcur(pc),a0
bsr .prtline
lea .curson(pc),a0
bsr .prtline
bra .saisie
.special:
;d0.b=0 => touche de fonction
swap d0
cmp.b #$4b,d0
beq.s .left
cmp.b #$4d,d0
bne .saisie
.right: bsr .one_to_right
bra .saisie
.left: bsr .one_to_left
bra .saisie
.char: cmp #$ff,d5
beq .saisie
addq #1,d5
move d0,d2
bsr .insert_char
lea .savecur(pc),a0
bsr .prtline
lea .cursoff(pc),a0
bsr .prtline
lea .ctrld(pc),a0
bsr .prtline
lea 0(a3,d7),a0
bsr .prtline
lea .restcur(pc),a0
bsr .prtline
bsr .one_to_right
lea .curson(pc),a0
bsr .prtline
bra .saisie