-
Notifications
You must be signed in to change notification settings - Fork 1
/
ataflsh.s
2759 lines (2564 loc) · 48.9 KB
/
ataflsh.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
XDEF FlushPrg
XDEF OutSize,IncbinSize
XREF create_file,write_file,seek_file,rel_seek_file,close_file
XREF LoadBin,MyMalloc,MyMfree,OutMsg
XREF BuildXdef,QsortV
XREF FlshBuf,DbgType,GDbgType,SrcType,EquFFlg,OutName
XREF SecSizes,TextSize,DataSize,BssSize,OutType,BsdOffsets
XREF TxtVarNb,DatVarNb,BssVarNb,LocRelNb
XREF LstBinNb,FstBinPtr
XREF TotExpNb,GloTbl,VarNb,HeadExp,EqusPtr,XrefTbl,XrefNb,XdefTbl,XdefNb
XREF FstModPtr,FstLinrPtr
XREF CurLinrNb,CurLinnNb,TotModNb
include "comequ.s"
section TEXT
; #[ A faire:
;pas de reloc si org
;finir variables en psrc
;pc-rel inter-section en dri & pc
; #] A faire:
; #[ FlushPrg:
FlushPrg: move.l d4,-(sp)
clr.l prg_ssize
clr.l relsize
moveq #0,d0
move.w LstBinNb,d0
bmi.s .norbin
addq.l #1,d0
add.l d0,d0
add.l d0,d0
jsr MyMalloc
move.l d0,BinTbl
beq.s .rmem
bsr.s BldBinTbl
.norbin: move.l IncbinSize,d0
beq.s .norincb
jsr MyMalloc
move.l d0,IncbinPtr
beq.s .rmem
.norincb: lea OutName,a0
bsr create_file
bmi.s .rcrea
move.l d0,d4
bsr.s _flshprg
bne.s .rwrite
.clse: move.l d4,d0
bsr close_file
tst.w LstBinNb
bmi.s .nofbin
move.l BinTbl,a0
jsr MyMfree
.nofbin: tst.l IncbinSize
beq.s .end
move.l IncbinPtr,a0
jsr MyMfree
.end: move.l (sp)+,d4
rts
.rmem: bsr Errfile_ram
bra.s .end
.rcrea: bsr Errfile_create
bra.s .end
.rwrite: bsr Errfile_write
bra.s .clse
;In:d0=@
BldBinTbl:
move.l d0,a0
move.l FstBinPtr,d0
beq.s .end
.l1: move.l d0,(a0)+
move.l d0,a1
move.l BIN_next(a1),d0
bne.s .l1
.end: rts
_flshprg: cmp.w #PURE_OBJ,OutType+2
beq.s .pure
cmp.w #BSD_OBJ,OutType+2
beq.s .bsd
move.l d4,d0
bsr tprgwhdr
bne.s .clse
move.l d4,d0
moveq #SEC_text,d1
bsr flshbin
bne.s .clse
move.l d4,d0
moveq #SEC_data,d1
bsr flshbin
bne.s .clse
cmp.w #DRI_OBJ,OutType+2
beq.s .dri
move.w DbgType,d0
beq.s .nodbg
subq.b #DBG_DRI,d0
bne.s .dbgx
move.l d4,d0
bsr wprgsym ;symbols
bne.s .clse
bra.s .nodbg
.dbgx: move.l d4,d0
bsr wprgsymx
bne.s .clse
.nodbg: move.l d4,d0
bsr writerel
move.l d4,d0
bsr psrcflsh ;src debug
bne.s .clse
.sym: tst.l prg_ssize
beq.s .clse
moveq #0,d0
move.l d4,d1
bsr seek_file
bmi.s .clse
move.l d4,d0
bsr tprgwhdr
.clse: rts
.dri: move.l d4,d0
bsr flshdri ;image+symbols+reloc
bra.s .sym
.pure: move.l d4,d0
bsr purewobj
bra.s .clse
.bsd: move.l d4,d0
bsr bsdwobj
bra.s .clse
; #] FlushPrg:
; #[ flshbin:
;a0=BIN
;d0=handle
;OUT:
;CCR
wincbin: movem.l d3-d4/a2,-(sp)
move.l d0,d4 ;handle
move.l BIN_size(a0),d3
tst.b imgflg
bne.s .img ;if flushing image
move.l BIN_off(a0),d1 ;offset
move.l BIN_name(a0),a0 ;fname
move.l a0,a2 ;???
move.l IncbinPtr,a1 ;@
move.l d3,d0 ;size
bsr LoadBin
bmi.s .err
.img: move.l IncbinPtr,a0
move.l d3,d0
move.l d4,d1
bsr write_file
.end: movem.l (sp)+,d3-d4/a2
rts
.err: bsr Errincbin
bra.s .img
flshbin: movem.l d4-d7/a4,-(sp)
move.l d0,d4
move.w d1,d7
moveq #0,d6
move.l FstBinPtr,d0
beq.s .good
.l1: move.l d0,a4
cmp.w BIN_sec(a4),d7
bne.s .next
move.l BIN_start(a4),d0
bne.s .noinc
move.l a4,a0
move.l d4,d0
bsr wincbin
bne.s .clse
add.l d0,d6
bra.s .next
.noinc: move.l d0,a0
move.l BIN_cur(a4),d0
sub.l a0,d0
add.l d0,d6
move.l d4,d1
bsr write_file
bne.s .clse
.next: move.l BIN_next(a4),d0
bne.s .l1
.good: moveq #0,d0
.clse: add.l d6,OutSize
tst.l d0
movem.l (sp)+,d4-d7/a4
rts
; #] flshbin:
; #[ PRG rel:
;parcourir les exp (deja triees) suivant la section & sauver les abs.l
R_STEP equ 254
R_SEC equr d1
R_LSTOFF equr d3 ;last offset
; equr d4
R_BINNB equr d5 ;# BIN
R_END equr d6 ;@ End buffer
R_EXPNB equr d7 ;# EXP in head
R_BIN equr a1 ;@ BIN
R_HEAD equr a2 ;@ HEAD
R_EXP equr a3 ;@ EXP
R_HANDLE equr a4 ;handle
R_CUR equr a6 ;@ Cur buffer
; #[ reloc1:
;In:
;d1=section
;Sets:
;@ Exp block
;@ Exp
;@ Bin block
;# Bin block
;# EXP #
scanrexp: move.l HeadExp,d0
beq.s .norel
.nxtblk: move.l d0,R_HEAD
move.l HEAD_start(R_HEAD),R_EXP ;fst EXP
move.w HEAD_nb(R_HEAD),R_EXPNB ;#EXP in block
subq.w #1,R_EXPNB
.l1: tst.b EXP_sec(R_EXP)
beq.s .nxt ;no reloc
move.w EXP_patch(R_EXP),d0
cmp.w #P_ABSL,d0
beq.s .rel ;reloc ABSL
cmp.w #P_DCL,d0
beq.s .rel ;and DCL
.nxt: lea EXP_SIZEOF(R_EXP),R_EXP
dbf R_EXPNB,.l1
move.l HEAD_next(R_HEAD),d0
bne.s .nxtblk
.norel: ;moveq #0,d0
rts
.rel: move.w EXP_bin(R_EXP),R_BINNB
IFNE _68000
moveq #0,d0
move.w R_BINNB,d0
add.l d0,d0
add.l d0,d0
move.l BinTbl,a0
move.l 0(a0,d0.l),R_BIN
ELSEIF
move.l ([BinTbl],R_BINNB.w*4),R_BIN
ENDC
.fstbin: cmp.w BIN_sec(R_BIN),R_SEC
bne.s .nxt
move.l BIN_off(R_BIN),a0
add.w EXP_poke(R_EXP),a0 ;new offset
subq.w #4,a0
move.l a0,d0
rts
;but: trouver:
;la 1ere EXP a reloger -> le 1er buffer binaire -> la 1ere section
;Out:
;d0=error/no error=0
;d1=section
getrel1: moveq #SEC_text,R_SEC
bsr scanrexp
bne.s .found
moveq #SEC_data,R_SEC
bsr scanrexp
.found: movem.l d0/d4-d7/a1-a3,rellast ;off,maxsz,bin#,cursz,exp#,head@,exp@,handle,bin@,rel@
move.l d0,(R_CUR)+
moveq #0,d0
rts
;In:
;d1=sec #
;Out:
;d0=error/no error=0
;d1=sec #
resetre1: bsr scanrexp
beq.s .nodata
move.l rellast,d1
movem.l d0/d4-d7/a1-a3,rellast ;off,maxsz,bin#,cursz,exp#,head@,exp@,handle,bin@,rel@
sub.l d1,d0
bra.s newrel
.nodata: clr.l rellast
rts
; #] reloc1:
; #[ reldata: ;reloc data from text
reldata: move.l FstBinPtr,d0
beq.s .good
moveq #SEC_data,d1
move.l TextSize,d2
.l1: move.l d0,a0
cmp.w BIN_sec(a0),d1
bne.s .next
add.l d2,BIN_off(a0)
.next: move.l BIN_next(a0),d0
bne.s .l1
.good: rts
; #] reldata:
; #[ addrel:
addrel: move.b d0,(R_CUR)+
cmp.l R_CUR,R_END
ble.s clserel
moveq #0,d0
rts
clserel: movem.l d1/a1,-(sp)
move.l FlshBuf,a0
move.l a0,-(sp)
move.l R_HANDLE,d1
move.l R_CUR,d0
sub.l a0,d0
add.l d0,relsize
bsr write_file
move.l (sp)+,R_CUR
movem.l (sp)+,d1/a1
rts
; #] addrel:
; #[ newrel:
;Input:
;d0:relative offset
newrel: move.l d3,-(sp)
move.l d0,d3
.nxtmult: sub.l #R_STEP,d3 ;-254
bmi.s .rel
beq.s .254
moveq #1,d0 ;write overflow=1
bsr addrel
bne.s .end
bra.s .nxtmult
.254: move.b #R_STEP,d3
bra.s .single
.rel: add.l #R_STEP,d3 ;+254
.single: move.b d3,d0 ;write offset (byte)
bsr addrel
.end: movem.l (sp)+,d3
rts
; #] newrel:
; #[ calcrel:
calcrel: cmp.w EXP_bin(R_EXP),R_BINNB
bne.s .newbin ;not same bin buffer
.goodbin: tst.b EXP_sec(R_EXP)
beq.s .next ;no reloc
move.w EXP_patch(R_EXP),d0
cmp.w #P_ABSL,d0
beq.s .dorel ;reloc ABSL
cmp.w #P_DCL,d0
bne.s .next ;and DCL
.dorel: move.l BIN_off(R_BIN),a0
add.w EXP_poke(R_EXP),a0 ;new offset
subq.w #4,a0
move.l a0,d0 ;ressort dans a0 et d0
.rel: moveq #1,d1
rts
.next: moveq #-1,d1
rts
IFNE BLINDOS
.err: _Debugger
ENDC BLINDOS
.nomore: moveq #0,d1
rts
.newbin: move.w BIN_sec(R_BIN),R_SEC ;required section
.nxtbin: move.w EXP_bin(R_EXP),R_BINNB
IFNE _68000
moveq #0,d0
move.w R_BINNB,d0
add.l d0,d0
add.l d0,d0
move.l BinTbl,a0
move.l 0(a0,d0.l),R_BIN
ELSEIF
move.l ([BinTbl],R_BINNB.w*4),R_BIN
ENDC
.cmpbin: cmp.w BIN_sec(R_BIN),R_SEC ;is it?
beq.s .goodbin
.l2: cmp.w EXP_bin(R_EXP),R_BINNB
bne.s .nxtbin ;not same bin buffer
lea EXP_SIZEOF(R_EXP),R_EXP
dbf R_EXPNB,.l2
move.l HEAD_next(R_HEAD),d0
beq.s .nomore
move.l d0,R_HEAD
move.l HEAD_start(R_HEAD),R_EXP ;fst EXP
move.w HEAD_nb(R_HEAD),R_EXPNB ;#EXP in block
subq.w #1,R_EXPNB
bra.s .l2
; #] calcrel:
; #[ flshrel:
;Input:
;d1:section
flshrel: movem.l rellast,d3-d7/a1-a3 ;off,maxsz,bin#,exp#,cursz,bin@,head@,exp@
bra.s .next
.nxtblk: move.l d0,R_HEAD
move.l HEAD_start(R_HEAD),R_EXP ;fst EXP
move.w HEAD_nb(R_HEAD),R_EXPNB ;#EXP in block
subq.w #1,R_EXPNB
.nxtEXP: bsr calcrel
bmi.s .next
beq.s .endEXP
sub.l R_LSTOFF,d0 ;moins l'offset d'avant
IFNE BLINDOS
ble.s .err
ENDC BLINDOS
move.l a0,R_LSTOFF ;next entry offset
bsr newrel
bne.s .end
.next: lea EXP_SIZEOF(R_EXP),R_EXP
dbf R_EXPNB,.nxtEXP
move.l HEAD_next(R_HEAD),d0
bne.s .nxtblk
.endEXP: moveq #0,d0
.end: move.l R_LSTOFF,rellast
tst.l d0
rts
IFNE BLINDOS
.err: _Debugger
bra.s .endEXP
ENDC BLINDOS
; #] flshrel:
; #[ endrel:
endrel: bsr clserel
bne.s .end
btst #0,relsize+3
bne.s .odd
.end: rts
.odd: moveq #0,d0 ;even
bsr addrel
bne.s .end
bra clserel
; #] endrel:
; #[ writerel:
writerel: movem.l d3-d7/a2-a4/a6,-(sp)
move.l d0,R_HANDLE ;file handle
bsr reldata
move.l FlshBuf,R_CUR ;rel buf @
move.l R_CUR,R_END
add.l #FLSHBUF_SIZE,R_END ;rel end @
bsr getrel1 ;1st reloc
bne.s .clse
tst.l rellast
beq.s .norel
tst.w d1 ;SEC_text
bne.s .notext
;moveq #SEC_text,d1
bsr flshrel ;text reloc
bne.s .clse
moveq #SEC_data,d1 ;reset data
bsr resetre1
bne.s .clse
tst.l rellast
beq.s .endrel
.notext: ;moveq #SEC_data,d1
bsr flshrel ;data reloc
bne.s .clse
.endrel: moveq #0,d0 ;0.b
bsr addrel ;write last zero
bne.s .clse
.norel: bsr endrel
bne.s .clse
move.l relsize,d0
add.l d0,OutSize
moveq #0,d0
.clse: movem.l (sp)+,d3-d7/a2-a4/a6
rts
; #] writerel:
; #] PRG rel:
; #[ DRI prg:
; #[ tprgwhdr:
tprgwhdr:
move.l d0,d1
lea prg_hdr,a0
move.l a0,a1
move.w #$601a,(a1)+
move.l TextSize,(a1)+
move.l DataSize,(a1)+
move.l BssSize,(a1)+
; clr.l (a1)+ ;symsize
; clr.l (a1)+ ;res1
; clr.l (a1)+ ;flags
; clr.w (a1)+ ;res2
moveq #$1c,d0
bra write_file
; #] tprgwhdr:
; #[ wprgsym:
;rajouter les regs?
wprgsym: movem.l d3-d7/a2-a4,-(sp)
move.l d0,d4
moveq #0,d6 ;taille totale symboles
move.l GloTbl,a2
lea -14(sp),sp
move.l sp,a4
; lea SecSizes,a0
; lea .reltab+4(pc),a1
; move.l SEC_text(a0),d0
; move.l d0,(a1)+
; add.l SEC_data(a0),d0
; move.l d0,(a1)+
move.l VarNb,d7
beq.s .end
.l0: move.l (a2)+,a3
moveq #0,d2
move.b VAR_sec(a3),d2
bmi.s .nx_var ;offset
move.l VAR_start(a3),a0 ;name
move.w VAR_len(a3),d0
move.l a4,a1
bsr cpy8sym
lea 8(a4),a1
move.w .symtab+2(pc,d2.w),(a1)+
move.l VAR_value(a3),d0
add.l .reltab(pc,d2.w),d0 ;data|bss
move.l d0,(a1)+
move.l a4,a0
moveq #14,d0
move.l d4,d1
bsr write_file
bne.s .clse
add.l #14,d6
.nx_var: subq.l #1,d7
bgt.s .l0
.end: move.l d6,prg_ssize
moveq #0,d0
.clse: lea 14(sp),sp
movem.l (sp)+,d3-d7/a2-a4
rts
.symtab: dc.l $8200,$8400,$8100,$c000
.reltab: ds.l 4 ;text/data/bss/equ
; #] wprgsym:
; #[ wprgsymx:
wprgsymx: movem.l d3-d7/a2-a4,-(sp)
move.l d0,d4
moveq #0,d6 ;taille totale symboles
move.l GloTbl,a2
lea -28(sp),sp
move.l sp,a4
; lea SecSizes,a0
; lea .reltab+4(pc),a1
; move.l SEC_text(a0),d0
; move.l d0,(a1)+
; add.l SEC_data(a0),d0
; move.l d0,(a1)+
move.l VarNb,d7
beq .end
.l0: move.l (a2)+,a3
moveq #0,d2
move.b VAR_sec(a3),d2
bmi.s .nx_var ;skip offset
.ok: move.l VAR_start(a3),a0
move.l a4,a1
moveq #14,d5 ;dri
move.w VAR_len(a3),d0
cmp.w #8,d0
blt.s .clrdri
beq.s .cpydri
moveq #28,d5 ;h
moveq #8-1,d0
bra.s .l2
.clrdri: clr.l (a1)
clr.l 4(a1)
.cpydri: subq.w #1,d0
.l2: move.b (a0)+,(a1)+
dbf d0,.l2
lea 8(a4),a1
move.w .symtab+2(pc,d2.w),d0
cmp.w #14,d5
beq.s .noth
move.b #$48,d0
.noth: move.w d0,(a1)+
; move.l VAR_value(a3),d0
; add.l .reltab(pc,d2.w),d0 ;data|bss
; move.l d0,(a1)+
move.l VAR_value(a3),(a1)+
cmp.w #14,d5
beq.s .write
move.w VAR_len(a3),d0
subq.w #8,d0
cmp.w #14,d0
blt.s .clrh
beq.s .cpyh
moveq #14-1,d0
bra.s .l3
.clrh:
REPT 3
clr.l (a1)+
ENDR
clr.w (a1)
.cpyh: lea 14(a4),a1
subq.w #1,d0
.l3: move.b (a0)+,(a1)+
dbf d0,.l3
.write: move.l a4,a0
move.l d5,d0
move.l d4,d1
bsr write_file
bne.s .clse
add.l d5,d6
.nx_var: subq.l #1,d7
bgt .l0
.end: move.l d6,prg_ssize
moveq #0,d0
.clse: lea 28(sp),sp
movem.l (sp)+,d3-d7/a2-a4
rts
.symtab: dc.l $8200,$8400,$8100,$c000 ;org=equ
.reltab: ds.l 4 ;text/data/bss/equ
; #] wprgsymx:
; #] DRI prg:
; #[ DRI obj:
; #[ clrbin:
;Strategie:
;ecrire les symboles dans un ordre fixe ({XREF+XDEF}|{XREF+SYM})
;(ajouter eventuellement les equ et reg)
;vider binaire+incbin
;marquer les binaires avec les EXP, section connue ou # xref
;ecrire le tout
;0:BSS
;1:TEXT
;2:DATA
;3:undefined
;4:reglist
;5:global
;6:constant
;7:defined
clrbin: move.l FstBinPtr,d0
beq.s .good
.l1: move.l d0,a1
move.l BIN_start(a1),d0
beq.s .next
move.l d0,a0
move.l BIN_cur(a1),d0
sub.l a0,d0
.l2: clr.b (a0)+
subq.l #1,d0
bgt.s .l2
.next: move.l BIN_next(a1),d0
bne.s .l1
.good: rts
; #] clrbin:
; #[ clrinc:
clrinc: move.l IncbinSize,d0
beq.s .good
move.l IncbinPtr,a0
lsr.l #1,d0
beq.s .one
bcs.s .odd
.l1: clr.w (a0)+
subq.l #1,d0
bne.s .l1
.good: rts
.odd: clr.w (a0)+
subq.l #1,d0
bne.s .odd
.one: clr.b (a0)+
rts
; #] clrinc:
; #[ bdriimg:
;d7/d6
;a2/a3
bdriimg: movem.l d3-d7/a2-a5,-(sp)
moveq #0,d6 ;reloc size
move.l HeadExp,d0
beq.s .endEXP
moveq #0,d5
move.l FstBinPtr,a5
move.l BIN_start(a5),d4
.nxtblk: move.l d0,a2
move.l HEAD_start(a2),a3 ;fst EXP
move.w HEAD_nb(a2),d7 ;#EXP in block
subq.w #1,d7
; bmi.s .endEXP
.nxtEXP: cmp.w EXP_bin(a3),d5
bne.s .newbin
.samebin: move.l d4,a1
add.w EXP_poke(a3),a1 ;where to poke
tst.b EXP_sec(a3)
beq.s .next ;no reloc
bmi.s .xref ;xref
move.w EXP_patch(a3),d0
cmp.w #P_D8PC,d0
bge.s .dopc
.asabs: cmp.w #P_ABSL,d0
beq.s .dorel ;reloc ABSL
cmp.w #P_DCL,d0
bne.s .next ;and DCL
.dorel: moveq #0,d0
move.b EXP_sec(a3),d0
subq.w #1,d0 ;section--(reloc)
move.l .tabsec(pc,d0.w),-4(a1)
.next: lea EXP_SIZEOF(a3),a3
dbf d7,.nxtEXP
move.l HEAD_next(a2),d0
bne.s .nxtblk
.endEXP: movem.l (sp)+,d3-d7/a2-a5
rts
.tabsec: dc.l $50002,$50001,$50003 ;TEXT,DATA,BSS
IFNE BLINDOS
.err: _Debugger
ENDC BLINDOS
.newbin: move.w EXP_bin(a3),d5
IFNE _68000
moveq #0,d1
move.w d5,d1
add.l d1,d1
add.l d1,d1
move.l BinTbl,a1
move.l 0(a1,d1.l),a5
ELSEIF
move.l ([BinTbl],d5.w*4),a5
ENDC ;_68000
move.l BIN_start(a5),d4
bra.s .samebin
.dopc: move.w BIN_sec(a5),d0 ;sec(sym)!=sec(bin)?asxref:asabs
addq.w #1,d0
cmp.b EXP_sec(a3),d0
beq.s .asabs
.xref: move.w EXP_patch(a3),d0
move.w .tab(pc,d0.w),d0 ;deja *2
jmp .tab(pc,d0.w)
.reloc: moveq #5,d0
swap d0
move.w EXP_varnb(a3),d0
lsl.w #3,d0 ;*8
addq.w #4,d0 ;+4
move.l d0,-4(a1)
bra.s .next
.relpc: move.w EXP_varnb(a3),d0
lsl.w #3,d0 ;*8
addq.w #6,d0 ;+6
move.w d0,-2(a1)
bra.s .next
.relbdpc: move.w EXP_varnb(a3),d0
lsl.w #3,d0 ;*8
addq.w #6,d0 ;+6
move.w d0,(a1)
bra .next
.tab: dc.w .rrel-.tab ;P_W911
dc.w .rrel-.tab ;P_EA1
dc.w .rrel-.tab ;P_BIT8
dc.w .rrel-.tab ;P_BIT32
dc.w .rrel-.tab ;P_W07
dc.w .rrel-.tab ;P_W05
dc.w .rrel-.tab ;P_W610
dc.w .rrel-.tab ;P_W02
dc.w .rrel-.tab ;P_L02
dc.w .rrel-.tab ;P_L1012
dc.w .rrel-.tab ;P_W03
dc.w .rrel-.tab ;P_L06
dc.w .rrel-.tab ;P_K06
dc.w .rrel-.tab ;P_L57
dc.w .rrel-.tab ;P_FTRAPW
dc.w .rrel-.tab ;P_FTRAPL
dc.w .rrel-.tab ;P_D8
dc.w .rrel-.tab ;P_D16
dc.w .rrel-.tab ;P_ABSB
dc.w .rrel-.tab ;P_ABSW
dc.w .reloc-.tab ;P_ABSL
dc.w .rrel-.tab ;P_DCB
dc.w .rrel-.tab ;P_DCW
dc.w .reloc-.tab ;P_DCL
dc.w .rpcb-.tab ;P_PCD8
dc.w .relpc-.tab ;P_D16PC
dc.w .relpc-.tab ;P_DBCC
dc.w .rpcb-.tab ;P_BCCB
dc.w .relpc-.tab ;P_BCCW
dc.w .rpcl-.tab ;P_BCCL
dc.w .relbdpc-.tab ;P_BDPCW
dc.w .rpcl-.tab ;P_BDPCL
.rpcb:
.rpcl:
.rrel:
IFNE BLINDOS
_Debugger
ENDC
bra .next
; #] bdriimg:
; #[ wdrixref:
wdrixref: movem.l d3-d7/a2-a4,-(sp)
move.l d0,d4
move.w #%10001000<<8,d5 ;xref=defined+undefined
moveq #0,d6 ;sym size
move.l XrefTbl,a2
lea -14(sp),sp
move.l sp,a4
move.l XrefNb,d7
beq.s .good
.l0: move.l (a2)+,a3 ;get var
move.l VAR_start(a3),a0 ;name
move.w VAR_len(a3),d0 ;name length
move.l a4,a1
bsr cpy8sym
lea 8(a4),a1
move.w d5,(a1)+
move.l VAR_value(a3),(a1)+ ;sym value
move.l a4,a0
moveq #14,d0 ;sym length
move.l d4,d1
bsr write_file
bne.s .clse
add.l #14,d6
.nx_var: subq.l #1,d7
bgt.s .l0
add.l d6,prg_ssize
.good: moveq #0,d0
.clse: lea 14(sp),sp
movem.l (sp)+,d3-d7/a2-a4
rts
; #] wdrixref:
; #[ wdrixdef:
wdrixdef: movem.l d3-d7/a2-a4,-(sp)
move.l d0,d4
move.w #%10100000<<8,d5 ;xdef=defined+global
moveq #0,d6 ;sym size
move.l XdefTbl,a2
lea -14(sp),sp
move.l sp,a4
move.l XdefNb,d7
beq.s .good
.l0: move.l (a2)+,a3 ;get var
move.l VAR_start(a3),a0 ;name
move.w VAR_len(a3),d0 ;name length
move.l a4,a1
bsr.s cpy8sym
lea 8(a4),a1
move.b VAR_sec(a3),d0
and.w #%1100,d0
move.w .tab+2(pc,d0.w),(a1)
or.w d5,(a1)+
move.l VAR_value(a3),(a1)+ ;sym value
move.l a4,a0
moveq #14,d0 ;sym length
move.l d4,d1
bsr write_file
bne.s .clse
add.l #14,d6
.nx_var: subq.l #1,d7
bgt.s .l0
add.l d6,prg_ssize
.good: moveq #0,d0
.clse: lea 14(sp),sp
movem.l (sp)+,d3-d7/a2-a4
rts
.tab: dc.l 2<<8,4<<8,1<<8,64<<8 ;bit 0,1,2,6(section=equ)
; #] wdrixdef:
; #[ cpy8sym:
;In:
;a0=src
;a1=dst
;d0=len
cpy8sym: cmp.w #8,d0
blt.s .clr
beq.s .cpy
moveq #8-1,d0
.l1: move.b (a0)+,(a1)+
dbf d0,.l1
bra.s .s1
.clr: addq.w #8,a1
clr.l -(a1)
clr.l -(a1)
.cpy: subq.w #1,d0
.l2: move.b (a0)+,(a1)+
dbf d0,.l2
.s1: rts
; #] cpy8sym:
; #[ wdrisym:
wdrisym: movem.l d3-d7/a2-a4,-(sp)
move.l d0,d4
move.w #%10000000<<8,d5 ;sym=defined
moveq #0,d6 ;sym size
move.l GloTbl,a2
lea -14(sp),sp
move.l sp,a4
move.l VarNb,d7
beq.s .good
.l0: move.l (a2)+,a3
move.l VAR_start(a3),a0
move.w VAR_len(a3),d0 ;name length
move.l a4,a1
bsr cpy8sym
lea 8(a4),a1
move.b VAR_sec(a3),d0
and.w #%1100,d0
move.w .tab+2(pc,d0.w),d0 ;sym type
btst #VAR_DEFED,VAR_type(a3)
beq.s .noxdef
bset #5+8,d0 ;xdef=global
.noxdef: or.w d5,d0
move.w d0,(a1)+
move.l VAR_value(a3),(a1)+ ;sym value
move.l a4,a0
moveq #14,d0 ;sym length
move.l d4,d1
bsr write_file
bne.s .clse
add.l #14,d6
.nx_var: subq.l #1,d7
bgt.s .l0
add.l d6,prg_ssize
.good: moveq #0,d0
.clse: lea 14(sp),sp
movem.l (sp)+,d3-d7/a2-a4
rts
.tab: dc.l 2<<8,4<<8,1<<8,$c000 ;bit 0,1,2,6(section=equ)
; #] wdrisym:
; #[ wdriequ:
;wdriequ: movem.l d3-d7/a2-a5,-(sp)
; move.l d0,d4
; move.w #%11000000<<8,d5 ;equ=defined+constant
; moveq #0,d6 ;sym size
; lea -14(sp),sp
; move.l sp,a4
; move.l EqusPtr,d0
; beq.s .good
;.l0: move.l d0,a5
; move.l EQUL_block(a5),a3
; move.w EQUL_nb(a5),d7
; subq.w #1,d7
;.l1: move.l (a3)+,a2
; move.b VAR_type(a2),d0
; subq.b #EQU_SET,d0
; bgt.s .nx_var
; move.l a4,a1
; move.l VAR_start(a2),a0
; move.w VAR_len(a2),d0 ;name length
; bsr cpy8sym
; lea 8(a4),a1
; move.w d5,(a1)+
; move.l VAR_value(a2),(a1)+ ;eq value
; move.l a4,a0
; moveq #14,d0 ;sym length
; move.l d4,d1
; bsr write_file
; bne.s .clse
; add.l #14,d6
;.nx_var: dbf d7,.l1
; move.l EQUL_next(a5),d0
; bne.s .l0
; add.l d6,prg_ssize
;.good: moveq #0,d0
;.clse: lea 14(sp),sp
; movem.l (sp)+,d3-d7/a2-a5
; rts
; #] wdriequ:
; #[ flshdri:
;In:d0.l=handle
flshdri: move.l d4,-(sp)
tst.w XrefNb ;<65536
bne.s .rvar
move.l d0,d4
; move.l d4,d0
bsr wdrixref
bne.s .clse
jsr BuildXdef
move.l d4,d0
tst.w DbgType
bne.s .dbg
bsr wdrixdef
bne.s .clse
bra.s .s1
.dbg: bsr wdrisym
bne.s .clse
; tst.b EquFFlg
; beq.s .s1
; move.l d4,d0
; bsr wdriequ
; bne.s .clse
.s1: bsr clrbin
bsr clrinc
bsr bdriimg