forked from dverite/assemble-amiga
-
Notifications
You must be signed in to change notification settings - Fork 0
/
patch68k.s
1739 lines (1653 loc) · 34.2 KB
/
patch68k.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
include "comequ.s"
IFNE AMIGA
include "amig_equ.s"
ENDC
XDEF StoreEXP,ResetLocEXPs,FreeEXPs,SetEXPErr,SprintDisp,BsdCreateOffsets
XDEF HeadExp,CurGloExp,TotExpNb,LocRelNb,BsdOffsets
XDEF GlobalPatch,LocalPatch
XDEF GlobPatchFlag,LocPatchFlag
XREF MyMalloc,MyMfree,GloEval,LocEval,AllocString,AllocLocString
XREF LoadSrc,OutMsg,Sprintf
XREF SrcCurStart,SrcCurName,CurLNb,CurModPtr,CurLPtr,CurSection
XREF FstBinPtr,CurBinNb,FstBinBuffer,BinBuffer,SecSize,GloTbl
XREF FstModPtr,CurModNb,MacStuff,SlowFlg,LocStrMemHead
XREF OutType,StopFlg,UsrTxt
XREF OptiNb,OptiNopFlg,OptiFBccFlg,WOptNopFlg,WOptFBccFlg
XREF TextSize,DataSize
IFNE AMIGA
XREF TabSecs,CurSecPtr
ENDC
XREFS_PER_LBLOCK EQU 100
; #[ A faire:
;patch errors plus precises
; #] A faire:
; #[ StoreEXP:
;In:
;d0.l=@ liste locales si type=3
;LO(d1.L)=flag_evalone | expr type (1,2,3)
;HI(d1.L)=expr size
;d2.w=patch type
;a0.l=expr @ (token) - inutilise -
;a1.l=expr @ (source)
StoreEXP: subq.b #EVAL_LOC,d1
bpl StoreLocalEXP
movem.l d1-d5/a0-a3,-(sp)
move.l d1,d5
move.l d0,d3
move.l a1,d4
.store: move.l CurGloExp,d0 ;1st block
beq .newHEAD
move.l d0,a3
move.l HEAD_current(a3),d0 ;current EXP
cmp.l HEAD_end(a3),d0 ;last EXP
bge .newHEAD
.storeEXP:
addq.l #1,TotExpNb ;ExpNb++
move.l d0,a2
move.l d3,EXP_backval(a2) ;sets
move.l CurLNb,EXP_lnb(a2) ;line #
tst.w d5
spl EXP_eval(a2) ;expr complexe
move.w CurModNb+2,EXP_mod(a2) ;module #
move.l SecSize,EXP_PC(a2) ;cur section size
move.w CurSection,EXP_secnum(a2)
move.w d2,EXP_patch(a2) ;backpatch type
IFNE AMIGA
cmp.w #P_ABSL,d2
beq.s .addrel
cmp.w #P_DCL,d2
bne.s .norel
.addrel: move.l CurSecPtr,a0
addq.l #1,SECTION_maxreloc(a0)
ENDC ;AMIGA
.norel: move.w CurBinNb,EXP_bin(a2) ;binary block #
IFNE BLINDOS
bmi.s .binerr
ENDC
move.l BinBuffer,d0
sub.l FstBinBuffer,d0
move.w d0,EXP_poke(a2) ;binary offset
swap d5
move.w d5,EXP_sec(a2) ;expr len + sec (0)
IFNE BLINDOS
beq.s .errempt
.aempty:
ENDC ;BLINDOS
tst.w MacStuff+MacNestCnt
bne .macro
sub.l SrcCurStart,d4
move.l CurModPtr,a0
add.l MOD_curoffs(a0),d4
move.l d4,EXP_start(a2) ;offset source integral
.ares: addq.w #1,HEAD_nb(a3) ;+1 EXP
add.l #EXP_SIZEOF,HEAD_current(a3) ;+1 element
.end: movem.l (sp)+,d1-d5/a0-a3
rts
.errmem: bra Errgexp_ram
IFNE BLINDOS
.errempt: _Debugger
moveq #0,d1
bsr patpeval
bra.s .aempty
.binerr: _Debugger
ENDC ;BLINDOS
.newHEAD: move.l #HEAD_SIZEOF+EXP_SIZEOF*EXP_BLOCK_NB,d0
jsr MyMalloc
beq.s .errmem
move.l d0,a3
add.l #HEAD_SIZEOF,d0
move.l CurGloExp,d1
beq.s .fstHEAD
move.l d1,HEAD_prev(a3)
exg d1,a3
move.l d1,HEAD_next(a3)
exg d1,a3
.inHEAD: clr.l HEAD_next(a3)
move.l d0,HEAD_start(a3)
move.l d0,HEAD_current(a3)
add.l #EXP_SIZEOF*EXP_BLOCK_NB,d0
move.l d0,HEAD_end(a3)
clr.w HEAD_nb(a3)
move.l a3,CurGloExp
bra .store
.fstHEAD: move.l a3,HeadExp
clr.l HEAD_prev(a3)
bra.s .inHEAD
.macro: move.w MacStuff+MacLineSize,d1 ;expr en macro
move.w d1,d0
addq.w #1,d0
move.l MacStuff+MacCurBufPtr,a0
.str: jsr AllocString
beq .errmem
move.l d0,a1
move.w d1,d0
PSTRNCPY
sub.l a0,d4 ;offset/debut de la ligne
add.w d4,a1
move.l a1,EXP_start(a2)
neg.w EXP_mod(a2) ;in ram
bra .ares
; #] StoreEXP:
; #[ StoreLocalEXP:
;expr avec uniquement des locales donc evaluable au local backpatching
;-globale-locale/locale-globale = constante
; ->rien faire ds local patch
; ->patcher ds global patch
; stocker dans le fantome l'expr a reevaluer -> EXP_len>0
;-locale sans reloc
; ->patcher ds local patch
; pas de fantome
;-locale avec reloc
; ->patcher ds local patch
; fantome sans expr -> sans backpatch -> EXP_len==0
;In:
;d0.l=@ liste locales si type=3
;d1.b=expr type (1,2,3)
;d2.w=patch type
;a0.l=expr @ (token)
;a1.l=expr @ (source)
StoreLocalEXP:
movem.l d1-d5/a0-a3,-(sp)
move.w d2,d3
move.l d0,d2
move.l a1,d4
move.l d1,d5
move.l CurLocExp,d0 ;1st block
beq .newHEAD
move.l d0,a3
.store: move.l HEAD_current(a3),d0 ;current EXP
cmp.l HEAD_end(a3),d0 ;last EXP
bge .nxtHEAD
.storeEXP:
move.l d0,a2
move.l d2,EXP_backval(a2) ;sets
move.l CurLNb,EXP_lnb(a2) ;line #
tst.w d5
spl EXP_eval(a2)
move.w CurModNb+2,EXP_mod(a2) ;module #
move.l SecSize,EXP_PC(a2) ;cur section size
move.w CurSection,EXP_secnum(a2)
move.w d3,EXP_patch(a2) ;backpatch type
move.w CurBinNb,EXP_bin(a2) ;binary block #
move.l BinBuffer,d0
sub.l FstBinBuffer,d0
move.w d0,EXP_poke(a2) ;offset patch ds l'exec
clr.l EXP_dupliq(a2) ;no ghost(default)
swap d5
move.b d5,EXP_len(a2)
IFNE BLINDOS
beq.s .bug
ENDC
tst.w MacStuff+MacNestCnt
bne.s .macro
sub.l SrcCurStart,d4
; move.l CurModPtr,a0
; add.l MOD_curoffs(a0),d4
move.l d4,EXP_start(a2) ;offset source partiel
.tstrel: swap d5
IFNE ATARI
cmp.w #P_ABSL,d3
beq.s .ghost
cmp.w #P_DCL,d3
beq.s .ghost
ENDC ;ATARI
IFNE AMIGA
cmp.w #P_ABSL,d3
beq.s .addrel
cmp.w #P_DCL,d3
bne.s .tstcomb
.addrel: move.l CurSecPtr,a0
addq.l #1,SECTION_maxreloc(a0)
bra.s .ghost
ENDC ;AMIGA
.tstcomb: subq.w #EVAL_LOCGLO-EVAL_LOC,d5
bne.s ._end
.ghost: bsr .cpy2glo ;loc+reloc=ghost
._end: addq.w #1,HEAD_nb(a3) ;+1 EXP
add.l #EXP_LOC_SIZEOF,HEAD_current(a3) ;+1 loc
moveq #0,d0
.end: movem.l (sp)+,d1-d5/a0-a3
rts
IFNE BLINDOS
.bug: _Debugger
bra.s ._end
ENDC
;.slow: moveq #0,d0
; move.w d5,d0
; move.l d4,a0
; bra.s .str
.macro: move.w MacStuff+MacLineSize,d5
move.w d5,d0
addq.w #1,d0
move.l MacStuff+MacCurBufPtr,a0
.str: jsr AllocLocString
beq.s .errmem
move.l d0,a1
move.w d5,d0
PSTRNCPY
sub.l a0,d4 ;offset/debut de la ligne
add.w d4,a1
move.l a1,EXP_start(a2) ;insuffisant en cas de glo-loc
neg.w EXP_mod(a2) ;in ram
bra.s .tstrel
.nxtHEAD: move.l HEAD_next(a3),d0
beq.s .resnext
move.l d0,a3 ;recuperer un bloc precedemment alloue
move.l d0,CurLocExp
move.l HEAD_start(a3),HEAD_current(a3)
clr.w HEAD_nb(a3)
bra .store
.errmem: bra Errlexp_ram
.resnext: move.l #HEAD_SIZEOF+EXP_LOC_SIZEOF*EXP_BLOCK_NB,d0
jsr MyMalloc
beq.s .errmem
move.l d0,a3
add.l #HEAD_SIZEOF,d0
move.l CurLocExp,d1
move.l d1,HEAD_prev(a3)
exg d1,a3
move.l d1,HEAD_next(a3)
exg d1,a3
.inHEAD: clr.l HEAD_next(a3)
move.l d0,HEAD_start(a3)
move.l d0,HEAD_current(a3)
add.l #EXP_LOC_SIZEOF*EXP_BLOCK_NB,d0
move.l d0,HEAD_end(a3)
clr.w HEAD_nb(a3)
move.l a3,CurLocExp
bra .store
.newHEAD: move.l #HEAD_SIZEOF+EXP_LOC_SIZEOF*EXP_BLOCK_NB,d0
jsr MyMalloc
beq.s .errmem
move.l d0,a3
add.l #HEAD_SIZEOF,d0
move.l a3,HeadLocExp
clr.l HEAD_prev(a3)
bra.s .inHEAD
;expr contenant seulement des locales et relogeable
;ou expr contenant glo-loc
;allouer une EXP globale et copier
;Out:
;A1=new EXP
.cpy2glo: move.l CurGloExp,d0
beq.s .gloHEAD
move.l d0,a0
.go_exp: move.l HEAD_current(a0),d0
cmp.l HEAD_end(a0),d0
bge.s .gloHEAD
addq.l #1,TotExpNb ;Tot EXP #++
addq.w #1,HEAD_nb(a0) ;Block EXP #++
add.l #EXP_SIZEOF,HEAD_current(a0) ;+1 glo
move.l d0,EXP_dupliq(a2)
move.l d0,a1
move.l a2,a0
moveq #EXP_SIZEOF/2-1,d1
.cp: move.w (a0)+,(a1)+
dbf d1,.cp
;updater l'offset source du ghost
move.l CurModPtr,a0
move.l MOD_curoffs(a0),d1
add.l d1,EXP_start-EXP_SIZEOF(a1)
move.l d0,a1 ;new global EXP
rts
.gloHEAD: ;copie du bloc ci-dessus en global
move.l #HEAD_SIZEOF+EXP_SIZEOF*EXP_BLOCK_NB,d0
jsr MyMalloc
beq.s .errgmem
move.l d0,a1
add.l #HEAD_SIZEOF,d0
move.l CurGloExp,d1
beq.s .fsgHEAD
move.l d1,a0
move.l a0,HEAD_prev(a1)
move.l a1,HEAD_next(a0)
.ingHEAD: clr.l HEAD_next(a1)
move.l d0,HEAD_start(a1)
move.l d0,HEAD_current(a1)
add.l #EXP_SIZEOF*EXP_BLOCK_NB,d0
move.l d0,HEAD_end(a1)
clr.w HEAD_nb(a1)
move.l a1,CurGloExp
move.l a1,a0
bra .go_exp
.errgmem: bra Errgexp_ram
.fsgHEAD: move.l a1,HeadExp
clr.l HEAD_prev(a1)
bra.s .ingHEAD
; #] StoreLocalEXP:
; #[ ResetLocEXPs:
ResetLocEXPs:
movem.l d0/a0/a1,-(sp)
move.l HeadLocExp,d0
beq.s .end
move.l d0,a0
move.l d0,CurLocExp
clr.w HEAD_nb(a0)
move.l HEAD_start(a0),HEAD_current(a0)
move.l LocStrMemHead,d0
beq.s .end
move.l d0,a0
lea MEMBLOCK_SIZEOF(a0),a1
move.l a1,MEMBLOCK_cur(a0)
.end: movem.l (sp)+,d0/a0/a1
rts
; #] ResetLocEXPs:
; #[ patch:
RELPCDATA MACRO
IFNE ATARI
tst.b GlobPatchFlag
beq.s .\@
cmp.w #SEC_data,BIN_sec(a6)
bne.s .\@
sub.l TextSize,d0
.\@: ENDC
ENDM
;Input:
;a0:@ ou patcher
;a6:@ struct BIN de la reference
;d0:valeur a patcher
;LO(d1.L):type de patch*2
;HI(d1.L):sign
;Inside:
;d0-d2 garbage
patch: subq.w #2,a0 ;par defaut
IFNE BLINDOS
cmp.w #P_MAX,d1
bhi.s .err
ENDC ;BLINDOS
move.w .tab(pc,d1.w),d1 ;deja *2
jmp .tab(pc,d1.w) ;a0=@opcode
IFNE BLINDOS
.err: _Debugger
rts
ENDC ;BLINDOS
.tab: dc.w .w911-.tab ;P_W911
dc.w .ea1-.tab ;P_EA1
dc.w .bit8-.tab ;P_BIT8
dc.w .bit32-.tab ;P_BIT32
dc.w .w07-.tab ;P_W07
dc.w .w05-.tab ;P_W05
dc.w .w610-.tab ;P_W610
dc.w .w02-.tab ;P_W02
dc.w .l02-.tab ;P_L02
dc.w .l1012-.tab ;P_L1012
dc.w .w03-.tab ;P_W03
dc.w .l06-.tab ;P_L06
dc.w .k06-.tab ;P_K06
dc.w .l57-.tab ;P_L57
dc.w .ftrapw-.tab ;P_FTRAPW
dc.w .ftrapl-.tab ;P_FTRAPL
dc.w .d8-.tab ;P_D8
dc.w .d16-.tab ;P_D16
dc.w .absb-.tab ;P_ABSB
dc.w .absw-.tab ;P_ABSW
dc.w .absl-.tab ;P_ABSL
dc.w .dcb-.tab ;P_DCB
dc.w .dcw-.tab ;P_DCW
dc.w .dcl-.tab ;P_DCL
dc.w .pcd8-.tab ;P_D8PC
dc.w .pcd16-.tab ;P_D16PC
dc.w .dbcc-.tab ;P_DBCC
dc.w .bccb-.tab ;P_BCCB
dc.w .bccw-.tab ;P_BCCW
dc.w .bccl-.tab ;P_BCCL
dc.w .bdpcw-.tab ;P_BDPCW
dc.w .bdpcl-.tab ;P_BDPCL
.w911: move.l d0,d1 ;0<x<=8
and.b #%111,d1 ;8->0
add.b d1,d1 ;lsl.b #1,d0
or.b d1,(a0)
tst.l d0
ble.s .rq
cmp.l #8,d0
bhi.s .rq
rts
.rq: bra Err_q_exp
.ea1: subq.l #1,d0 ;d0==1
bne.s .rea
rts
.rea: bra Err_shiftea1
.bit8: move.w d0,(a0)
tst.l d0 ;0<=x<8
bmi.s .rge64
moveq #7,d1
cmp.l d1,d0
bhi.s .warn8
rts
.rge64: bra Err_bitge64
.warn8: moveq #63,d1
cmp.l d1,d0
bhi.s .rge64
bra Warn_bitmod8
.bit32: move.w d0,(a0)
tst.l d0 ;0<=x<32
bmi.s .rge64
moveq #31,d1
cmp.l d1,d0
bhi.s .warn32
rts
.warn32: moveq #63,d1
cmp.l d1,d0
bhi.s .rge64
bra Warn_bitmod32
.dcb:
.d8:
.absb:
.w07: move.b d0,1(a0)
moveq #127,d2 ;-128<=x<=127
cmp.l d2,d0
bhi.s .bytemi
rts ;127<=(unsigned x)<=0
.bytemi: bgt.s .rgeb ;(signed x)>127
swap d1
tst.b d1
beq.s .rgeb
not.l d2 ;-128
cmp.l d2,d0
blt.s .rgeb ;(signed x)<-128
rts
.rgeb: bra Err_sizegeb
.w05: or.w d0,2(a0)
moveq #31,d1 ;-31<x<31
cmp.l d1,d0
bhi.s .rge32
rts
.rge32: bra Err_widthge32
.w610: move.l d0,d1
lsl.w #6,d1
or.w d1,2(a0)
moveq #31,d2 ;-31<x<31
cmp.l d2,d0
bhi.s .rg32
rts
.rg32: bra Err_offsetge32
.w02: or.w d0,(a0)
tst.l d0 ;0<=x<=7
bmi.s .rbkpt
moveq #7,d1
cmp.l d1,d0
bhi.s .rbkpt
rts
.rbkpt: bra Err_bkptge8
.l02: or.w d0,2(a0)
tst.l d0 ;0<=x<=7
bmi.s .rpfc
moveq #7,d1
cmp.l d1,d0
bhi.s .rpfc
rts
.rpfc: bra Err_pfcge7
.l1012:
; moveq #7,d1 ;-7<=x<=7
; cmp.l d1,d0
; bhi.s .rge7
ror.w #6,d0
or.w d0,(a0)
rts
;.rge7: bra Error_level_ge_7
.w03: or.w d0,(a0)
tst.l d0 ;0<=x<=15
bmi.s .rgt15
moveq #15,d1
cmp.l d1,d0
bhi.s .rgt15
rts
.rgt15: bra Err_trapgt15
.k06:
.l06: andi.w #%1111111,d0 ;test a faire
or.w d0,(a0)
rts
.l57: andi.w #%111,d0 ;a tester
lsl.w #5,d0
or.w d0,(a0)
rts
.ftrapw: move.w d0,(a0) ;inutilise pour le moment
rts
.ftrapl: move.l d0,(a0) ;inutilise pour le moment
rts
.d16: move.w d0,(a0)
cmp.l #$7fff,d0 ;-32767<=x<=32767
bhi.s .d16mi
rts
.d16mi: swap d1
tst.b d1
beq.s .dcwerr
tst.w d0
bpl.s .dcwerr
swap d0
addq.w #1,d0
bne.s .dcwerr
rts
.dcw: move.w d0,(a0)
cmp.l #$ffff,d0 ;-65535<=x<=65535
bhi.s .dcwmi
rts
.dcwmi: swap d1
tst.b d1
beq.s .dcwerr
swap d0
addq.w #1,d0
bne.s .dcwerr
rts
.dcwerr: bra Err_sizegew
.absw: move.w d0,(a0)
cmp.l #$7fff,d0
bgt.s .dcwerr
cmp.l #-32768,d0
blt.s .dcwerr
rts
.dcl:
.absl: move.l d0,-2(a0)
rts
.bccb: RELPCDATA
sub.l EXP_PC(a3),d0 ;-128<=x<=127
beq.s .short_0
move.b d0,1(a0)
moveq #-128,d1
cmp.l d1,d0
blt.s .rmb
not.l d1
cmp.l d1,d0
bgt.s .rpb
btst #0,d0
bne Warn_oddbranch
rts
.short_0: cmp.b #$61,(a0)
beq.s .rzbccb
tst.w OptiNopFlg
beq.s .rzbccb
move.w #$4e71,(a0)
bra Opti_zbccb2nop
.rzbccb: bra Errzbccb_forb
.rmb:
.rpb: bra Err_bunreach
.pcd8: RELPCDATA
addq.l #2,d0
sub.l EXP_PC(a3),d0
move.b d0,1(a0)
moveq #-128,d1
cmp.l d1,d0
blt.s .rmb
not.l d1
cmp.l d1,d0
bgt.s .rpb
rts
.dbcc: RELPCDATA
addq.l #2,d0
sub.l EXP_PC(a3),d0
move.w d0,(a0)
move.l #$7fff,d1
cmp.l d1,d0
bgt.s .rw
not.l d1
cmp.l d1,d0
blt.s .rw
btst #0,d0
bne Warn_oddbranch
rts
.bccw: RELPCDATA
addq.l #2,d0
sub.l EXP_PC(a3),d0
move.w d0,(a0) ;poke d'abord
move.l #$7fff,d1 ;teste ensuite
cmp.l d1,d0
bgt.s .rw
not.l d1
cmp.l d1,d0
blt.s .rw
btst #0,d0
bne.s .oddbccw
.aoddw: tst.w OptiFBccFlg
beq.s .endpcw
moveq #$7f,d1
cmp.l d1,d0
bls.s .optw ;ou ble ?
.endpcw: rts
.rw: bra Err_wunreach
.optw: bra Opti_fwbcc2b
.oddbccw: move.l d0,-(sp)
bsr Warn_oddbranch
move.l (sp)+,d0
bra.s .aoddw
.pcd16: RELPCDATA
addq.l #2,d0
sub.l EXP_PC(a3),d0
move.w d0,(a0)
move.l #$7fff,d1
cmp.l d1,d0
bgt.s .rw
not.l d1
cmp.l d1,d0
blt.s .rw
rts
.bdpcw: RELPCDATA
addq.l #4,d0
sub.l EXP_PC(a3),d0
move.w d0,(a0)
move.l #$7fff,d1
cmp.l d1,d0
bgt.s .rw
not.l d1
cmp.l d1,d0
blt.s .rw
rts
.bccl: RELPCDATA
addq.l #4,d0
sub.l EXP_PC(a3),d0
move.l d0,-2(a0)
btst #0,d0
bne.s .oddbccl
.aoddl: tst.w OptiFBccFlg
bne.s .optl
.endbccl: rts
.optl: moveq #$7f,d1
cmp.l d1,d0
bls .optw ;ou ble ?
move.l #$7fff,d1
cmp.l d1,d0
bgt.s .endbccl
not.l d1
cmp.l d1,d0
blt.s .endbccl
bra Opti_fwbcc2w
.oddbccl: move.l d0,-(sp)
bsr Warn_oddbranch
move.l (sp)+,d0
bra.s .aoddl
.bdpcl: RELPCDATA
addq.l #6,d0
sub.l EXP_PC(a3),d0
move.l d0,-2(a0)
rts
; #] patch:
; #[ LocalPatch:
;reevalue les exp contenant des locales|var+loc
;d3:# EXP
;d4:# MOD
;d5:# BIN
;d6:start BIN
;d7:last char
;a2:@ HEAD
;a3:@ EXP
;a4:@ MOD
;a5:pas touche
;a6:@ BIN
LocalPatch:
movem.l d0-a6,-(sp)
move.l HeadLocExp,d0
beq .end
st LocPatchFlag
moveq #0,d5 ;BIN # (0=impossible)
move.l FstBinPtr,a6
move.l BIN_start(a6),d6
moveq #0,d4 ;MOD # (0=impossible)
suba.l a4,a4
.nxtHEAD: move.l d0,a2
move.l HEAD_start(a2),a3
move.w HEAD_nb(a2),d3
subq.w #1,d3
bmi .end ;peut arriver
clr.w HEAD_nb(a2)
.nxtEXP: cmp.w EXP_mod(a3),d4
bne .newmod
.samemod: move.l EXP_start(a3),a0
add.l a4,a0 ;MOD start
moveq #0,d0
move.b EXP_len(a3),d0
lea 0(a0,d0.w),a1
move.b (a1),d7
SETEOL (a1)
move.b EXP_eval(a3),d0
bsr LocEval
beq.s .patch ;no reloc
bmi.s .reval
move.b d7,(a1)
subq.b #EVAL_RELOC,d1 ;reloc+(loc-glob/glob-loc) ?
bne .updateghost ;EVAL_LOCGLO ou EVAL_RELOC+EVAL_LOCGLO
.noghost: move.w EXP_patch(a3),a0 ;patch d'1 expr possiblement relogeable
move.w .tab(pc,a0.w),a0 ;deja *2
jmp .tab(pc,a0.w)
.reval: bra ._erreval
.reloc: move.l EXP_dupliq(a3),a0 ;reloc & patch
move.w CurSection,d1
addq.b #1,d1
move.b d1,EXP_sec(a0)
addq.l #1,LocRelNb
bra.s .dup
.patch: move.b d7,(a1)
move.l EXP_dupliq(a3),d2
beq.s .nodup
move.l d2,a0
.dup: clr.b EXP_len(a0) ;for ghost
.nodup: cmp.w EXP_bin(a3),d5
bne.s .newbin
.samebin: move.l d6,a0 ;bin start
add.w EXP_poke(a3),a0 ;patch addr
move.w EXP_patch(a3),d1
moveq #SEC_text+1,d7
bsr patch ;d0=value
.next: lea EXP_LOC_SIZEOF(a3),a3
dbf d3,.nxtEXP
move.l HEAD_next(a2),d0
bne .nxtHEAD
.end: sf LocPatchFlag
movem.l (sp)+,d0-a6
rts
.newbin: move.w d5,d1
move.w EXP_bin(a3),d5
sub.w d5,d1
IFNE BLINDOS
bpl.s .prevbin
ENDC
.l2: move.l BIN_next(a6),a6
addq.w #1,d1
bne.s .l2
move.l BIN_start(a6),d6
bra.s .samebin
;en local patch on doit pas pouvoir reculer d'1 buffer binaire
IFNE BLINDOS
.prevbin: _Debugger
ENDC
.tab: dc.w .rrel-.tab ;P_W911
dc.w .rrel-.tab ;P_EA1
dc.w .rrel-.tab ;P_BIT8
dc.w .rrel-.tab ;P_BIT32
dc.w .rrel-.tab ;P_W07
dc.w .rrel-.tab ;P_W05
dc.w .rrel-.tab ;P_W610
dc.w .rrel-.tab ;P_W02
dc.w .rrel-.tab ;P_L02
dc.w .rrel-.tab ;P_L1012
dc.w .rrel-.tab ;P_W03
dc.w .rrel-.tab ;P_L06
dc.w .rrel-.tab ;P_K06
dc.w .rrel-.tab ;P_L57
dc.w .rrel-.tab ;P_FTRAPW
dc.w .rrel-.tab ;P_FTRAPL
dc.w .rrel-.tab ;P_D8
dc.w .rrel-.tab ;P_D16
dc.w .rrel-.tab ;P_ABSB
dc.w .rrel-.tab ;P_ABSW
dc.w .reloc-.tab ;P_ABSL
dc.w .rrel-.tab ;P_DCB
dc.w .rrel-.tab ;P_DCW
dc.w .reloc-.tab ;P_DCL
dc.w .patch-.tab ;P_D8PC
dc.w .patch-.tab ;P_D16PC
dc.w .patch-.tab ;P_DBCC
dc.w .patch-.tab ;P_BCCB
dc.w .patch-.tab ;P_BCCW
dc.w .patch-.tab ;P_BCCL
dc.w .patch-.tab ;P_BDPCW
dc.w .patch-.tab ;P_BDPCL
.newmod: move.w EXP_mod(a3),d4
bmi.s .macro
move.l FstModPtr,a4
move.w d4,d1
subq.w #2,d1
bmi.s .fstmod
.l3: move.l MOD_next(a4),a4
dbf d1,.l3
.fstmod: move.l MOD_addr(a4),a4
bra .samemod
.macro: suba.l a4,a4
bra .samemod
;Expression avec globales+locales et/ou relogeable
;d0=liste de valeurs locales
;a3=expr source
.updateghost:
tst.l d0
beq .reloc ;reloger mais pas reevaluer
.stloc: move.l EXP_dupliq(a3),d1
bne.s .do_dup
move.l d0,a0
move.l (a0),d0 ;recuperer la valeur
bra .noghost
.do_dup: move.l d1,a1 ;storer les locales pour globpatch
move.l EXP_backval(a1),d2 ;plantos ($ff)
beq.s .noset
move.l d2,a0
move.w (a0),d2
add.w d2,d2
move.w d2,d1
add.w d1,d1
add.w d2,d1 ;*6
addq.l #6,d0 ;skip @+set count
move.l d0,2(a0,d1.w)
bra.s .rel
.noset: move.l d0,EXP_backval(a1)
.rel: move.w CurSection,d1
addq.b #1,d1
move.b d1,EXP_sec(a1)
bra .next
.rrel: moveq #EVAL_NOREL,d1
; bra ._erreval
._erreval:
move.b d7,(a1)
move.l EXP_dupliq(a3),d0
beq.s .do_err
move.l d0,a1
clr.b EXP_len(a1) ;ne pas globalpatcher si erreur !
.do_err: bsr patpeval
tst.b StopFlg
beq .next
bra .end
; #] LocalPatch:
; #[ GlobalPatch:
;d3:# EXP
;d4:# MOD
;d5:# BIN
;d6:BIN start
;d7:last char
;a2:@ HEAD
;a3:@ EXP
;a4:MOD start
;a5:pas touche
;a6:@ BIN
GlobalPatch:
movem.l d0-a6,-(sp)
move.l HeadExp,d0
beq .ok
st GlobPatchFlag
moveq #0,d5
move.l FstBinPtr,a6
move.l BIN_start(a6),d6
moveq #0,d4 ;MOD # (0=impossible)
move.w d4,CurModule
.nxblock: move.l d0,a2
move.l HEAD_start(a2),a3
move.w HEAD_nb(a2),d3
subq.w #1,d3
bmi .end
.nxtEXP: move.w EXP_sec(a3),d0 ;sec+size
andi.w #$ff,d0 ;viros section
beq .locrel ;fantome pour la reloc
cmp.w EXP_mod(a3),d4
bne .newmod
.samemod: move.l EXP_start(a3),a0
add.l a4,a0 ;MOD start
lea 0(a0,d0.w),a1
move.b (a1),d7
SETEOL (a1)
; move.l EXP_backval(a3),d1
move.b EXP_eval(a3),d0
bsr GloEval ;utilise a3
bmi.s .reval
move.b d7,(a1)
move.l d1,-(sp) ;sauve d1
btst #8,d1 ;local with reloc
sne EXP_backval(a3)
beq.s .noloc
addq.l #1,LocRelNb
.noloc: swap d1
move.w d1,d7 ;var #
move.b d2,d1 ;sign
swap d1
cmp.w EXP_bin(a3),d5
bne .newbin
.samebin: move.b d1,EXP_sec(a3) ;reloc->section+1,(ff if undef)
bmi .xref
.patch: lea .t(pc),a0
move.w EXP_patch(a3),d2
move.w 0(a0,d2.w),d2
jmp 0(a0,d2.w)
.next: move.l (sp)+,EXP_varnb(a3) ;var #|00|(section+1 ou ff if undef)
.next2: lea EXP_SIZEOF(a3),a3
dbf d3,.nxtEXP
move.l HEAD_next(a2),d0
bne .nxblock
move.w CurModule,d0
beq.s .ok
bsr free_module
.ok: moveq #0,d0
.end: sf GlobPatchFlag
movem.l (sp)+,d0-a6
rts
;reference relogeable a un local - pas d'evaluation
.locrel: st EXP_backval(a3)
IFNE AMIGA
bsr store_reloc
ENDC
bra.s .next2
;erreur d'eval
.reval: move.b d7,(a1)
bsr patpeval
tst.b StopFlg
beq.s .next2
bra.s .end
.newmod: tst.w SlowFlg
bne.s .slow
move.w EXP_mod(a3),d4
bmi.s .macro
move.l FstModPtr,a4
move.w d4,d1
subq.w #2,d1
bmi.s .fstmod
.l3: move.l MOD_next(a4),a4
dbf d1,.l3
.fstmod: move.l MOD_addr(a4),a4
bra .samemod
.macro: suba.l a4,a4
bra .samemod
.slow: bsr slow_getmod
bra .samemod
.newbin: move.w d5,d2
move.w EXP_bin(a3),d5
sub.w d5,d2
bpl.s .binprev
.l2: move.l BIN_next(a6),a6
addq.w #1,d2
bne.s .l2
move.l BIN_start(a6),d6
bra .samebin
.binprev: move.l BIN_prev(a6),a6
subq.w #1,d2
bne.s .binprev
move.l BIN_start(a6),d6
bra .samebin
; #[ check xref:
.xref: move.w EXP_patch(a3),a1
IFNE BLINDOS
cmp.w #P_MAX,a1
bhi.s .bug
ENDC ;BLINDOS