forked from dverite/assemble-amiga
-
Notifications
You must be signed in to change notification settings - Fork 0
/
qsort.s
2243 lines (2119 loc) · 39.3 KB
/
qsort.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
XREF IVarPError,VarPError
XDEF GetLocVar,GetGloVar,ForceLocVar,ForceGloVar,FindEqu
XDEF GetREquate,GetXref,BuildXdef,QsortV
XDEF GetEqur,GetEqur3
XDEF LocNb,VarNb,GloNb,LocTbl,GloTbl,CstLocTbl
XDEF EqusPtr,XrefTbl,XrefNb,XdefTbl,XdefNb
XDEF TxtVarNb,DatVarNb,BssVarNb,OffVarNb
XDEF icmpsort
section TEXT
QBLINDOS EQU 1
; #[ Create Start Variables:
CreateIntVars:
lea .t(pc),a2
.l1: tst.l (a2)
beq.s .end
bsr VarAlloc
beq .rmem
move.l d0,a1
move.l (a2)+,a0 ;def string
moveq #0,d0
move.b (a0)+,d0
move.l a0,VAR_start(a1)
move.w d0,VAR_len(a1)
move.l (a2)+,VAR_value(a1) ;def value
move.l (a2)+,d0
move.b d0,VAR_type(a1)
st VAR_sec(a1)
clr.w VAR_mod(a1)
clr.l VAR_lnb(a1)
move.l (a2)+,d0
beq.s .noptr
move.l d0,a0
move.l a1,(a0) ;@ struct
.noptr: move.l a1,a0
move.l a2,-(sp)
bsr stock_equate
move.l (sp)+,a2
bra.s .l1
.end: move.l DbgTypePtr,a0
move.w DbgType,VAR_value+2(a0)
move.l SrcTypePtr,a0
move.w SrcType,VAR_value+2(a0)
lea MPUType,a1
move.l MPUTypePtr,a0
move.w (a1)+,VAR_value+2(a0)
move.l MMUTypePtr,a0
move.w (a1)+,VAR_value+2(a0)
move.l FPUTypePtr,a0
move.w (a1)+,VAR_value+2(a0)
move.l OutTypePtr,a0
move.l OutType,VAR_value(a0)
rts
.rmem: bra Erreq_ram
.t: dc.l .asm,VERSION,EQU_EQU,0
dc.l .dbg,0,EQU_EQU,DbgTypePtr
dc.l .fpu,0,EQU_EQU,FPUTypePtr
dc.l .lk,0,EQU_EQU,OutTypePtr
dc.l .mmu,0,EQU_EQU,MMUTypePtr
dc.l .mpu,0,EQU_EQU,MPUTypePtr
dc.l .narg,0,EQU_EQU,MacStuff+MacNARGptr
dc.l .rs,0,EQU_SET,RsCountPtr
dc.l .src,0,EQU_EQU,SrcTypePtr
dc.l 0
.asm: dc.b 5,"__ASM"
.dbg: dc.b 5,"__DBG"
.fpu: dc.b 5,"__FPU"
.lk: dc.b 4,"__LK"
.mmu: dc.b 5,"__MMU"
.mpu: dc.b 5,"__MPU"
.narg: dc.b 4,"NARG"
.rs: dc.b 4,"__RS"
.src: dc.b 5,"__SRC"
;.time: dc.b 6,"__TIME"
;.date: dc.b 6,"__DATE"
;.file: dc.b 6,"__FILE"
;.line: dc.b 6,"__LINE"
even
CreateDefVars:
lea DefBuf,a3
.l1: move.l a3,a2
move.l a3,a0
moveq #0,d5 ;length
.l2: move.b (a0)+,d0
bmi.s .create
beq.s .end
addq.w #1,d5
cmp.b #'=',d0
bne.s .l2
subq.w #1,d5
.eval: moveq #1,d0
jsr ForEval
bmi.s .reval
move.l d0,d2 ;value
swap d1
move.w d1,d0
moveq #EQU_EQU,d1
tst.w d0
beq.s .acreate
bset #VAR_MINUS,d1
.acreate: st d3 ;section
move.w d5,d0 ;length
move.l a2,a0 ;name
bsr stock_rs
bsr stock_equate
.l3: tst.b (a3)+
bgt.s .l3
tst.b (a3)
bne.s .l1
.end: rts
.create: moveq #1,d2
moveq #EQU_EQU,d1 ;type
bra.s .acreate
.reval: bra ErrEv_prep
; #] Create Start Variables:
; #[ Init_Var:
init_var: bsr FstVarAlloc
move.w #-1,CurBinNb ;init a -1 pour addq #1
move.l #VARL_SIZEOF+GLOBALS_PER_BLOCK*VAR_SIZEOF,d0
bsr MyMalloc
beq.s .errmem
move.l d0,a1
moveq #VARL_SIZEOF,d1
add.l d1,d0
clr.l VARL_next(a1)
clr.w VARL_nb(a1)
move.l d0,VARL_block(a1)
move.l a1,GloPtr
move.l #VARL_SIZEOF+LOCALS_PER_BLOCK*VAR_SIZEOF,d0 ;50
bsr MyMalloc
beq.s .errmem
move.l d0,a1
moveq #VARL_SIZEOF,d1
add.l d1,d0
clr.l VARL_next(a1)
clr.w VARL_nb(a1)
move.l d0,VARL_block(a1)
move.l a1,LocPtr
clr.l EqusPtr
clr.l LocNb
clr.l GloNb
clr.l VarNb
move.l #LOCPTR_PER_BLOCK*4,d0
bsr MyMalloc
move.l d0,CstLocTbl
move.l d0,LocTbl
beq.s .errmem
moveq #0,d0
rts
.errmem: bra Errglo_ram
; #] Init_Var:
; #[ Free Vars:
FreeLocals:
movem.l d0-d1/a0,-(sp)
move.l CstLocTbl,a0
; move.l #LOCPTR_PER_BLOCK*4,d0
bsr MyMfree
move.l LocPtr,d1
beq.s .end
.nx: move.l d1,a0
move.l VARL_next(a0),d1
; move.l #VARL_SIZEOF+LOCALS_PER_BLOCK*VAR_SIZEOF,d0 ;50
bsr MyMfree
tst.l d1
bne.s .nx
.end: movem.l (sp)+,d0-d1/a0
rts
FreeAllVars:
;tables de ptrs xref et xdef
move.l XdefTbl,d0
beq.s .noxdef
move.l d0,a0
bsr MyMfree
.noxdef: move.l XrefTbl,d0
beq.s .noxref
move.l d0,a0
bsr MyMfree
;blocks de ptrs xref et xdef
.noxref: move.l xrefs_ptr,d1
bsr.s .freevarlist
move.l xdefs_ptr,d1
bsr.s .freevarlist
;les variables allouees marginalement: macros,def-variables,xref-xdef
bsr FreeVars
;table de ptrs sur globales
move.l GloTbl,d0
beq.s .noglob
move.l d0,a0
bsr MyMfree
;les blocks d'equate
.noglob: move.l EqusPtr,d1
bsr.s .freevarlist
;les blocks de globales
move.l GloPtr,d1
bsr.s .freevarlist
rts
.freevarlist:
tst.l d1
beq.s .out
.nx: move.l d1,a0
move.l VARL_next(a0),d1
bsr MyMfree
tst.l d1
bne.s .nx
.out: rts
; #] Free Vars:
; #[ StockVar: globale/locale
StockVar: tst.b loc_flag
bne stock_local
.asrc: move.l d3,-(sp)
lea length_variable,a0
move.w (a0),d0
clr.w (a0)
moveq #VAR_GLOB,d1
move.l SecSize,d2
move.w CurSecType,d3
bmi.s .stock
lea TxtVarNb,a0
addq.l #1,0(a0,d3.w)
.stock: move.w CurSection,d3
move.l start_variable,a0
bsr stock_global
tst.w SrcType
bne.s .src
.end: move.l (sp)+,d3
rts
.src: bsr LinrAlloc ;gros bloc source
bra.s .end
;Garb:d0/a0/a1
stock_local:
move.l a2,-(sp)
move.l LocPtr,a2
.nxtbl: move.w VARL_nb(a2),d0
cmp.w #LOCALS_PER_BLOCK,d0
bne.s .enough_room
move.l VARL_next(a2),d0
beq.s .this
move.l d0,a2
bra.s .nxtbl
.this: bsr alloc_local_block ;block plein -> creer suivant
move.l d0,VARL_next(a2)
move.l d0,a2
move.w VARL_nb(a2),d0
.enough_room:
move.l VARL_block(a2),a3
mulu #VAR_SIZEOF,d0 ;nombre de vars dans le block
lea 0(a3,d0.w),a0 ;adresse ou stocker pointeur sur var
move.l start_variable,a1
addq.w #1,VARL_nb(a2)
tst.w VarRamFlg
bne.s .copy
.fast: move.l a1,VAR_start(a0) ;@ var
lea length_variable,a1
move.w (a1),VAR_len(a0) ;taille var
clr.w (a1)
move.b #VAR_LOC,VAR_type(a0)
move.b CurSection+1,VAR_sec(a0)
move.l SecSize,VAR_value(a0)
move.w CurModNb+2,VAR_mod(a0) ;module courant
move.l CurLNb,VAR_lnb(a0)
addq.l #1,LocNb
.end: move.l (sp)+,a2
rts
.copy: move.w d2,-(sp)
move.w length_variable,d2
move.w d2,d0
bsr AllocString
beq.s .errram
move.l a0,-(sp)
move.l a1,a0
move.l d0,a1
move.w d2,d0
STRNCPY
sub.w d2,a1
move.l (sp)+,a0
move.w (sp)+,d2
bra.s .fast
.errram: move.w (sp)+,d2
bsr Errloc_ram
bra.s .end
; #] StockVar:
; #[ Stock_global: (global, equ, equr, reg, set, rs, cargs, pargs).
;Input:
;a0:start_variable
;d0:length_variable
;d1:type
;d2:value
;d3:section
;In:
;a4:start_variable
;d2:value
;d3:section
;d4:length_variable
;d5:type
;Out:
;a0:adresse de la VAR
stock_global:
jsr end_locals
addq.l #1,GloNb
stock_rs: movem.l d3-d7/a2-a4,-(sp)
move.l a0,a4 ;label start
move.w d0,d4 ;label length
move.w d1,d5 ;var type
move.l GloPtr,a2
.bl_loop: move.w VARL_nb(a2),d0
cmp.w #GLOBALS_PER_BLOCK,d0
bne.s .this
move.l VARL_next(a2),d0
bne.s .nxt_bl
bsr alloc_global_block ;block plein -> creer suivant
move.l d0,VARL_next(a2)
.nxt_bl: move.l d0,a2
bra.s .bl_loop
.this: move.l VARL_block(a2),a3
mulu #VAR_SIZEOF,d0
lea 0(a3,d0),a0 ;adresse de stockage de la variable
move.l a4,a1
addq.w #1,VARL_nb(a2)
addq.l #1,VarNb
tst.w VarRamFlg
bne.s .ramcopy
.fast: move.l a1,VAR_start(a0) ;@ var
move.w d4,VAR_len(a0) ;taille var
move.b d5,VAR_type(a0)
move.b d3,VAR_sec(a0)
.ok: move.l d2,VAR_value(a0)
move.w CurModNb+2,VAR_mod(a0) ;module courant
move.l CurLNb,VAR_lnb(a0)
movem.l (sp)+,d3-d7/a2-a4
rts
.ramcopy: move.w d4,d0
bsr AllocString
beq.s .rram
move.l a0,-(sp)
move.l a1,a0
move.l d0,a1
move.w d4,d0
STRNCPY
sub.w d4,a1
move.l (sp)+,a0
bra.s .fast
.rram: bra Errglo_ram
; #] Stock_global:
; #[ QsortL:
QsortL: movem.l d0/a0/a6,-(sp)
lea scmpsort(pc),a6 ;case sensitive cmp
tst.w CaseFlg
bne.s .nocase
lea icmpsort(pc),a6 ;case insensitive cmp
.nocase: move.l a1,a5 ;routine de traitement d'egalite
subq.l #1,d0
ble.s .noerr
add.l d0,d0
add.l d0,d0
move.l a0,a3 ;pointeur sur 1ere struct
lea 0(a0,d0.l),a4 ;pointeur sur last struct
moveq #-4,d6
move.l a3,d2
move.l a4,d3
moveq #0,d1
bsr.s .qsort1
movem.l (sp)+,d0/a0/a6
tst.l d1
bne.s .err
rts
.noerr: movem.l (sp)+,d0/a0/a6
rts
.err: move.l a5,d1
bne PMdef
rts ;pas de routine d'egalite->pas de traitement
.qsort1: move.l d2,a3
move.l d3,a4
move.l a4,d4
sub.l a3,d4
lsr.l #1,d4
and.l d6,d4
add.l a3,d4
move.l d4,a0 ;pointeur sur structure pivot
move.l (a0),a0 ;adresse structure pivot
move.w VAR_len(a0),d4 ;taille pivot
move.l VAR_start(a0),a2 ;pointeur ascii pivot
move.l (a3),a0 ;adresse struct
cmp.w VAR_len(a0),d4
bls.s .up2
.up_loop: addq.w #4,a3
.up: move.l (a3),a0 ;adresse struct
cmp.w VAR_len(a0),d4
bhi.s .up_loop
.up2: bne.s .down
;sizes are the same: compare strings
move d4,d7
subq #1,d7
move.l VAR_start(a0),a1 ;pointeur ascii variable
cmp.l a1,a2
beq.s .down
move.l a2,a0
jsr (a6)
beq.s .equup
bhi.s .down
bra.s .up_loop
.dn_loop: subq.w #4,a4
.down: move.l (a4),a0
cmp.w VAR_len(a0),d4
blt.s .dn_loop
bne.s .inv
;sizes are the same: compare strings
move.w d4,d7
subq.w #1,d7
move.l VAR_start(a0),a1 ;pointeur ascii variable
cmp.l a1,a2
beq.s .inv
move.l a2,a0
jsr (a6)
bhi.s .dn_loop
beq.s .equdown
.inv: cmpa.l a4,a3
bhi.s .stop
move.l (a3),d0
move.l (a4),(a3)
move.l d0,(a4)
addq.w #4,a3
subq.w #4,a4
cmpa.l a4,a3
ble.s .up
.stop: cmp.l a4,d2
bge.s .remonte
movem.l d2-d3/a3,-(sp)
move.l a4,d3
bsr .qsort1
movem.l (sp)+,d2-d3/a3
.remonte: cmp.l d3,a3
bge.s .end
movem.l d2-d3,-(sp)
move.l a3,d2
bsr .qsort1
movem.l (sp)+,d2-d3
.end: rts
.equup: move.l (a3),a0
move.l a5,d0
beq.s .down ;pas de routine d'egalite
jsr (a5)
bra.s .down
.equdown: move.l (a4),a0
move.l a5,d0
beq.s .inv ;pas de routine d'egalite
jsr (a5)
bra.s .inv
scmpsort:
.l1: cmpm.b (a0)+,(a1)+
dbne d7,.l1
rts
icmpsort: move.l d1,-(sp)
moveq #0,d0
moveq #0,d1
.l1: move.b (a0)+,d0
move.b .t(pc,d0.w),d0
move.b (a1)+,d1
move.b .t(pc,d1.w),d1
cmp.b d0,d1
dbne d7,.l1
movem.l (sp)+,d1
rts
CASETAB
; #] QsortL:
; #[ QsortV:
QsortV: movem.l d3-d7/a2-a4,-(sp)
subq.l #1,d0
ble.s .noerr
add.l d0,d0
add.l d0,d0
move.l a0,a3 ;pointeur sur 1ere struct
lea 0(a0,d0.l),a4 ;pointeur sur last struct
moveq #-4,d6
move.l a3,d2
move.l a4,d3
moveq #0,d1
bsr .qsort1
.noerr: movem.l (sp)+,d3-d7/a2-a4
rts
.qsort1: move.l d2,a3
move.l d3,a4
move.l a4,d4
sub.l a3,d4
lsr.l #1,d4
and.l d6,d4
add.l a3,d4
move.l d4,a0 ;pointeur sur structure pivot
move.l (a0),a0 ;adresse structure pivot
move.l VAR_value(a0),d4 ;valeur pivot
move.l (a3),a0 ;adresse struct
cmp.l VAR_value(a0),d4
bls.s .up2
.upl1: addq.w #4,a3
.up: move.l (a3),a0 ;adresse struct
cmp.l VAR_value(a0),d4
bhi.s .upl1
.up2: bra.s .down
.dnl1: subq.w #4,a4
.down: move.l (a4),a0
cmp.l VAR_value(a0),d4
blt.s .dnl1
.inv: cmpa.l a4,a3
bhi.s .stop
move.l (a3),d0
move.l (a4),(a3)
move.l d0,(a4)
addq.w #4,a3
subq.w #4,a4
cmpa.l a4,a3
ble.s .up
.stop: cmp.l a4,d2
bge.s .remonte
movem.l d2-d3/a3,-(sp)
move.l a4,d3
bsr .qsort1
movem.l (sp)+,d2-d3/a3
.remonte: cmp.l d3,a3
bge.s .end
movem.l d2-d3,-(sp)
move.l a3,d2
bsr .qsort1
movem.l (sp)+,d2-d3
.end: rts
; #] QsortV:
; #[ Doubly defined error:
;Input:
;d5=tbl #
;a6=tbl @
;Output:
;d1:doubly var len
;d4:mdef #
;a1:doubly var @
;a3:start doubly @
;In:
;a0:array @
;a1:var name @
;a2:block @
;d1:name length
;d2:block var #
;Garb:None
pminit: movem.l d3/a3,-(sp)
move.l a0,a3
move.l d0,d3
move.l (a2)+,a0 ;next doubly
move.l VAR_start(a0),a1 ;var
move.w VAR_len(a0),d1
.l1: move.l (a3)+,a0 ;scan var table
cmp.w VAR_len(a0),d1
bne.s .nxt1
move.l VAR_start(a0),a0
move.w d1,d0
subq.w #1,d0
bsr cmpmdef
beq.s .end ;1st name found
.nxt1: subq.l #1,d3
bgt.s .l1
IFNE QBLINDOS
_Debugger
ENDC ;QBLINDOS
.end: move.l a3,a0
move.l d3,d0
movem.l (sp)+,d3/a3
rts
pmcnt: movem.l d3-d4/a3,-(sp)
move.l a0,a3
move.l d0,d3
moveq #-1,d4 ;-1 for dbf, -1 for first print
subq.l #1,d3
.l1: move.l (a3)+,a0
cmp.w VAR_len(a0),d1
bne.s .end
move.l VAR_start(a0),a0
move.w d1,d0
subq.w #1,d0
bsr cmpmdef
bne.s .end
addq.l #1,d4
subq.l #1,d3
bgt.s .l1
.end: move.l d4,d0
movem.l (sp)+,d3-d4/a3
rts
;In:
;a0=@ fst var
;d0=mdef var nb (-2)
pmsort: movem.l d1-d4/a1-a4,-(sp)
move.l a0,a3
move.l d0,d4
move.l d4,d3
.l1: move.l (a3)+,a0
move.l (a3),a1
move.w VAR_mod(a0),d0 ;tri par module
cmp.w VAR_mod(a1),d0
beq.s .lnb
blt.s .nxt
move.l a0,(a3)
move.l a1,-4(a3)
bra.s .cmp
.lnb: move.l VAR_lnb(a0),d0 ;et par # de ligne
cmp.l VAR_lnb(a1),d0
ble.s .nxt
move.l a0,(a3)
move.l a1,-4(a3)
.cmp: cmp.w d4,d3
beq.s .nxt
subq.w #8,a3
addq.w #2,d4
.nxt: dbf d4,.l1
movem.l (sp)+,d1-d4/a1-a4
rts
;In:
;d2:mdef head #
;d3:cur var #
;d4:mdef #
;d5:tot var #
;a2:mdef head @
;a3:cur var @
;a4:mdef @
;a6:head var @
PMdef: movem.l d2-d5/a2-a4/a6,-(sp)
move.l d0,d5 ;nombre d'elements de la table
move.l a0,a6 ;pointeur sur table de pointeur triee
move.l DoublyPtr,a4 ;struct mdef
.nextbl: move.l VARL_block(a4),a2
move.w VARL_nb(a4),d2
subq.w #1,d2
bmi.s .err
.nextvar: move.l d5,d0 ;reinit var tbl
move.l a6,a0
bsr pminit ;init a0,d0
move.l a0,a3 ;first var
bsr pmcnt ;init d1
move.l d0,d4 ;same vars #
subq.w #4,a3
move.l a3,a0
bsr pmsort
move.l (a3)+,a0
move.l d4,d0
addq.l #2,d0
jsr IVarPError ;affichage message 1+2
.l1: move.l (a3)+,a0
jsr VarPError ;affichage message 2
dbf d4,.l1
dbf d2,.nextvar
move.l VARL_next(a4),d0
move.l d0,a4
bne.s .nextbl
.free: move.l DoublyPtr,d2
.l2: move.l d2,a0
move.l VARL_next(a0),d2
bsr MyMfree
tst.l d2
bne.s .l2
.allfree: clr.l DoublyPtr
movem.l (sp)+,d2-d5/a2-a4/a6
rts
IFNE QBLINDOS
.err: _Debugger
ENDC ;QBLINDOS
bra.s .allfree
;In:
;a0=new var
;a1=start var
;d1=length var
;Garb:d0,a0
cmpmdef: tst.w CaseFlg
beq.s .case
move.l a1,-(sp)
.l1: cmpm.b (a0)+,(a1)+
dbne d0,.l1
move.l (sp)+,a1
rts
.case: movem.l d1-d2/a1,-(sp)
moveq #0,d2
moveq #0,d1
.l2: move.b (a0)+,d2
move.b .t(pc,d2.w),d2
move.b (a1)+,d1
move.b .t(pc,d1.w),d1
cmp.b d2,d1
dbne d0,.l2
movem.l (sp)+,d1-d2/a1
rts
CASETAB
; #] Doubly defined error:
; #[ Find_Global:
RECHERCHE_REG REG d2-d7/a2-a4
;In:
;a0.l:@ var string
;d0.w:strlen
;Out:
;d0.l:var #
;a1.l/d1.l:@ structure (NULL if nf)
find_global:
movem.l RECHERCHE_REG,-(sp)
lea scmpsrch(pc),a4
tst.w CaseFlg
bne.s .nocase
lea icmpsrch(pc),a4
.nocase: move.l VarNb,d5
subq.l #1,d5
ble.s .one
move.w d0,d1
subq.w #1,d1
IFNE _68000
asl.w #4,d0
lea glob_table,a2
add.w d0,a2
ELSEIF
add.w d0,d0
lea (glob_table.l,d0.w*8),a2
ENDC ;_68000
move.l (a2)+,a1
move.l (a2)+,d7
bmi.s .nofound
move.l (a2)+,d3 ;# anterieur
moveq #0,d5
moveq #-4,d6
bra.s .boucle
.moins: move.l d4,d7
add.l d6,d7 ;sub.l #4,d7
bmi.s .nofound
.boucle: move.l d5,d4
add.l d7,d4
lsr.l #1,d4
and.l d6,d4
move.l 0(a1,d4.l),a2 ;pointeur sur struct
move.l VAR_start(a2),a2
move.l a0,a3
move.w d1,d0
jsr (a4)
bmi.s .moins
.plus: beq.s .found
move.l d4,d5
sub.l d6,d5 ;add.l #4,d5
cmp.l d7,d5
bls.s .boucle
.nofound: moveq #0,d1
movem.l (sp)+,RECHERCHE_REG
rts
.found: move.l 0(a1,d4.l),a1 ;pointeur sur struct
.asfound: move.l d4,d0
add.l d3,d0
lsr.l #2,d0 ;var #
move.l a1,d1
movem.l (sp)+,RECHERCHE_REG
rts
.one: bmi.s .nofound
moveq #0,d4 ;var #
moveq #0,d3 ;prev var #
move.l GloPtr,a1
move.l VARL_block(a1),a1
cmp.w VAR_len(a1),d0
bne.s .nofound
move.l (a1),a2
move.l a0,a3
subq.w #1,d0
jsr (a4)
beq.s .asfound
bra.s .nofound
scmpsrch:
.l1: cmpm.b (a2)+,(a3)+
dbne d0,.l1
rts
icmpsrch: movem.l d1-d2,-(sp)
moveq #0,d2
moveq #0,d1
.l1: move.b (a2)+,d2
move.b .t(pc,d2.w),d2
move.b (a3)+,d1
move.b .t(pc,d1.w),d1
cmp.b d2,d1
dbne d0,.l1
movem.l (sp)+,d1-d2
rts
CASETAB
; #] Find_Global:
; #[ GetXref:
;In:
;a0.l=variable string
;d0.w=label length
;Out:
;a1.l=@ xref (NULL if not found)
;d0.l=xref nb
;Garb:d2
GetXref: ;eval,evalone
; #] GetXref:
;keep tight
; #[ Find_Xref:
;In:
;a0.l:@ var string
;d0.w: strlen
;Out:ccr!=0+a1.l+d1.l
find_xref:
move.l XrefTbl,a1
move.l XrefNb,d1
bra find_dicho
; #] Find_Xref:
; #[ Find_Local:
;In:
;a0.l:@ var string
;d0.w:strlen
;Out:
;a1.l/d1.l:@ structure (NULL if nf)
find_local:
move.l LocTbl,a1
move.l LocNb,d1
; bra find_dicho
; #] Find_Local:
; #[ Find_dicho:
;In:
;a0.l:@ var string
;d0.w: strlen
;a1.l:@ table de longs
;d1.l: nombre de structs dans la table
;Out:ccr!=0+a1.l+d1.l+d0.l
find_dicho:
movem.l RECHERCHE_REG,-(sp)
lea scmpsrch(pc),a4
tst.w CaseFlg
bne.s .nocase
lea icmpsrch(pc),a4
.nocase: move.l d1,d7
subq.l #1,d7
ble.s .one
move.w d0,d2
move.w d0,d1
subq.w #1,d1
moveq #0,d5
add.l d7,d7
add.l d7,d7
moveq #-4,d6
.boucle: move.l d5,d4
add.l d7,d4
lsr.l #1,d4
and.l d6,d4
move.l 0(a1,d4.l),a2
cmp.w VAR_len(a2),d2
blt.s .moins
beq.s .same
.plus: move.l d4,d5
sub.l d6,d5 ;add.l #4,d5
cmp.l d7,d5
bls.s .boucle
bra.s .nofound
.same: move.l VAR_start(a2),a2 ;pointeur ascii variable
move.l a0,a3
move.w d1,d0
jsr (a4)
bhi.s .plus
beq.s .found
.moins: move.l d4,d7
add.l d6,d7 ;sub.l #4,d7
bge.s .boucle
.nofound: moveq #0,d1
movem.l (sp)+,RECHERCHE_REG
rts
.found: move.l d4,d0
lsr.l #2,d0 ;xref #
move.l 0(a1,d4.l),a1 ;adresse de la structure cherchee
.asfound: move.l a1,d1
movem.l (sp)+,RECHERCHE_REG
rts
.one: bmi.s .nofound
move.l (a1),a1
cmp.w VAR_len(a1),d0
bne.s .nofound
move.l VAR_start(a1),a2 ;pointeur ascii variable
move.l a0,a3
subq.w #1,d0
jsr (a4)
bne.s .nofound
moveq #0,d0
bra.s .asfound
; #] Find_dicho:
; #[ GetGloVar:
;** Machine dependent ! **
;In:
;a0.l=variable string
;d0.w=label length
;Out:
;a1.l=@ var (NULL if not found)
;d0.l=var value
;d1.b=var sec
;Garb:d2
GetGloVar:
bsr find_global
beq.s .nf
move.l d0,d1
move.l VAR_value(a1),d0
swap d1
IFNE AMIGA
clr.w d1
move.b VAR_sec(a1),d1
move.l a1,d2
.nf: rts
ENDC ;AMIGA
IFNE ATARI
clr.w d1
move.b VAR_sec(a1),d1
ble.s .end ;offset+text
tst.w OutType+2 ;if obj, keep section & @
bne.s .end
subq.b #SEC_data,d1 ;if prg clr section & add @
beq.s .data
.bss: add.l DataSize,d0
.data: add.l TextSize,d0
;moveq #0,d1
.end: move.l a1,d2
.nf: rts
ENDC ;ATARI
; #] GetGloVar:
; #[ GetLocVar:
;** Machine dependent ! **
;In:
;a0.l=variable string
;d0.w=label length
;Out:
;a1.l=@ var (NULL if not found)
;d0.l=var value
;d1.b=var sec
;Garb:d2
GetLocVar:
bsr find_local
beq.s .nf
move.l VAR_value(a1),d0
moveq #0,d1
tst.w OutType+2
bne.s .end