forked from jrl-umi3218/jrl-cmakemodules
-
Notifications
You must be signed in to change notification settings - Fork 0
/
python.cmake
404 lines (339 loc) · 13.3 KB
/
python.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
# Copyright (C) 2008-2019 LAAS-CNRS, JRL AIST-CNRS, INRIA.
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
#.rst:
# .. command:: FINDPYTHON
#
# Find python interpreter and python libs.
# Arguments are passed to the find_package command so
# refer to `find_package` documentation to learn about valid arguments.
#
# To specify a specific Python version from the command line,
# use the command ``FINDPYTHON()``
# and pass the following arguments to CMake
# ``-DPYTHON_EXECUTABLE=/usr/bin/python3.5 -DPYTHON_LIBRARY= /usr/lib/x86_64-linux-gnu/libpython3.5m.so.1``
#
# To specify a specific Python version within the CMakeLists.txt,
# use the command ``FINDPYTHON(2.7 EXACT REQUIRED)``.
#
# If PYTHON_PACKAGES_DIR is set, then the {dist,site}-packages will be replaced by the value contained in PYTHON_PACKAGES_DIR.
#
# .. warning::
# According to the ``FindPythonLibs`` and ``FindPythonInterp``
# documentation, you could also set ``Python_ADDITIONAL_VERSIONS``.
# If you do this, you will not have an error if you found two different versions
# or another version that the requested one.
#
#.rst:
# .. variable:: PYTHON_SITELIB
#
# Absolute path where Python files will be installed.
#.rst:
# .. variable:: PYTHON_EXT_SUFFIX
#
# Portable suffix of C++ Python modules.
IF(CMAKE_VERSION VERSION_LESS "3.2")
SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake/python ${CMAKE_MODULE_PATH})
MESSAGE(WARNING "CMake versions older than 3.2 do not properly find Python. Custom macros are used to find it.")
ENDIF(CMAKE_VERSION VERSION_LESS "3.2")
MACRO(FINDPYTHON)
FIND_PACKAGE(PythonInterp ${ARGN})
IF (NOT ${PYTHONINTERP_FOUND} STREQUAL TRUE)
MESSAGE(FATAL_ERROR "Python executable has not been found.")
ENDIF (NOT ${PYTHONINTERP_FOUND} STREQUAL TRUE)
MESSAGE(STATUS "PythonInterp: ${PYTHON_EXECUTABLE}")
# Set PYTHON_INCLUDE_DIR variables if it is not defined by the user
IF(DEFINED PYTHON_EXECUTABLE AND NOT WIN32)
# Retrieve the corresponding value of PYTHON_INCLUDE_DIR if it is not defined
IF(NOT DEFINED PYTHON_INCLUDE_DIR)
EXECUTE_PROCESS(
COMMAND "${PYTHON_EXECUTABLE}" "-c"
"import distutils.sysconfig as sysconfig; print(sysconfig.get_python_inc())"
OUTPUT_VARIABLE PYTHON_INCLUDE_DIR
ERROR_QUIET)
STRING(STRIP "${PYTHON_INCLUDE_DIR}" PYTHON_INCLUDE_DIR)
ENDIF(NOT DEFINED PYTHON_INCLUDE_DIR)
ENDIF(DEFINED PYTHON_EXECUTABLE AND NOT WIN32)
# Inform PythonLibs of the required version of PythonInterp
SET(PYTHONLIBS_VERSION_STRING ${PYTHON_VERSION_STRING})
FIND_PACKAGE(PythonLibs ${ARGN})
MESSAGE(STATUS "PythonLibraries: ${PYTHON_LIBRARIES}")
IF (NOT ${PYTHONLIBS_FOUND} STREQUAL TRUE)
MESSAGE(FATAL_ERROR "Python has not been found.")
ENDIF (NOT ${PYTHONLIBS_FOUND} STREQUAL TRUE)
STRING(REPLACE "." ";" _PYTHONLIBS_VERSION ${PYTHONLIBS_VERSION_STRING})
LIST(GET _PYTHONLIBS_VERSION 0 PYTHONLIBS_VERSION_MAJOR)
LIST(GET _PYTHONLIBS_VERSION 1 PYTHONLIBS_VERSION_MINOR)
IF (NOT ${PYTHON_VERSION_MAJOR} EQUAL ${PYTHONLIBS_VERSION_MAJOR} OR
NOT ${PYTHON_VERSION_MINOR} EQUAL ${PYTHONLIBS_VERSION_MINOR})
MESSAGE(FATAL_ERROR "Python interpreter and libraries are in different version: ${PYTHON_VERSION_STRING} vs ${PYTHONLIBS_VERSION_STRING}")
ENDIF (NOT ${PYTHON_VERSION_MAJOR} EQUAL ${PYTHONLIBS_VERSION_MAJOR} OR
NOT ${PYTHON_VERSION_MINOR} EQUAL ${PYTHONLIBS_VERSION_MINOR})
# Find PYTHON_LIBRARY_DIRS
GET_FILENAME_COMPONENT(PYTHON_LIBRARY_DIRS "${PYTHON_LIBRARIES}" PATH)
MESSAGE(STATUS "PythonLibraryDirs: ${PYTHON_LIBRARY_DIRS}")
MESSAGE(STATUS "PythonLibVersionString: ${PYTHONLIBS_VERSION_STRING}")
# Use either site-packages (default) or dist-packages (Debian packages) directory
OPTION(PYTHON_DEB_LAYOUT "Enable Debian-style Python package layout" OFF)
# ref. https://docs.python.org/3/library/site.html
OPTION(PYTHON_STANDARD_LAYOUT "Enable standard Python package layout" OFF)
IF(PYTHON_STANDARD_LAYOUT)
SET(PYTHON_SITELIB_CMD "import sys, os; print(os.sep.join(['lib', 'python' + sys.version[:3], 'site-packages']))")
ELSE(PYTHON_STANDARD_LAYOUT)
SET(PYTHON_SITELIB_CMD "from distutils import sysconfig; print(sysconfig.get_python_lib(prefix='', plat_specific=False))")
ENDIF(PYTHON_STANDARD_LAYOUT)
EXECUTE_PROCESS(
COMMAND "${PYTHON_EXECUTABLE}" "-c"
"${PYTHON_SITELIB_CMD}"
OUTPUT_VARIABLE PYTHON_SITELIB
OUTPUT_STRIP_TRAILING_WHITESPACE
ERROR_QUIET)
# Keep compatility with former jrl-cmake-modules versions
IF(PYTHON_DEB_LAYOUT)
STRING(REPLACE "site-packages" "dist-packages" PYTHON_SITELIB "${PYTHON_SITELIB}")
ENDIF(PYTHON_DEB_LAYOUT)
# If PYTHON_PACKAGES_DIR is defined, then force the Python packages directory name
IF(PYTHON_PACKAGES_DIR)
STRING(REGEX REPLACE "(site-packages|dist-packages)" "${PYTHON_PACKAGES_DIR}" PYTHON_SITELIB "${PYTHON_SITELIB}")
ENDIF(PYTHON_PACKAGES_DIR)
MESSAGE(STATUS "Python site lib: ${PYTHON_SITELIB}")
# Get PYTHON_SOABI
# We should be in favor of using PYTHON_EXT_SUFFIX in future for better portability.
# However we keep it here for backward compatibility.
SET(PYTHON_SOABI "")
IF(PYTHON_VERSION_MAJOR EQUAL 3 AND NOT WIN32)
EXECUTE_PROCESS(
COMMAND "${PYTHON_EXECUTABLE}" "-c"
"from distutils.sysconfig import get_config_var; print('.' + get_config_var('SOABI'))"
OUTPUT_VARIABLE PYTHON_SOABI)
STRING(STRIP ${PYTHON_SOABI} PYTHON_SOABI)
ENDIF(PYTHON_VERSION_MAJOR EQUAL 3 AND NOT WIN32)
# Get PYTHON_EXT_SUFFIX
SET(PYTHON_EXT_SUFFIX "")
IF(PYTHON_VERSION_MAJOR EQUAL 3)
EXECUTE_PROCESS(
COMMAND "${PYTHON_EXECUTABLE}" "-c"
"from distutils.sysconfig import get_config_var; print(get_config_var('EXT_SUFFIX'))"
OUTPUT_VARIABLE PYTHON_EXT_SUFFIX)
STRING(STRIP ${PYTHON_EXT_SUFFIX} PYTHON_EXT_SUFFIX)
ENDIF(PYTHON_VERSION_MAJOR EQUAL 3)
IF("${PYTHON_EXT_SUFFIX}" STREQUAL "")
IF(WIN32)
SET(PYTHON_EXT_SUFFIX ".pyd")
ELSE()
SET(PYTHON_EXT_SUFFIX ".so")
ENDIF()
ENDIF()
# Log Python variables
LIST(APPEND LOGGING_WATCHED_VARIABLES
PYTHONINTERP_FOUND
PYTHONLIBS_FOUND
PYTHON_LIBRARY_DIRS
PYTHONLIBS_VERSION_STRING
PYTHON_EXECUTABLE
PYTHON_SOABI
PYTHON_EXT_SUFFIX
)
ENDMACRO(FINDPYTHON)
#.rst:
# .. command:: DYNAMIC_GRAPH_PYTHON_MODULE ( SUBMODULENAME LIBRARYNAME TARGETNAME INSTALL_INIT_PY=1 SOURCE_PYTHON_MODULE=cmake/dynamic_graph/python-module-py.cc)
#
# Add a python submodule to dynamic_graph
#
# :param SUBMODULENAME: the name of the submodule (can be foo/bar),
#
# :param LIBRARYNAME: library to link the submodule with.
#
# :param TARGETNAME: name of the target: should be different for several
# calls to the macro.
#
# :param INSTALL_INIT_PY: if set to 1 install and generated a __init__.py file.
# Set to 1 by default.
#
# :param SOURCE_PYTHON_MODULE: Location of the cpp file for the python module in the package.
# Set to cmake/dynamic_graph/python-module-py.cc by default.
#
# .. note::
# Before calling this macro, set variable NEW_ENTITY_CLASS as
# the list of new Entity types that you want to be bound.
# Entity class name should match the name referencing the type
# in the factory.
#
MACRO(DYNAMIC_GRAPH_PYTHON_MODULE SUBMODULENAME LIBRARYNAME TARGETNAME)
# By default the __init__.py file is installed.
SET(INSTALL_INIT_PY 1)
SET(SOURCE_PYTHON_MODULE "cmake/dynamic_graph/python-module-py.cc")
# Check if there is optional parameters.
set(extra_macro_args ${ARGN})
list(LENGTH extra_macro_args num_extra_args)
if( ${num_extra_args} GREATER 0)
list(GET extra_macro_args 0 INSTALL_INIT_PY)
if( ${num_extra_args} GREATER 1)
list(GET extra_macro_args 1 SOURCE_PYTHON_MODULE)
endif(${num_extra_args} GREATER 1)
endif(${num_extra_args} GREATER 0)
IF(NOT DEFINED PYTHONLIBS_FOUND)
FINDPYTHON()
ELSEIF(NOT ${PYTHONLIBS_FOUND} STREQUAL "TRUE")
MESSAGE(FATAL_ERROR "Python has not been found.")
ENDIF()
SET(PYTHON_MODULE ${TARGETNAME})
# We need to set this policy to old to accept wrap target.
CMAKE_POLICY(PUSH)
IF(POLICY CMP0037)
CMAKE_POLICY(SET CMP0037 OLD)
ENDIF()
ADD_LIBRARY(${PYTHON_MODULE}
MODULE
${PROJECT_SOURCE_DIR}/${SOURCE_PYTHON_MODULE})
FILE(MAKE_DIRECTORY ${PROJECT_BINARY_DIR}/src/dynamic_graph/${SUBMODULENAME})
SET_TARGET_PROPERTIES(${PYTHON_MODULE}
PROPERTIES PREFIX ""
OUTPUT_NAME dynamic_graph/${SUBMODULENAME}/wrap
)
CMAKE_POLICY(POP)
TARGET_LINK_LIBRARIES(${PYTHON_MODULE} ${PUBLIC_KEYWORD} "-Wl,--no-as-needed")
TARGET_LINK_LIBRARIES(${PYTHON_MODULE} ${PUBLIC_KEYWORD} ${LIBRARYNAME} ${PYTHON_LIBRARY})
INCLUDE_DIRECTORIES(${PYTHON_INCLUDE_PATH})
#
# Installation
#
SET(PYTHON_INSTALL_DIR ${PYTHON_SITELIB}/dynamic_graph/${SUBMODULENAME})
INSTALL(TARGETS ${PYTHON_MODULE}
DESTINATION
${PYTHON_INSTALL_DIR})
SET(ENTITY_CLASS_LIST "")
FOREACH (ENTITY ${NEW_ENTITY_CLASS})
SET(ENTITY_CLASS_LIST "${ENTITY_CLASS_LIST}${ENTITY}('')\n")
ENDFOREACH(ENTITY ${NEW_ENTITY_CLASS})
# Install if INSTALL_INIT_PY is set to 1
IF (${INSTALL_INIT_PY} EQUAL 1)
CONFIGURE_FILE(
${PROJECT_SOURCE_DIR}/cmake/dynamic_graph/submodule/__init__.py.cmake
${PROJECT_BINARY_DIR}/src/dynamic_graph/${SUBMODULENAME}/__init__.py
)
INSTALL(
FILES ${PROJECT_BINARY_DIR}/src/dynamic_graph/${SUBMODULENAME}/__init__.py
DESTINATION ${PYTHON_INSTALL_DIR}
)
ENDIF(${INSTALL_INIT_PY} EQUAL 1)
ENDMACRO(DYNAMIC_GRAPH_PYTHON_MODULE SUBMODULENAME)
#.rst:
# .. command:: PYTHON_INSTALL(MODULE FILE DEST)
#
# Compile and install a Python file.
#
MACRO(PYTHON_INSTALL MODULE FILE DEST)
PYTHON_BUILD("${MODULE}" "${FILE}")
INSTALL(FILES
"${CMAKE_CURRENT_SOURCE_DIR}/${MODULE}/${FILE}"
DESTINATION "${DEST}/${MODULE}")
ENDMACRO()
#.rst:
# .. command:: PYTHON_INSTALL_ON_SITE (MODULE FILE)
#
# Compile and install a Python file in :cmake:variable:`PYTHON_SITELIB`.
#
MACRO(PYTHON_INSTALL_ON_SITE MODULE FILE)
IF(NOT DEFINED PYTHONLIBS_FOUND)
FINDPYTHON()
ELSEIF(NOT ${PYTHONLIBS_FOUND} STREQUAL "TRUE")
MESSAGE(FATAL_ERROR "Python has not been found.")
ENDIF()
PYTHON_INSTALL("${MODULE}" "${FILE}" "${PYTHON_SITELIB}")
ENDMACRO()
# PYTHON_BUILD(MODULE FILE DEST)
# --------------------------------------
#
# Build a Python file from the source directory in the build directory.
#
MACRO(PYTHON_BUILD MODULE FILE)
FILE(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${MODULE}")
# convert "/" to "_"
STRING(REGEX REPLACE "/" "_" FILE_TARGET_NAME
"${CMAKE_CURRENT_BINARY_DIR}/${MODULE}/${FILE}c")
ADD_CUSTOM_TARGET(${FILE_TARGET_NAME} ALL
COMMAND
"${PYTHON_EXECUTABLE}"
"${PROJECT_SOURCE_DIR}/cmake/compile.py"
"${CMAKE_CURRENT_SOURCE_DIR}"
"${CMAKE_CURRENT_BINARY_DIR}"
"${MODULE}/${FILE}"
)
# Tag pyc file as generated.
SET_SOURCE_FILES_PROPERTIES(
"${CMAKE_CURRENT_BINARY_DIR}/${MODULE}/${FILE}c"
PROPERTIES GENERATED TRUE)
# Clean generated files.
SET_PROPERTY(
DIRECTORY APPEND PROPERTY
ADDITIONAL_MAKE_CLEAN_FILES
"${CMAKE_CURRENT_BINARY_DIR}/${MODULE}/${FILE}c"
)
ENDMACRO()
# PYTHON_INSTALL_BUILD(MODULE FILE DEST)
# --------------------------------------
#
# Install a Python file residing in the build directory and its
# associated compiled version.
#
MACRO(PYTHON_INSTALL_BUILD MODULE FILE DEST)
MESSAGE(AUTHOR_WARNING "PYTHON_INSTALL_BUILD is deprecated and will be removed in the future")
MESSAGE(AUTHOR_WARNING "Please use PYTHON_INSTALL_ON_SITE")
MESSAGE(AUTHOR_WARNING "ref https://github.com/jrl-umi3218/jrl-cmakemodules/issues/136")
FILE(MAKE_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${MODULE}")
INSTALL(CODE
"EXECUTE_PROCESS(COMMAND
\"${PYTHON_EXECUTABLE}\"
\"${PROJECT_SOURCE_DIR}/cmake/compile.py\"
\"${CMAKE_CURRENT_BINARY_DIR}\"
\"${CMAKE_CURRENT_BINARY_DIR}\"
\"${MODULE}/${FILE}\")
")
# Tag pyc file as generated.
SET_SOURCE_FILES_PROPERTIES(
"${CMAKE_CURRENT_BINARY_DIR}/${MODULE}/${FILE}c"
PROPERTIES GENERATED TRUE)
# Clean generated files.
SET_PROPERTY(
DIRECTORY APPEND PROPERTY
ADDITIONAL_MAKE_CLEAN_FILES
"${CMAKE_CURRENT_BINARY_DIR}/${MODULE}/${FILE}c"
)
INSTALL(FILES
"${CMAKE_CURRENT_BINARY_DIR}/${MODULE}/${FILE}"
"${CMAKE_CURRENT_BINARY_DIR}/${MODULE}/${FILE}c"
DESTINATION "${DEST}/${MODULE}")
ENDMACRO()
#.rst:
# .. command:: FIND_NUMPY
#
# Detect numpy module
#
MACRO(FIND_NUMPY)
# Detect numpy.
MESSAGE (STATUS "checking for numpy")
EXECUTE_PROCESS(
COMMAND "${PYTHON_EXECUTABLE}" "-c"
"import numpy; print (numpy.get_include())"
OUTPUT_VARIABLE NUMPY_INCLUDE_DIRS
ERROR_QUIET)
IF (NOT NUMPY_INCLUDE_DIRS)
MESSAGE (FATAL_ERROR "Failed to detect numpy")
ELSE ()
STRING(REGEX REPLACE "\n$" "" NUMPY_INCLUDE_DIRS "${NUMPY_INCLUDE_DIRS}")
FILE(TO_CMAKE_PATH "${NUMPY_INCLUDE_DIRS}" NUMPY_INCLUDE_DIRS)
MESSAGE (STATUS " NUMPY_INCLUDE_DIRS=${NUMPY_INCLUDE_DIRS}")
ENDIF()
ENDMACRO()