-
Notifications
You must be signed in to change notification settings - Fork 0
/
pong.nlogo
1467 lines (1238 loc) · 29.8 KB
/
pong.nlogo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
extensions [table csv]
globals [
paddle-size ;; size of the paddles [ default 5 ]
score-1 ;; score player 1
score-2 ;; score player 2
round-over? ;; check if the round is over
step
curr-state ;; current state
curr-episode ;; current episode number
curr-reward ;; current reward
;; learning parameters
epsilon
min-epsilon ;; min exploration rate
max-epsilon ;; max exploration rate
decay-rate ;; decay rate epsilon
quality ;; quality matrix
;; metrics
steps-per-episode ;; steps per episode
reward-per-episode ;; reward per episode
reward-smooth ;; needed for the smooth plot of reward per episode
reward-smooth-list ;; needed for the smooth plot of reward per episode
avg-reward-per-episode ;; the sum of all the reward per episode
bounces-per-round ;; number of bounces on the paddles in a round
bounces-per-episode ;; average number of bounces on the paddles of all steps in a episode
avg-bounces ;; average bounces per point
avg-bounces-smooth ;; needed for the smooth plot of average bounces per point
avg-bounces-smooth-list ;; needed for the smooth plot of average bounces per point
avg-bounces-per-episode ;; the sum of all the paddle-bounces per episode
score-smooth
score-smooth-list
test-avg-score
test-std-score
]
breed [balls ball]
breed [paddles paddle]
paddles-own [
id ;; player 1 or 2
;xcor ;; x coordinate of paddle
;ycor ;; y coordinate of paddle
]
balls-own [
id ;; ball's id
;xcor ;; x coordinate of ball
;ycor ;; y coordinate of ball
;heading ;; direction of ball
]
;; SETUP -----------------------------------------------------------------
to setup
clear-all
set-default-shape balls "circle"
set-default-shape paddles "paddle"
set score-1 0
set score-2 0
set round-over? true
set paddle-size 3
set smoother 50
;; setup-episode
set epsilon 1
set random-move-prob 0.3
set episodes 5000
set min-epsilon 0.01
set max-epsilon 1.0
set decay-rate 0.0005
set curr-episode 0
set step 0
set gamma 0.9
set lr 0.1
set avg-bounces []
set avg-bounces-smooth []
set avg-bounces-smooth-list []
set reward-per-episode 0
set reward-smooth []
set reward-smooth-list []
set score-smooth []
set score-smooth-list []
set curr-state (list 0 0 0)
if state-type = "with-opponent-x" [
set curr-state (list 0 0 0 0)
]
set quality table:make
init-quality
setup-turtles
setup-ball
reset-ticks
end
;; init the paddles to their side of the field centered
to setup-turtles
ask paddles [die] ;; destroy previous paddles
;; player 1 - learning agent
create-paddles 1 [
setxy 0 (min-pycor + 1)
set id 1
set size paddle-size
set color red
]
;; player 2 - random agent
create-paddles 1 [
setxy 0 (max-pycor - 1)
set id 2
set size paddle-size
set color blue
]
end
;; init the ball to the center of the field
to setup-ball
ask balls [die] ;; destroy previous balls
create-balls 1 [
setxy 0 0
;; 0 is north, 90 is east, and so on
;; avoid east(90) and west(270) to not get stucked
;; we also want to avoid angle too close to 90 and 270
;; we chose in [-45, +45] and [+135, +225]
set heading (-45 + random 91) + (random 2 * 180)
set color white
set id 0
]
end
to init-quality
foreach (range min-pxcor (max-pxcor + 1)) [ ball-x ->
foreach (range (min-pycor + 1) max-pycor) [ ball-y ->
foreach (range (min-pxcor + 1) max-pxcor) [ paddle-x ->
ifelse state-type = "with-opponent-x" [
foreach (range (min-pxcor + 1) max-pxcor) [ opponent-x ->
let key (list ball-x ball-y paddle-x opponent-x)
table:put quality key [0 0]
]
][
let key (list ball-x ball-y paddle-x)
table:put quality key [0 0]
]
]
]
]
end
to load
load-quality
end
;; check if the game is over
to-report game-over?
report score-1 = 21 or score-2 = 21
end
;; PADDLES UPDATE ---------------------------------------------------------
to move-paddle-with-direction [speed direction]
set heading (ifelse-value direction = "sx" [-90] [90])
fd speed
end
to move-paddle-left [speed]
move-paddle-with-direction speed "sx"
end
to move-paddle-right [speed]
move-paddle-with-direction speed "dx"
end
to constrain-paddles
ask paddles [
if round(xcor) = max-pxcor [
move-paddle-left 1
]
if round(xcor) = min-pxcor [
move-paddle-right 1
]
]
end
;; learning agent behavior
to move-learning-agent [action]
ask paddles with [id = 1] [
ifelse action = 0
[ move-paddle-left 1 ]
[ move-paddle-right 1 ]
]
constrain-paddles
end
;; scripted AI agent behavior
to move-scripted-agent
;; Ask ball info
let ball-x 0
let ball-y 0
let ball-dir 1 ; avoid 0 degree
ask balls with [id = 0] [
set ball-x (round xcor)
set ball-y (round ycor)
set ball-dir heading
]
ask paddles with [id = 2] [
ifelse random-float 1 > random-move-prob
[
;; otherwise the scripted agent follow the ball.
if xcor < ball-x [
move-paddle-right 1
]
if xcor > ball-x [
move-paddle-left 1
]
]
[
;; when the scripted agent fail select a random action.
ifelse int(random 2) = 0
[ move-paddle-left 1 ]
[ move-paddle-right 1 ]
]
]
;; avoid collision with the wall
constrain-paddles
end
;; BALL UPDATE ------------------------------------------------------------
to move-ball
ask balls [
;; near a paddle patch
if (paddle-ahead?) [
set heading (180 - heading) ;; bounce to the paddle
set bounces-per-round (bounces-per-round + 1)
]
;; left wall or right wall
if (round(pxcor) = min-pxcor or round(pxcor) = max-pxcor) [
set heading (- heading) ;; bounce to the wall
]
fd 1 ;; forward in the heading direction
]
end
to-report paddle-ahead?
let paddles-ahead paddles with [pxcor + 2 >= [pxcor] of myself and pxcor - 2 <= [pxcor] of myself]
ifelse heading > 270 or heading < 90 [
set paddles-ahead paddles-ahead with [pycor = [pycor] of myself + 1]
][
set paddles-ahead paddles-ahead with [pycor = [pycor] of myself - 1]
]
report any? paddles-ahead
end
;; STATE
to-report get-state
;; Ask ball info
let ball-x 0
let ball-y 0
let ball-dir 1 ;; avoid 0 degree
ask balls with [id = 0] [
set ball-x xcor
set ball-y ycor
set ball-dir heading
]
let paddle-x 0
ask paddles with [id = 1] [
set paddle-x xcor
]
let state []
ifelse state-type = "with-opponent-x" [
let opponent-x 0
ask paddles with [id = 2] [
set opponent-x xcor
]
;; set state (lower-complexity ball-x ball-y ball-dir paddle-x opponent-x)
set state (lower-complexity ball-x ball-y 0 paddle-x opponent-x)
][
;; set state (lower-complexity ball-x ball-y ball-dir paddle-x "none")
set state (lower-complexity ball-x ball-y 0 paddle-x "none")
]
report state
end
to-report lower-complexity [ball-x ball-y ball-dir paddle-x opponent-x]
let xb round(ball-x)
let yb round(ball-y)
let xp paddle-x
if opponent-x != "none" [
let xo opponent-x
report (list xb yb xp xo)
]
report (list xb yb xp)
end
;; SARSA -----------------------------------------------------------------
to start-episodes-sarsa
ifelse curr-episode < episodes [
reset-episode
run-episode "sarsa"
tick
;; exploration/eploitation rate decay
set epsilon (min-epsilon + ((max-epsilon - min-epsilon) * exp(- decay-rate * curr-episode)))
set curr-episode (curr-episode + 1)
][
stop
]
end
;; Q-LEARNING ------------------------------------------------------------
to start-episodes-q-learning
ifelse curr-episode < episodes [
reset-episode
run-episode "q-learning"
tick
;; exploration/eploitation rate decay
set epsilon (min-epsilon + ((max-epsilon - min-epsilon) * exp(- decay-rate * curr-episode)))
set curr-episode (curr-episode + 1)
][
stop
]
end
;; CORE Q-LEARNING AND SARSA ------------------------------------------------------------
to run-episode [mode]
set step 0
let step-per-round 0
let new-quality 0
let next_action 0
let action 0
;; the state before the action is performed
set curr-state get-state
if mode = "sarsa" [set action choose-action curr-state]
while [not game-over?] [
;; the state before the action is performed
set curr-state get-state
;; exploitation/exploration action
if mode = "q-learning"[set action choose-action curr-state]
if mode = "sarsa" [set next_action choose-action curr-state]
;; perform the action
update-graphics curr-state action
;; get the state after the ball moved
let new-state get-state
let winner check-win-conditions new-state
;; the immediate reward
let reward winner ;; +1 if it score, -1 if it loose, 0 otherwise
if reward-type = "distance" [
let ball-x item 0 new-state ;??????
let paddle-x item 2 new-state ;??????
; set reward reward * 100
let dist (abs paddle-x - ball-x)
ifelse dist = 0 [
set reward reward + (1)
][
set reward reward + (1 / dist)
]
]
let next-actions (table:get quality new-state)
let curr-quality (item action (table:get quality curr-state)) ;; Q(s, a)
if mode = "sarsa"
[
;; Q(s,a) := Q(s,a) + lr [R(s,a) + gamma * Q(s',a') - Q(s,a)]
set new-quality curr-quality + lr * ((reward + gamma * item next_action next-actions) - curr-quality)
]
if mode = "q-learning"
[
;; Q(s,a) := Q(s,a) + lr [R(s,a) + gamma * max Q(s',a') - Q(s,a)]
set new-quality curr-quality + lr * ((reward + gamma * max next-actions) - curr-quality)
]
;; set the new quality for the current state given the action
let curr-actions (table:get quality curr-state)
set curr-actions (replace-item action curr-actions new-quality)
table:put quality curr-state curr-actions
if mode = "sarsa" [set action next_action]
;; update metrics
set curr-reward reward
set reward-per-episode (reward-per-episode + reward)
set steps-per-episode (steps-per-episode + 1)
set step (step + 1)
set step-per-round (step-per-round + 1)
;; when round ended
if winner != 0 [
set bounces-per-episode (bounces-per-episode + (bounces-per-round * step-per-round))
set step-per-round 0
set bounces-per-round 0
]
]
set avg-bounces lput (bounces-per-episode / step) avg-bounces
;; For the smooth plot of reward-per-episode
set reward-smooth-list lput reward-per-episode reward-smooth-list
if (length reward-smooth-list = smoother)[
set reward-smooth lput mean(reward-smooth-list) reward-smooth
set reward-smooth-list []
]
;; Update the sum of the avg reward per episode
set avg-reward-per-episode avg-reward-per-episode + reward-per-episode
;; For the smooth plot of avg-bounces
set avg-bounces-smooth-list lput (bounces-per-episode / step) avg-bounces-smooth-list
if (length avg-bounces-smooth-list = smoother)[
set avg-bounces-smooth lput mean(avg-bounces-smooth-list) avg-bounces-smooth
set avg-bounces-smooth-list []
]
;; Update the sum of the avg bounces per episode
set avg-bounces-per-episode avg-bounces-per-episode + (bounces-per-episode / step)
set score-smooth-list lput (score-1 - score-2) score-smooth-list
if (length score-smooth-list = smoother)[
set score-smooth lput mean(score-smooth-list) score-smooth
set score-smooth-list []
]
;; Time optimization
if (curr-episode mod 5000) = 0 [
save-quality
csv:to-file (word "./quality_" curr-episode ".csv") table:to-list quality
]
end
;; Q-LEARNING AND SARSA ------------------------------------------------------------
to reset-episode
setup-turtles
set reward-per-episode 0
set steps-per-episode 0
set bounces-per-episode 0
set bounces-per-round 0
set score-1 0
set score-2 0
reset-ticks
end
;; called every tick while the episode is not over
;; update the graphics and return the current state
to update-graphics [state action]
ifelse round-over? [
setup-ball
set round-over? false
] [
move-learning-agent action
move-scripted-agent
move-ball
]
tick
end
to-report get-best-action [state]
;; get quality values for each action given the current state
let row table:get quality state
report ifelse-value (item 0 row = 0 and item 1 row = 0)
[random 2] ;; If the value is the same we choose randomly
[ ifelse-value (item 0 row > item 1 row)
[0]
[1]
]
end
to-report choose-action [state]
ifelse random-float 1 > epsilon [
report get-best-action state
][
report int(random 2)
]
end
to-report check-win-conditions [state]
let winner 0
let ball-y item 1 state
;; bottom wall
if (ball-y = (min-pycor + 1)) [
set score-2 score-2 + 1
set round-over? true
set winner -1
]
;; top wall
if (ball-y = (max-pycor - 1)) [
set score-1 score-1 + 1
set round-over? true
set winner 1
]
report winner
end
to save-quality
csv:to-file "./quality.csv" table:to-list quality
end
to load-quality
let l csv:from-file "./quality.csv"
;; parse lists
set l map [x -> (list read-from-string (item 0 x) read-from-string (item 1 x))] l
;; reconstruct the matrix
set quality table:from-list l
end
;; PLAY -----------------------------------------------------------------
;; Just play one match, without learning
to play
while [not game-over?] [
;; the state before the action is performed
set curr-state get-state
;; exploitation/exploration action
let action get-best-action curr-state
update-graphics curr-state action
;; get the state after the ball moved
let new-state get-state
let winner check-win-conditions new-state
]
stop
end
;; TEST -----------------------------------------------------------------
;; Just play 1000 matches, without learning
to test
set test-avg-score 0
set test-std-score 0
let list-scores []
let test-episodes 100
while [curr-episode < test-episodes] [
while [not game-over?] [
;; the state before the action is performed
set curr-state get-state
;; exploitation/exploration action
let action get-best-action curr-state
update-graphics curr-state action
;; get the state after the ball moved
let new-state get-state
let winner check-win-conditions new-state
]
set curr-episode curr-episode + 1
set list-scores lput (score-1 - score-2) list-scores
reset-episode
]
set test-avg-score mean list-scores
set test-std-score standard-deviation list-scores
stop
end
@#$#@#$#@
GRAPHICS-WINDOW
360
95
752
352
-1
-1
22.6
1
10
1
1
1
0
1
1
1
-8
8
-5
5
1
1
1
ticks
30.0
MONITOR
680
362
752
423
Score 1
score-1
0
1
15
MONITOR
676
15
751
76
Score 2
score-2
0
1
15
BUTTON
16
16
116
60
Setup
setup\n
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1
SLIDER
16
324
178
357
random-move-prob
random-move-prob
0
1
0.3
0.1
1
NIL
HORIZONTAL
SLIDER
16
285
178
318
episodes
episodes
0
200000
5000.0
10000
1
NIL
HORIZONTAL
SLIDER
187
450
339
483
smoother
smoother
1
1000
50.0
50
1
NIL
HORIZONTAL
PLOT
790
14
1191
180
Reward per episode (smooth)
episodes
avg reward
0.0
10.0
-21.0
21.0
true
false
"" ""
PENS
"pen-0" 1.0 0 -7500403 true "" "if enable-plots [\n clear-plot\n let indexes (n-values length reward-smooth [i -> i])\n (foreach indexes reward-smooth[[x y] -> plotxy x y])\n]"
TEXTBOX
480
384
694
414
Player1 (learning agent)
12
0.0
1
TEXTBOX
473
37
636
67
Player2 (scripted agent)
12
0.0
1
PLOT
789
192
1191
345
Average paddle bounces per point (smooth)
episodes
NIL
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "if enable-plots [\n clear-plot\n let indexes (n-values length avg-bounces-smooth [i -> i])\n (foreach indexes avg-bounces-smooth [[x y] -> plotxy x y])\n]"
BUTTON
16
66
116
110
Load
load
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1
MONITOR
240
16
340
61
Episode
curr-episode + 1
0
1
11
BUTTON
128
66
228
110
Play
play
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1
MONITOR
1197
14
1289
59
avg reward
avg-reward-per-episode / curr-episode
5
1
11
MONITOR
1199
192
1288
237
avg bounces
avg-bounces-per-episode / curr-episode
5
1
11
PLOT
788
353
1192
486
Score 1 - Score 2
NIL
NIL
0.0
0.0
-21.0
21.0
true
false
"" ""
PENS
"pen-1" 1.0 0 -2674135 true "" "if enable-plots [\n clear-plot\n let indexes (n-values length score-smooth [i -> i])\n (foreach indexes score-smooth [[x y] -> plotxy x y])\n]"
BUTTON
240
66
340
110
Test
test
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1
MONITOR
451
440
598
485
NIL
test-avg-score
17
1
11
CHOOSER
16
206
178
251
algorithm
algorithm
"Q-Learning" "SARSA"
0
BUTTON
128
16
228
60
Learn
ifelse algorithm = \"Q-Learning\" [\n start-episodes-q-learning\n][\n start-episodes-sarsa\n]\n
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1
CHOOSER
16
156
178
201
state-type
state-type
"with-opponent-x" "without-opponent-x"
1
SWITCH
16
450
177
483
enable-plots
enable-plots
1
1
-1000
CHOOSER
184
156
346
201
reward-type
reward-type
"basic" "distance"
0
MONITOR
16
374
178
419
NIL
epsilon
17
1
11
SLIDER
184
285
338
318
gamma
gamma
0
1
0.9
0.1
1
NIL
HORIZONTAL
SLIDER
184
324