-
Notifications
You must be signed in to change notification settings - Fork 1
/
evone68k.s
1199 lines (1166 loc) · 21.1 KB
/
evone68k.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
XDEF Eval1,ForEval1,LocEval1,GloEval1,OptEval1
XREF GlobPatchFlag,LocPatchFlag,GetGloVar,GetLocVar
XREF ForceGloVar,ForceLocVar
XREF LValAlloc,GetREquate,CurSection,SecSize,TextSize
XREF DataSize,FindEqu,GetXref
include "comequ.s"
; #[ A faire:
;local en force eval
;recuperer la size des vars ds les exprs en patch
;espace -> erreur
; #] A faire:
POPEVAL1 MACRO
ENDM
;macro pour Eval1 et OptiEval1 (meme retour)
;Inside: d2.B=sign
GEN_EVAL1 MACRO
.loop: moveq #0,d1
move.b (a0)+,d1
add.w d1,d1
move.w .tab(pc,d1.w),d1
jmp .tab(pc,d1.w)
.space: tst.b (a0)
bgt.s .loop
bra errempt1
.parent: moveq #')',d0
move.l a0,d1
.l1: cmp.b (a0)+,d0
bne.s .l1
st -(a0) ;virer parenthese
move.l a2,-(sp)
move.l a0,-(sp)
move.l d1,a0
bsr.s .loop
move.l (sp)+,a2
move.b #')',(a2) ;remettre parenthese
move.l (sp)+,a2 ;a2 initial
add.l #$20000,d1 ;+2 chars
tst.b d1
rts
.minus: tst.b (a0) ;TOKENEOL
bmi.s .rsyn
bsr.s .loop
bmi.s .out
tst.w d1
bne.s .add1
neg.l d0
not.b d2
tst.b d1
rts
.add1: add.l #$10000,d1 ;+1 char
tst.b d1
.out: rts
.rsyn: bra errsyn1
.tilde: tst.b (a0)
bmi.s .rsyn
bsr.s .loop
bmi.s .out
tst.b d1
bne.s .add1
not.l d0
smi d2
tst.b d1
rts
ENDM ;GEN_EVAL1
; #[ Eval1:
;>a0
;<d0,d1
;Evalue un operande.
;if (!backpatch)
;locale: <0+LOC
;equ: <valeur+NOERR
;equr: <valeur+EQUR
;default: <0+GLOB
;else if (backpatch==GLOBALPATCH)
;locale: (impossible)
;equ: <valeur+NOERR (forward equate)
;equr: <error (forward equr)
;default: check globale, <valeur
Eval1:
GEN_EVAL1
.tab: dc.w errempt1-.tab ;0
REPT $19 ;1-19
dc.w errsyn1-.tab ;1
ENDR
dc.w quote1-.tab ;1a TOKENQUOTE
dc.w errsyn1-.tab ;1b
dc.w errsyn1-.tab ;1c
dc.w errsyn1-.tab ;1d
dc.w errsyn1-.tab ;1e
dc.w errsyn1-.tab ;1f
dc.w .space-.tab ;20 ' '
dc.w errsyn1-.tab ;21 !
dc.w quote1-.tab ;22 "
dc.w errsyn1-.tab ;23 #
dc.w hexa1-.tab ;24 $
dc.w bin1-.tab ;25 %
dc.w errsyn1-.tab ;26 &
dc.w quote1-.tab ;27 '
dc.w .parent-.tab ;28 (
dc.w errsyn1-.tab ;29 )
dc.w star1-.tab ;2a *
dc.w .space-.tab ;2b +
dc.w errsyn1-.tab ;2c ,
dc.w .minus-.tab ;2d -
dc.w eval1_loc1-.tab ;2e .
dc.w errsyn1-.tab ;2f /
REPT 10 ;0-9
dc.w dec1-.tab
ENDR
dc.w errsyn1-.tab ;3a :
dc.w errsyn1-.tab ;3b ;
dc.w errsyn1-.tab ;3c <
dc.w errsyn1-.tab ;3d =
dc.w errsyn1-.tab ;3e >
dc.w errsyn1-.tab ;3f ?
dc.w octal1-.tab ;40 @
REPT 26 ;A-Z
dc.w eval1_var1-.tab
ENDR
dc.w errsyn1-.tab ;5b [
dc.w dec1-.tab ;5c \
dc.w errsyn1-.tab ;5d ]
dc.w errsyn1-.tab ;5e ^
dc.w eval1_var1-.tab ;5f _
dc.w errsyn1-.tab ;60 `
REPT 26 ;a-z
dc.w eval1_var1-.tab
ENDR
dc.w errsyn1-.tab ;7b {
dc.w errsyn1-.tab ;7c |
dc.w errsyn1-.tab ;7d }
dc.w .tilde-.tab ;7e ~
dc.w errsyn1-.tab ;7f
REPT $80
dc.w errempt1-.tab ;80-ff
ENDR
; #] Eval1:
; #[ ForEval1:
;>a0
;<d0,d1
;Evalue un operande.
;if (!backpatch)
;locale: <0+LOC
;equ: <valeur+NOERR
;equr: <valeur+EQUR
;default: <0+GLOB
;else if (backpatch==GLOBALPATCH)
;locale: (impossible)
;equ: <valeur+NOERR (forward equate)
;equr: <error (forward equr)
;default: check globale, <valeur
ForEval1:
.loop: moveq #0,d1
move.b (a0)+,d1
add.w d1,d1
move.w .tab(pc,d1.w),d1
jmp .tab(pc,d1.w)
.space: tst.b (a0)
bgt.s .loop
bra errempt1
.parent: moveq #')',d0
move.l a0,d1
.l1: cmp.b (a0)+,d0
bne.s .l1
st -(a0) ;virer parenthese
move.l a2,-(sp)
move.l a0,-(sp)
move.l d1,a0
bsr.s .loop
move.l (sp)+,a2
move.b #')',(a2) ;remettre parenthese
move.l (sp)+,a2 ;a2 initial
tst.b d1
rts
.minus: tst.b (a0) ;TOKENEOL
bmi.s .rsyn
bsr.s .loop
bmi.s .end
tst.w d1
bne.s .erroper
eor.l #$ff0000,d1 ;inv SIGN
tst.w d1
.end: rts
.rsyn: bra errsyn1
.tilde: tst.b (a0) ;TOKENEOL
bmi.s .rsyn
bsr.s .loop
bmi.s .end
tst.w d1
bne.s .erroper
not.l d0
smi d2
swap d1
move.b d2,d1
swap d1
; and.l #$00ffff,d1 ;clr SIGN
tst.w d1
rts
.erroper: moveq #0,d0
moveq #EVAL_OPERR,d1
rts
.errmust: moveq #0,d0
moveq #EVAL_MUSTEVAL,d1
rts
.tab: dc.w errempt1-.tab ;0
REPT $19
dc.w errsyn1-.tab ;1-19
ENDR
dc.w quote1-.tab ;1a TOKENQUOTE
dc.w errsyn1-.tab ;1b
dc.w errsyn1-.tab ;1c
dc.w errsyn1-.tab ;1d
dc.w errsyn1-.tab ;1e
dc.w errsyn1-.tab ;1f
dc.w .space-.tab ;20 ' '
dc.w errsyn1-.tab ;21 !
dc.w quote1-.tab ;22 "
dc.w errsyn1-.tab ;23 #
dc.w hexa1-.tab ;24 $
dc.w bin1-.tab ;25 %
dc.w errsyn1-.tab ;26 &
dc.w quote1-.tab ;27 '
dc.w .parent-.tab ;28 (
dc.w errsyn1-.tab ;29 )
dc.w for_star1-.tab ;2a *
dc.w .space-.tab ;2b +
dc.w errsyn1-.tab ;2c ,
dc.w .minus-.tab ;2d -
dc.w for_loc1-.tab ;2e .
dc.w errsyn1-.tab ;2f /
REPT 10 ;0-9
dc.w dec1-.tab
ENDR
dc.w errsyn1-.tab ;3a :
dc.w errsyn1-.tab ;3b ;
dc.w errsyn1-.tab ;3c <
dc.w errsyn1-.tab ;3d =
dc.w errsyn1-.tab ;3e >
dc.w errsyn1-.tab ;3f ?
dc.w octal1-.tab ;40 @
REPT 26 ;A-Z
dc.w for_var1-.tab
ENDR
dc.w errsyn1-.tab ;5b [
dc.w dec1-.tab ;5c \
dc.w errsyn1-.tab ;5d ]
dc.w errsyn1-.tab ;5e ^
dc.w for_var1-.tab ;5f _
dc.w errsyn1-.tab ;60 `
REPT 26 ;a-z
dc.w for_var1-.tab
ENDR
dc.w errsyn1-.tab ;7b {
dc.w errsyn1-.tab ;7c |
dc.w errsyn1-.tab ;7d }
dc.w .tilde-.tab ;7e ~
dc.w errsyn1-.tab ;7f
REPT $80
dc.w errempt1-.tab ;80-ff
ENDR
; #] ForEval1:
; #[ OptiEval1:
OptEval1:
GEN_EVAL1
.tab: dc.w errempt1-.tab ;0
REPT $19 ;1-19
dc.w errsyn1-.tab ;1
ENDR
dc.w quote1-.tab ;1a TOKENQUOTE
dc.w errsyn1-.tab ;1b
dc.w errsyn1-.tab ;1c
dc.w errsyn1-.tab ;1d
dc.w errsyn1-.tab ;1e
dc.w errsyn1-.tab ;1f
dc.w .space-.tab ;20 ' '
dc.w errsyn1-.tab ;21 !
dc.w quote1-.tab ;22 "
dc.w errsyn1-.tab ;23 #
dc.w hexa1-.tab ;24 $
dc.w bin1-.tab ;25 %
dc.w errsyn1-.tab ;26 &
dc.w quote1-.tab ;27 '
dc.w .parent-.tab ;28 (
dc.w errsyn1-.tab ;29 )
dc.w if_star1-.tab ;2a *
dc.w .space-.tab ;2b +
dc.w errsyn1-.tab ;2c ,
dc.w .minus-.tab ;2d -
dc.w if_loc1-.tab ;2e .
dc.w errsyn1-.tab ;2f /
REPT 10 ;0-9
dc.w if_dec1-.tab
ENDR
dc.w errsyn1-.tab ;3a :
dc.w errsyn1-.tab ;3b ;
dc.w errsyn1-.tab ;3c <
dc.w errsyn1-.tab ;3d =
dc.w errsyn1-.tab ;3e >
dc.w errsyn1-.tab ;3f ?
dc.w octal1-.tab ;40 @
REPT 26 ;A-Z
dc.w if_var1-.tab
ENDR
dc.w errsyn1-.tab ;5b [
dc.w dec1-.tab ;5c \
dc.w errsyn1-.tab ;5d ]
dc.w errsyn1-.tab ;5e ^
dc.w if_var1-.tab ;5f _
dc.w errsyn1-.tab ;60 `
REPT 26 ;a-z
dc.w if_var1-.tab
ENDR
dc.w errsyn1-.tab ;7b {
dc.w errsyn1-.tab ;7c |
dc.w errsyn1-.tab ;7d }
dc.w .tilde-.tab ;7e ~
dc.w errsyn1-.tab ;7f
REPT $80
dc.w errempt1-.tab ;80-ff
ENDR
; #] OptiEval1:
; #[ LocEval1:
;>a0
;<d0,d1
;Evalue un operande.
;if (!backpatch)
;locale: <0+LOC
;equ: <valeur+NOERR
;equr: <valeur+EQUR
;default: <0+GLOB
;else if (backpatch==GLOBALPATCH)
;locale: (impossible)
;equ: <valeur+NOERR (forward equate)
;equr: <error (forward equr)
;default: check globale, <valeur
LocEval1:
.loop: moveq #0,d1
move.b (a0)+,d1
add.w d1,d1
move.w .tab(pc,d1.w),d1
jmp .tab(pc,d1.w)
.space: tst.b (a0)
bgt.s .loop
bra errempt1
.parent: moveq #')',d0
move.l a0,d1
.l1: cmp.b (a0)+,d0
bne.s .l1
st -(a0) ;virer parenthese
move.l a2,-(sp)
move.l a0,-(sp)
move.l d1,a0
bsr.s .loop
move.l (sp)+,a2
move.b #')',(a2) ;remettre parenthese
move.l (sp)+,a2 ;a2 initial
tst.b d1
rts
.minus: tst.b (a0)
bmi.s .rsyn
bsr.s .loop
bmi.s .end
tst.w d1
bne.s .erroper
neg.l d0
bchg #16,d1
tst.w d1
.end: rts
.rsyn: bra errsyn1
.tilde: tst.b (a0)
bmi.s .rsyn
bsr.s .loop
bmi.s .end
tst.w d1
bne.s .erroper
not.l d0
bpl.s .plus
bset #16,d1
tst.w d1
rts
.plus: bclr #16,d1
tst.w d1
rts
.erroper: moveq #0,d0
moveq #EVAL_OPERR,d1
rts
.tab: dc.w errempt1-.tab ;0
REPT $19 ;1-19
dc.w errsyn1-.tab
ENDR
dc.w quote1-.tab ;1a TOKENQUOTE
dc.w errsyn1-.tab ;1b
dc.w errsyn1-.tab ;1c
dc.w errsyn1-.tab ;1d
dc.w errsyn1-.tab ;1e
dc.w errsyn1-.tab ;1f
dc.w .space-.tab ;20 ' '
dc.w errsyn1-.tab ;21 !
dc.w quote1-.tab ;22 "
dc.w errsyn1-.tab ;23 #
dc.w hexa1-.tab ;24 $
dc.w bin1-.tab ;25 %
dc.w errsyn1-.tab ;26 &
dc.w quote1-.tab ;27 '
dc.w .parent-.tab ;28 (
dc.w errsyn1-.tab ;29 )
dc.w cannot-.tab ;2a *
dc.w .space-.tab ;2b +
dc.w errsyn1-.tab ;2c ,
dc.w .minus-.tab ;2d -
dc.w loc_loc1-.tab ;2e .
dc.w errsyn1-.tab ;2f /
REPT 10 ;0-9
dc.w loc_dec1-.tab
ENDR
dc.w errsyn1-.tab ;3a :
dc.w errsyn1-.tab ;3b ;
dc.w errsyn1-.tab ;3c <
dc.w errsyn1-.tab ;3d =
dc.w errsyn1-.tab ;3e >
dc.w errsyn1-.tab ;3f ?
dc.w octal1-.tab ;40 @
REPT 26 ;A-Z
dc.w cannot-.tab
ENDR
dc.w errsyn1-.tab ;5b [
dc.w dec1-.tab ;5c \
dc.w errsyn1-.tab ;5d ]
dc.w errsyn1-.tab ;5e ^
dc.w cannot-.tab ;5f _
dc.w errsyn1-.tab ;60 `
REPT 26 ;a-z
dc.w cannot-.tab
ENDR
dc.w errsyn1-.tab ;7b {
dc.w errsyn1-.tab ;7c |
dc.w errsyn1-.tab ;7d }
dc.w .tilde-.tab ;7e ~
dc.w errsyn1-.tab ;7f
REPT $80
dc.w errempt1-.tab ;80-ff
ENDR
; #] LocEval1:
; #[ GloEval1:
;>a0,a3=@struct EXP
;<d0,d1,d2
;Evalue un operande.
;if (!backpatch)
;locale: <0+LOC
;equ: <valeur+NOERR
;equr: <valeur+EQUR
;default: <0+GLOB
;else if (backpatch==GLOBALPATCH)
;locale: (impossible)
;equ: <valeur+NOERR (forward equate)
;equr: <error (forward equr)
;default: check globale, <valeur
GloEval1:
.loop: moveq #0,d1
move.b (a0)+,d1
add.w d1,d1
move.w .tab(pc,d1.w),d1
jmp .tab(pc,d1.w)
.space: tst.b (a0)
bgt.s .loop
bra errempt1
.parent: moveq #')',d0
move.l a0,d1
.l1: cmp.b (a0)+,d0
bne.s .l1
st -(a0) ;virer parenthese
move.l a2,-(sp)
move.l a0,-(sp)
move.l d1,a0
bsr.s .loop
move.l (sp)+,a2
move.b #')',(a2) ;remettre parenthese
move.l (sp)+,a2 ;a2 initial
tst.b d1
rts
.minus: tst.b (a0)
bmi.s .rsyn
bsr.s .loop
bmi.s .end
tst.w d1
bne.s .roper
neg.l d0
not.b d2
tst.w d1
.end: rts
.rsyn: bra errsyn1
.tilde: tst.b (a0)
bmi.s .rsyn
bsr.s .loop
bmi.s .end
tst.w d1
bne.s .roper
not.l d0
smi d2
tst.w d1
rts
.roper: moveq #0,d0
moveq #EVAL_OPERR,d1
rts
.tab: dc.w errempt1-.tab ;0
REPT $19 ;1-19
dc.w errsyn1-.tab
ENDR
dc.w quote1-.tab ;1a TOKENQUOTE
dc.w errsyn1-.tab ;1b
dc.w errsyn1-.tab ;1c
dc.w errsyn1-.tab ;1d
dc.w errsyn1-.tab ;1e
dc.w errsyn1-.tab ;1f
dc.w .space-.tab ;20 ' '
dc.w errsyn1-.tab ;21 !
dc.w quote1-.tab ;22 "
dc.w errsyn1-.tab ;23 #
dc.w hexa1-.tab ;24 $
dc.w bin1-.tab ;25 %
dc.w errsyn1-.tab ;26 &
dc.w quote1-.tab ;27 '
dc.w .parent-.tab ;28 (
dc.w errsyn1-.tab ;29 )
dc.w glo_star1-.tab ;2a *
dc.w .space-.tab ;2b +
dc.w errsyn1-.tab ;2c ,
dc.w .minus-.tab ;2d -
IFNE ATARI
dc.w glo_loc1-.tab ;2e .
ENDC
IFNE AMIGA
dc.w cannot-.tab
ENDC
dc.w errsyn1-.tab ;2f /
IFNE ATARI
REPT 10 ;0-9
dc.w glo_loc1-.tab
ENDR
ENDC
IFNE AMIGA
REPT 10
dc.w cannot-.tab
ENDR
ENDC
dc.w errsyn1-.tab ;3a :
dc.w errsyn1-.tab ;3b ;
dc.w errsyn1-.tab ;3c <
dc.w errsyn1-.tab ;3d =
dc.w errsyn1-.tab ;3e >
dc.w errsyn1-.tab ;3f ?
dc.w octal1-.tab ;40 @
REPT 26 ;A-Z
dc.w glo_var1-.tab
ENDR
dc.w errsyn1-.tab ;5b [
dc.w dec1-.tab ;5c \
dc.w errsyn1-.tab ;5d ]
dc.w errsyn1-.tab ;5e ^
dc.w glo_var1-.tab ;5f _
dc.w errsyn1-.tab ;60 `
REPT 26 ;a-z
dc.w glo_var1-.tab ;61 a
ENDR
dc.w errsyn1-.tab ;7b {
dc.w errsyn1-.tab ;7c |
dc.w errsyn1-.tab ;7d }
dc.w .tilde-.tab ;7e ~
dc.w errsyn1-.tab ;7f
REPT $80
dc.w errempt1-.tab ;80-ff
ENDR
; #] GloEval1:
; #[ Eval1 routines:
VAR1_REGLIST reg a1 ;-a2
eval1_var1:
move.l a1,-(sp)
move.l a0,a1
subq.w #1,a0
moveq #-1,d2
.gl1: tst.b (a1)+
dble d2,.gl1
neg.w d2
move.w d2,d0
jsr FindEqu ;garb d1/a1
add.w d2,a0
beq.s .patch
move.l d0,a1
move.b VAR_sec(a1),d1
bpl.s .relequ
move.l VAR_value(a1),d0
move.b VAR_type(a1),d1
beq.s .plus ;EQU_EQU et >0
lsl.b #1,d1 ;>0?
bcs.s .moins
.plus: subq.b #EQU_EQUR*2,d1
bpl.s .equr ;ni EQU_EQU,ni EQU_SET
move.l (sp)+,a1
POPEVAL1
sf d2
moveq #EVAL_NOERR,d1
rts
.moins: neg.l d0 ;si negatif seulement EQU ou SET -> pas de verif
move.l (sp)+,a1
POPEVAL1
st d2
moveq #EVAL_NOERR,d1
rts
.patch: move.l d2,d1 ;d2=ffff:expr_size
swap d1
move.l (sp)+,a1
POPEVAL1
addq.b #EVAL_GLO+1,d1
rts
;si c'est 1 set relogeable ,stocker sa valeur
.relequ: move.b VAR_type(a1),d1
beq.s .patch
subq.b #EQU_SET,d1
bne.s .equr
moveq #6,d0
jsr LValAlloc
beq.s .rmem
move.l a0,-(sp)
move.l d0,a0
move.l VAR_value(a1),(a0)+
lsl.b #1,d1
scs (a0)+
move.b VAR_sec(a1),d1
addq.b #1,d1
move.b d1,(a0)+
move.l (sp)+,a0
bra.s .patch ;d0=@table
.equr: ;aussi EQU_REG,EQU_MACRO
move.l (sp)+,a1
POPEVAL1
moveq #EVAL_EQUR,d1
rts
.rmem: move.l (sp)+,a1
POPEVAL1
moveq #EVAL_MEM,d1
rts
eval1_loc1:
moveq #-1,d2
.l1: move.b (a0)+,d0
dble d2,.l1
neg.w d2 ;+ le point
move.l d2,d1
swap d1
POPEVAL1
moveq #0,d0
addq.b #EVAL_LOC+1,d1
rts
star1: moveq #6,d0
jsr LValAlloc
beq.s .errmem
move.l a1,-(sp)
move.l d0,a1
move.l SecSize,(a1)+
move.w CurSection,d1
addq.w #1,d1
move.w d1,(a1) ;SIGN+section
move.l (sp)+,a1
POPEVAL1
move.l #$1ff00+EVAL_GLO,d1
rts
.errmem: POPEVAL1
moveq #EVAL_MEM,d1
rts
; #] Eval1 routines:
; #[ ForEval1 routines:
for_var1:
move.l a1,-(sp)
move.l a0,a1
subq.w #1,a0
moveq #-1,d2
.l1: tst.b (a1)+
dble d2,.l1
neg.w d2
move.w d2,d0
jsr FindEqu ;garb d1/a1
beq.s .equnf
add.w d2,a0
move.l d0,a1
moveq #0,d1
move.b VAR_type(a1),d0
lsl.b #1,d0
scs d1 ;SIGN
subq.b #EQU_EQUR*2,d0
beq.s .errequr
swap d1 ;d1=00:SIGN:00:00
move.b VAR_sec(a1),d1
move.l VAR_value(a1),d0
move.l (sp)+,a1
POPEVAL1
addq.b #1,d1
rts
.equnf: move.w d2,d0
jsr ForceGloVar
add.w d2,a0
beq.s .glonf
moveq #1,d1
add.b VAR_sec(a1),d1
move.l VAR_value(a1),d0
.end: move.l (sp)+,a1
POPEVAL1
tst.l d1
rts
.errequr: moveq #EVAL_COMPEQUR,d1
bra.s .end
.glonf: moveq #EVAL_MUSTEVAL,d1
bra.s .end
for_star1:
POPEVAL1
move.l SecSize,d0
move.w CurSection,d1
addq.b #1,d1
rts
for_loc1: move.l a1,-(sp)
move.l a0,a1
moveq #-1,d2
.l1: tst.b (a1)+
dble d2,.l1
not.w d2
move.w d2,d0
jsr ForceLocVar
add.w d2,a0
beq.s .nf
moveq #1,d1
add.b VAR_sec(a1),d1
move.l VAR_value(a1),d0
.end: POPEVAL1
move.l (sp)+,a1
tst.l d1
rts
.nf: moveq #EVAL_MUSTEVAL,d1
bra.s .end
; #] ForEval1 routines:
; #[ IfEval1 routines:
if_var1: movem.l VAR1_REGLIST,-(sp)
move.l a0,a1
subq.w #1,a0
moveq #-1,d2
.gl1: tst.b (a1)+
dble d2,.gl1
neg.w d2
move.w d2,d0
jsr FindEqu ;garb d1/a1
beq.s .notequ
add.w d2,a0
move.l d0,a1
move.b VAR_sec(a1),d1
bpl.s .relequ
move.l VAR_value(a1),d0
move.b VAR_type(a1),d1
beq.s .plus ;EQU_EQU et >0
lsl.b #1,d1 ;>0?
bcs.s .moins
.plus: subq.b #EQU_EQUR*2,d1
bpl.s .equr ;ni EQU_EQU,ni EQU_SET
POPEVAL1
movem.l (sp)+,VAR1_REGLIST
sf d2
moveq #EVAL_NOERR,d1
rts
.moins: neg.l d0 ;si negatif seulement EQU ou SET -> pas de verif
POPEVAL1
movem.l (sp)+,VAR1_REGLIST
st d2
moveq #EVAL_NOERR,d1
rts
.notequ: move.w d2,d0
jsr ForceGloVar
beq.s .nf
add.w d2,a0
.rel: moveq #0,d1
move.b VAR_sec(a1),d1
addq.b #1,d1
swap d1
POPEVAL1
movem.l (sp)+,VAR1_REGLIST
addq.b #EVAL_OPTI,d1
rts
;c'est 1 equ relogeable (sign=0)
.relequ: move.l VAR_value(a1),d0
cmp.b #EQU_EQUR,VAR_type(a1)
bne.s .rel
.equr: ;aussi EQU_REG,EQU_MACRO
POPEVAL1
movem.l (sp)+,VAR1_REGLIST
moveq #EVAL_EQUR,d1
rts
.nf: move.l d2,d1 ;d2=ffff:expr_size
swap d1
POPEVAL1
movem.l (sp)+,VAR1_REGLIST
addq.b #EVAL_GLO+1,d1
rts
if_loc1: move.l a1,-(sp)
move.l a0,a1
moveq #-1,d2
.l1: tst.b (a1)+
dble d2,.l1
not.w d2
if_force: move.w d2,d0
jsr ForceLocVar
bne.s .found
addq.w #1,d2
add.w d2,a0
move.l d2,d1 ;d2=ffff:expr_size
swap d1
POPEVAL1
move.l (sp)+,a1
addq.b #EVAL_LOC+1,d1
rts
.found: moveq #0,d1
move.b VAR_sec(a1),d1
addq.b #1,d1
swap d1
move.l (sp)+,a1
POPEVAL1
addq.b #EVAL_OPTI,d1
rts
if_star1: move.l SecSize,d0
moveq #EVAL_OPTI,d1
rts
if_dec1: subq.w #1,a0
moveq #0,d1
moveq #0,d0
move.l a1,-(sp)
move.l a0,a1
.l1:
REPT 4
move.b (a0)+,d1
ble.s .decend
sub.b #'0',d1
bmi.s .pardec
cmp.b #9,d1
bgt.s .syndec
move.l d0,d2
lsl.l #3,d0
add.l d2,d2
add.l d2,d0
bcs.s .lgdec
add.l d1,d0
ENDR
bra.s .l1
.decend: move.l (sp)+,a1
POPEVAL1
sf d2
moveq #EVAL_NOERR,d1
rts
.pardec: cmp.b #')'-'0',d1
beq.s .decend
cmp.b #'$'-'0',d1
beq.s .local
.syndec: move.l (sp)+,a1
bra errsyn1
.lgdec: move.l (sp)+,a1
bra errlnum1
.local: ;a1 start,a0 end
move.l a0,d2
sub.l a1,d2
move.l a1,a0
or.l #$ffff0000,d2
bra if_force
; #] IfEval1 routines:
; #[ LocEval1 routines:
loc_dec1: subq.w #1,a0
loc_loc1: move.l a1,-(sp)
move.l a0,a1
moveq #-1,d0
.l1: tst.b (a1)+
dble d0,.l1
not.w d0
jsr GetLocVar
beq.s .nf
IFNE ATARI
tst.b d1
beq.s .end
;local en data/bss resolu en GlobalPatch
move.l d0,d2 ;a2->d2???
moveq #6,d0
jsr LValAlloc
beq.s .errmem
move.l d0,a1
move.l d2,(a1)+
move.w d1,(a1)+ ;BUG move.l!
POPEVAL1
moveq #EVAL_LOCGLO+EVAL_RELOC,d1
move.l (sp)+,a1
rts
ENDC ;ATARI
.end: POPEVAL1
moveq #EVAL_RELOC,d1
move.l (sp)+,a1
rts
.errmem: POPEVAL1
moveq #0,d0
moveq #EVAL_MEM,d1
move.l (sp)+,a1
rts
.nf: POPEVAL1
moveq #EVAL_NFVAR,d1
move.l (sp)+,a1
rts
; #] LocEval1 routines:
; #[ GloEval1 routines:
glo_var1: movem.l d3/a1,-(sp)
moveq #-1,d3
move.l a0,a1
.l1: tst.b (a1)+
dble d3,.l1
neg.w d3
move.w d3,d0
subq.w #1,a0
jsr GetGloVar ;pas touche a0
beq.s .xref
move.b VAR_sec(a1),d1
addq.b #1,d1
move.b VAR_type(a1),d3
smi d2
bpl.s .plus
neg.l d0
and.b #$7f,d3
.plus: bne.s .check
.out: POPEVAL1
movem.l (sp)+,d3/a1
rts
.check: subq.b #EQU_GLOB,d3
beq.s .out
addq.b #EQU_GLOB-EQU_SET,d3
bne.s .errtype ;ni EQU_EQU, ni EQU_SET
.set: move.l EXP_backval(a3),d0
beq.s .fwset
move.l d0,a1
move.l (a1)+,d0
move.b (a1)+,d2
beq.s .pl
neg.l d0
.pl: POPEVAL1
move.b (a1)+,d1
ble.s .out2
move.b d1,d3
subq.b #SEC_data+1,d3
beq.s .plustxt
add.l DataSize,d0
.plustxt: add.l TextSize,d0
.out2: movem.l (sp)+,d3/a1
rts
.errtype: POPEVAL1
moveq #EVAL_TYPE,d1
bra.s .out
.xref: move.w d3,d0
jsr GetXref
beq.s .errvar
swap d0 ;#<<16
move.l d0,d1
st d1 ;undef
POPEVAL1
moveq #0,d0 ;pour le ccr
movem.l (sp)+,d3/a1
rts
.errvar: moveq #EVAL_NFVAR,d1
bra.s .out
.fwset: moveq #EVAL_FW_SET,d1
bra.s .out
glo_star1:
move.l a1,-(sp)
IFNE BLINDOS
move.l EXP_backval(a3),d0
beq.s .bug
move.l d0,a1
ELSEIF
move.l EXP_backval(a3),a1
ENDC ;BLINDOS
move.l (a1)+,d0 ;val
move.w (a1)+,d1 ;section+1
IFNE ATARI