forked from Digitaler-Impfnachweis/covpass-android
-
Notifications
You must be signed in to change notification settings - Fork 0
/
dependencies.gradle
219 lines (181 loc) · 8.36 KB
/
dependencies.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
/*
* (C) Copyright IBM Deutschland GmbH 2021
* (C) Copyright IBM Corp. 2021
*/
dependencies {
ext {
// ------------------------------------------------------------------------------------------------
// Expose correct dependency version constraints, so our dependents can
// leave out the version number and automatically get the correct version.
// Additionally, we ensure a consistent set of versions here.
// ------------------------------------------------------------------------------------------------
versionConstraints = {
api platform("org.jetbrains.kotlinx:kotlinx-coroutines-bom:1.5.2")
api platform("io.ktor:ktor-bom:1.6.3")
api platform("com.ensody.reactivestate:reactivestate-bom:4.3.2")
api platform("com.squareup.okhttp3:okhttp-bom:4.9.1")
constraints {
// While kotlin-stdlib and kotlin-stdlib-common are automatically set by the gradle plugin,
// a few older dependencies still want kotlin-stdlib-jdk7 or kotlin-reflect based on a different Kotlin
// version. Make everything consistent and prevent compilation warnings.
api "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
api "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
api "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
api "org.conscrypt:conscrypt-android:2.5.2"
def bouncyCastleVersion = "1.69"
api "org.bouncycastle:bcprov-jdk15to18:$bouncyCastleVersion"
api "org.bouncycastle:bcprov-jdk15on:$bouncyCastleVersion"
api "org.bouncycastle:bcmail-jdk15to18:$bouncyCastleVersion"
api "org.bouncycastle:bcmail-jdk15on:$bouncyCastleVersion"
api "org.bouncycastle:bcpkix-jdk15to18:$bouncyCastleVersion"
api "org.bouncycastle:bcpkix-jdk15on:$bouncyCastleVersion"
api "com.upokecenter:cbor:4.4.3"
api "com.augustcellars.cose:cose-java:1.1.0"
}
}
// ------------------------------------------------------------------------------------------------
testDependency = { dependency ->
if (project.name.endsWith("-test")) {
api dependency
} else {
testImplementation dependency
}
}
base = {
versionConstraints()
testDependency "junit:junit:4.13.2"
testDependency "org.jetbrains.kotlin:kotlin-test-junit"
testDependency "org.jetbrains.kotlinx:kotlinx-coroutines-test"
testDependency "io.mockk:mockk:1.12.0"
}
fragmentVersion = "1.3.6"
baseAndroid = {
base()
api "androidx.annotation:annotation:1.2.0"
api "androidx.core:core-ktx:1.6.0"
testImplementation("org.robolectric:robolectric:4.6.1") {
exclude group: "org.bouncycastle"
}
testImplementation "org.bouncycastle:bcprov-jdk15to18"
testImplementation "org.bouncycastle:bcpkix-jdk15to18"
testDependency "androidx.arch.core:core-testing:2.1.0"
testDependency "androidx.fragment:fragment-testing:$fragmentVersion"
def androidxTestVersion = "1.3.0"
testDependency "androidx.test:core:$androidxTestVersion"
testDependency "androidx.test:core-ktx:$androidxTestVersion"
testDependency "androidx.test:runner:$androidxTestVersion"
testDependency "androidx.test:rules:$androidxTestVersion"
testDependency "androidx.test.ext:junit:1.1.2"
testDependency "androidx.test.ext:junit-ktx:1.1.2"
}
reactiveState = {
api "com.ensody.reactivestate:reactivestate"
testDependency "com.ensody.reactivestate:reactivestate-test"
}
activityVersion = "1.3.1"
androidUI = {
baseAndroid()
coroutines()
api "com.google.android.material:material:1.4.0"
api "androidx.appcompat:appcompat:1.3.1"
api "androidx.activity:activity-ktx:$activityVersion"
api "androidx.fragment:fragment-ktx:$fragmentVersion"
api "androidx.window:window:1.0.0-alpha09"
def lifecycleVersion = "2.3.1"
api "androidx.lifecycle:lifecycle-livedata-ktx:$lifecycleVersion"
api "androidx.lifecycle:lifecycle-runtime-ktx:$lifecycleVersion"
api "androidx.lifecycle:lifecycle-viewmodel-ktx:$lifecycleVersion"
api "androidx.lifecycle:lifecycle-viewmodel-savedstate:$lifecycleVersion"
constraints {
api "androidx.lifecycle:lifecycle-common-java8:$lifecycleVersion"
api "androidx.lifecycle:lifecycle-service:$lifecycleVersion"
api "androidx.lifecycle:lifecycle-process:$lifecycleVersion"
}
api "androidx.constraintlayout:constraintlayout:2.1.0"
api "com.airbnb.android:lottie:4.1.0"
}
conscrypt = {
api "org.conscrypt:conscrypt-android"
}
coroutines = {
api "org.jetbrains.kotlinx:kotlinx-coroutines-core"
testImplementation "org.jetbrains.kotlinx:kotlinx-coroutines-test"
}
timber = {
implementation "com.jakewharton.timber:timber:5.0.1"
}
ktor = {
coroutines()
api "io.ktor:ktor-client-core"
api "io.ktor:ktor-client-android"
api "io.ktor:ktor-client-json-jvm"
api "io.ktor:ktor-client-okhttp"
api "io.ktor:ktor-client-serialization"
api "com.squareup.okhttp3:okhttp"
api "com.squareup.okhttp3:logging-interceptor"
testImplementation "io.ktor:ktor-client-mock-jvm"
}
coseJava = {
api("com.augustcellars.cose:cose-java") {
exclude group: "org.bouncycastle"
}
bouncyCastle()
}
bouncyCastle = {
api "org.bouncycastle:bcprov-jdk15to18"
api "org.bouncycastle:bcpkix-jdk15to18"
}
zxing = {
api "com.journeyapps:zxing-android-embedded:4.2.0"
api "com.google.zxing:core:3.4.1"
}
camerax = {
def camerax_version = "1.0.2"
api "androidx.camera:camera-core:${camerax_version}"
api "androidx.camera:camera-camera2:${camerax_version}"
api "androidx.camera:camera-lifecycle:${camerax_version}"
api 'androidx.camera:camera-view:1.0.0-alpha30'
}
def boofCVVersion = "0.39.1"
boofCV = {
api("org.boofcv:boofcv-core:$boofCVVersion") {
exclude group: "xmlpull", module: "xmlpull"
exclude group: "org.apache.commons", module: "commons-compress"
exclude group: "com.thoughtworks.xstream", module: "commons-compress"
}
api "org.boofcv:boofcv-android:$boofCVVersion"
}
boofCVTest = {
testDependency "org.boofcv:boofcv-core:$boofCVVersion"
testDependency "org.boofcv:boofcv-android:$boofCVVersion"
}
cryptographic = {
api "androidx.security:security-crypto:1.1.0-alpha03"
}
kotlinxSerialization = {
def kotlinxSerializationVersion = "1.3.0"
api "org.jetbrains.kotlinx:kotlinx-serialization-core:$kotlinxSerializationVersion"
api "org.jetbrains.kotlinx:kotlinx-serialization-cbor:$kotlinxSerializationVersion"
api "org.jetbrains.kotlinx:kotlinx-serialization-json:$kotlinxSerializationVersion"
}
worker = {
api "androidx.work:work-runtime-ktx:2.5.0"
}
certLogic = {
api "eu.ehn.dcc.certlogic:certlogic-kotlin:v0.9.0-kotlin"
api "com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.12.5"
}
inAppUpdate = {
api "com.google.android.play:core-ktx:1.8.1"
}
room = {
def roomVersion = "2.3.0"
api "androidx.room:room-ktx:$roomVersion"
api "androidx.room:room-runtime:$roomVersion"
kapt "androidx.room:room-compiler:$roomVersion"
}
clockSync = {
api "com.github.instacart.truetime-android:library:3.4"
}
}
}