-
Notifications
You must be signed in to change notification settings - Fork 2
/
arduino-noise-meter.ino
599 lines (476 loc) · 19.1 KB
/
arduino-noise-meter.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
/*
* Copyright 2015 David Valeri
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
#define UNSIGNED_LONG_MAX 4294967295
// Define clear bit macro. Operates on a Special Registry Flag (SFR) and
// a bit offset in the SRF.
#ifndef cbi
#define cbi(sfr, bit) (_SFR_BYTE(sfr) &= ~_BV(bit))
#endif
// Define set bit macro. Operates on a Special Registry Flag (SFR) and
// a bit offset in the SRF.
#ifndef sbi
#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))
#endif
// Config FFT ////////////////////////////////////////
// Configure FFT
// See http://wiki.openmusiclabs.com/wiki/Defines
#define LOG_OUT 1
#define FFT_N 256
#include <FFT.h>
#include <ApplicationMonitor.h>
Watchdog::CApplicationMonitor ApplicationMonitor;
// Application Constants /////////////////////////////
// The time, in milliseconds, for which a sample is averaged into the calculated
// smoothed level when the current sample is higher than the smoothed average.
const unsigned long RISING_LEVEL_W = 2500;
// The time, in milliseconds, for which a sample is averaged into the calculated
// smoothed level when the current sample is lower than the smoothed average.
const unsigned long FALLING_LEVEL_W = 5000;
// Used internally to detect when a full set of samples have been collected for FFT analysis.
const unsigned int FFT_SAMPLE_COUNTER_THRESHOLD = FFT_N * 2;
// Used internally to detect when a full set of samples have been collected for adjuster evaluation.
const unsigned int ADJUST_SAMPLE_COUNTER_THRESHOLD = 5;
const unsigned int FFT_OUTPUT_BINS = FFT_N / 2;
// Index into RELAY_PINS to control the light of the corresponding color.
const int GREEN = 0;
const int YELLOW = 1;
const int RED = 2;
// The digital IO pin numbers used by the relay board.
const int RELAY_PINS[] = { 2, 7, 8 };
// A flag indicating if blink modes should be enabled or represented as
// a solid indicator.
const bool BLINK_ENABLED = true;
// The interval, in milliseconds, that the display level is evaluated for
// a change that impacts the displayed state when in a blinking state
// in the display is illuminated.
const unsigned long BLINK_ILLUMINATED_LEVEL_UPDATE_INTERVAL = 750;
// The interval, in milliseconds, that the display level is evaluated for
// a change that impacts the displayed state when in a blinking state
// and the display is not illuminated.
const unsigned long BLINK_EXTINGUISHED_LEVEL_UPDATE_INTERVAL = 1000
- BLINK_ILLUMINATED_LEVEL_UPDATE_INTERVAL;
// The OK display level.
const byte OK_LEVEL = 0;
// The INFO display level.
const byte INFO_LEVEL = 1;
// The WARN display level.
const byte WARN_LEVEL = 2;
// The WARN PLUS display level.
const byte WARN_PLUS_LEVEL = 3;
// The STFU DAVE display level.
const byte STFU_DAVE_LEVEL = 4;
const byte INPUT_SOURCE_LEVEL = 0;
const byte INPUT_SOURCE_ADJUSTER = 1;
const byte INPUT_SWITCH_SAMPLES_TO_IGNORE = 2;
const int THRESHOLD_DELTA = 100;
const int THRESHOLD_RELEASE_DELTA = 75;
const unsigned int DEFAULT_THRESHOLD = 10000;
//////////////////////////////////////////////////////
// The moving average of the input level.
volatile float smoothedLevel = 0;
// The current adjuster level reading.
volatile int adjusterLevel = 0;
// Current sample counter index.
unsigned short sampleCounter = 0;
byte fftCounter = 0;
// The last time, in millis since starup, that the input level was evaluated.
unsigned long previousSampleUpdateMillis = 0;
// A flag indicating if the next ADC result should be ignored. Used to ignore
// indeterminate results since we don't concern ourselves with timing when switching
// the ADC MUX.
volatile boolean ignoreConversion = false;
// The current input source for the ADC. Used to determine what we are currently
// taking readings for.
volatile byte inputSource = INPUT_SOURCE_ADJUSTER;
// The current display level.
byte displayLevel = OK_LEVEL;
// The last time, in milliseconds since starup, that the display level was evaluated.
unsigned long previousDisplayLevelUpdateMillis = 0;
// The time, in milliseconds, at which the display level will next be evaluated.
unsigned long displayLevelUpdateInterval = 0;
volatile unsigned int infoThreshold = DEFAULT_THRESHOLD;
volatile unsigned int infoReleaseThreshold = DEFAULT_THRESHOLD;
volatile unsigned int warnThreshold = DEFAULT_THRESHOLD;
volatile unsigned int warnReleaseThreshold = DEFAULT_THRESHOLD;
volatile unsigned int warnPlusThreshold = DEFAULT_THRESHOLD;
volatile unsigned int warnPlusReleaseThreshold = DEFAULT_THRESHOLD;
volatile unsigned int stfuDaveThreshold = DEFAULT_THRESHOLD;
volatile unsigned int stfuDaveReleaseThreshold = DEFAULT_THRESHOLD;
void setup() {
// Initialize the serial port so we can have debug logging.
Serial.begin(115200);
// Set the digital IO pins to output mode for the relay board control pins and
// make sure everything is dark.
for (int i = 0; i < 3; i++) {
pinMode(RELAY_PINS[i], OUTPUT);
digitalWrite(RELAY_PINS[i], LOW);
}
Serial.println(F(""));
ApplicationMonitor.Dump(Serial);
ApplicationMonitor.EnableWatchdog(Watchdog::CApplicationMonitor::Timeout_120ms);
initAdc();
cli();
Serial.println(F("############################ Initialized ############################"));
sei();
}
void loop() {
unsigned long currentMillis = millis();
ApplicationMonitor.IAmAlive();
ApplicationMonitor.SetData(currentMillis);
// Calculate the new display state //////////////////////////
byte newDisplayLevel = displayLevel;
// We must ensure that we are atomically reading in the values that we compare
// against since they are written in the ISR and read here. We don't want to
// read a half written value so we ensure that we don't allow the interrupt to fire
// while reading the values.
cli();
float currentSmoothedLevel = smoothedLevel;
int currentInfoThreshold = infoThreshold;
int currentInfoReleaseThreshold = infoReleaseThreshold;
int currentWarnThreshold = warnThreshold;
int currentWarnReleaseThreshold = warnReleaseThreshold;
int currentWarnPlusThreshold = warnPlusThreshold;
int currentWarnPlusReleaseThreshold = warnPlusReleaseThreshold;
int currentStfuDaveThreshold = stfuDaveThreshold;
int currentStfuDaveReleaseThreshold = stfuDaveReleaseThreshold;
sei();
if (currentSmoothedLevel > currentStfuDaveThreshold) {
newDisplayLevel = STFU_DAVE_LEVEL;
} else if (currentSmoothedLevel > currentWarnPlusThreshold) {
// Add a little historesis.
if (displayLevel < WARN_PLUS_LEVEL
|| (displayLevel > WARN_PLUS_LEVEL && currentSmoothedLevel < currentStfuDaveReleaseThreshold)) {
newDisplayLevel = WARN_PLUS_LEVEL;
}
} else if (currentSmoothedLevel > currentWarnThreshold) {
// Add a little historesis.
if (displayLevel < WARN_LEVEL
|| (displayLevel > WARN_LEVEL && currentSmoothedLevel < currentWarnPlusReleaseThreshold)) {
newDisplayLevel = WARN_LEVEL;
}
} else if (currentSmoothedLevel > currentInfoThreshold) {
// Add a little historesis.
if (displayLevel < INFO_LEVEL
|| (displayLevel > INFO_LEVEL && currentSmoothedLevel < currentWarnReleaseThreshold)) {
newDisplayLevel = INFO_LEVEL;
}
} else if (currentSmoothedLevel < currentInfoReleaseThreshold) {
newDisplayLevel = OK_LEVEL;
}
if (newDisplayLevel != displayLevel) {
displayLevel = newDisplayLevel;
// If we are in a blinking state, don't immediately update the display
// because the user then sometimes sees a flicker or a truncated
// blink cycle during the transition.
if (displayLevelUpdateInterval == UNSIGNED_LONG_MAX) {
displayLevelUpdateInterval = 0;
}
cli();
Serial.print(F("Chose new display level: "));
Serial.println(displayLevel);
sei();
}
// Drive the display as needed /////////////////////////////////
if (currentMillis - previousDisplayLevelUpdateMillis > displayLevelUpdateInterval) {
previousDisplayLevelUpdateMillis = currentMillis;
// Perhaps no need to check again until the display level changes.
displayLevelUpdateInterval = UNSIGNED_LONG_MAX;
switch (displayLevel) {
default:
case OK_LEVEL:
turnOtherLightsOff(GREEN);
turnLightOn(GREEN);
break;
case INFO_LEVEL:
turnOtherLightsOff(YELLOW);
if (BLINK_ENABLED) {
displayLevelUpdateInterval = toggleLight(YELLOW);
} else {
turnLightOn(YELLOW);
}
break;
case WARN_LEVEL:
turnOtherLightsOff(YELLOW);
turnLightOn(YELLOW);
break;
case WARN_PLUS_LEVEL:
turnOtherLightsOff(RED);
if (BLINK_ENABLED) {
displayLevelUpdateInterval = toggleLight(RED);
} else {
turnLightOn(RED);
}
break;
case STFU_DAVE_LEVEL:
turnOtherLightsOff(RED);
turnLightOn(RED);
break;
}
cli();
Serial.print(F("Next display update in: "));
Serial.println(displayLevelUpdateInterval);
Serial.print(F("Current level: "));
Serial.println(currentSmoothedLevel);
sei();
}
}
/**
* Interrupt handler for ADC sample ready.
*/
ISR(ADC_vect) {
unsigned long currentMillis = millis();
// Read low to high per the atomic access control rules for the ADC. Reading ADCL locks these
// registers while reading ADCH releases these registers to the ADC again for writing.
byte sampleLowByte = ADCL;
byte sampleHighByte = ADCH;
int sample = (sampleHighByte << 8) | sampleLowByte;
if (!ignoreConversion) {
if (inputSource == INPUT_SOURCE_ADJUSTER) {
// Now massage the sample into a format that we can shove into the FFT input and calculate
// an arithmatic mean on when we have enough samples.
fft_input[sampleCounter] = sample;
sampleCounter += 1;
if (sampleCounter == ADJUST_SAMPLE_COUNTER_THRESHOLD) {
int sum = 0;
for (int i = 0; i < ADJUST_SAMPLE_COUNTER_THRESHOLD; i++) {
sum += fft_input[i];
}
int newAdjusterLevel = sum / ADJUST_SAMPLE_COUNTER_THRESHOLD;
// Docs on abs say to not do maths inside of the brackets so assign this
// to an intermediate value. http://www.arduino.cc/en/Reference/Abs
int delta = newAdjusterLevel - adjusterLevel;
if (abs(delta) > 2)
{
adjusterLevel = newAdjusterLevel;
int mappedAdjusterLevel = map(adjusterLevel, 0, 1024, 0, 512);
infoThreshold = 2000 + mappedAdjusterLevel;
infoReleaseThreshold = infoThreshold - (THRESHOLD_RELEASE_DELTA * 0.75);
warnThreshold = infoThreshold + THRESHOLD_DELTA;
warnReleaseThreshold = warnThreshold - THRESHOLD_RELEASE_DELTA;
warnPlusThreshold = warnThreshold + THRESHOLD_DELTA;
warnPlusReleaseThreshold = warnPlusThreshold - THRESHOLD_RELEASE_DELTA;
stfuDaveThreshold = warnPlusThreshold + THRESHOLD_DELTA;
stfuDaveReleaseThreshold = stfuDaveThreshold - THRESHOLD_RELEASE_DELTA;
// Bring the smoothed average up to baseline quickly.
if (smoothedLevel == 0.0) {
smoothedLevel = infoThreshold - THRESHOLD_DELTA;
}
Serial.print(F("Set baseline threshold: "));
Serial.println(infoThreshold);
}
sampleCounter = 0;
setAdcInput(INPUT_SOURCE_LEVEL);
}
} else if (inputSource == INPUT_SOURCE_LEVEL) {
// Now massage the sample into the format that FFT wants it in.
// Shift sample down by DC bias (1024 / 2 in ADC speak).
sample -= 0x0200;
// Slide the sample left the remaining 6 bits to fill the 16b int with our
// 10b sample
sample <<= 6;
// This bin is the real part bin. It gets the converted sample value.
fft_input[sampleCounter] = sample;
// This bin is the imaginary part bin. It gets 0s, always.
fft_input[sampleCounter + 1] = 0;
// Don't forget to skip 2 at a time since we fill two indexes in the
// array per sample.
sampleCounter += 2;
if (sampleCounter == FFT_SAMPLE_COUNTER_THRESHOLD) {
// Do the FFT
fft_window();
fft_reorder();
fft_run();
fft_mag_log();
// CPU_CLOCK / ADC_PRESCALER / CYCLES_PER_SAMPLE / FHT_N
//
// Fs = 16MHz / 32 / 13 = ~38KHz
// Df = Fs / 256 = 150Hz bandwidth per bin
//
// We have 128 bins each 150Hz wide for a total range of ~19KHz.
//
int magnitude = 0;
for (int i = 1; i < FFT_OUTPUT_BINS; i++) {
magnitude += fft_log_out[i];
}
// Uncomment to send binary FFT data out the serial line for use in Pd
// Serial.write(255);
// Serial.write(fft_log_out, 128);
// Now we are going to adjust the running smoothed value. We use different smoothing
// factors for increases and decreases so that we are less sensitive to dropping volume levels
// than we are to rising levels.
//
// Math is happening here...
// http://en.wikipedia.org/wiki/Low-pass_filter#Simple_infinite_impulse_response_filter
// http://en.wikipedia.org/wiki/Moving_average#Exponential_moving_average
// http://en.wikipedia.org/wiki/Moving_average#Application_to_measuring_computer_performance
if (smoothedLevel < magnitude) {
smoothedLevel = smoothedLevel + alpha(currentMillis, previousSampleUpdateMillis, RISING_LEVEL_W)
* (magnitude - smoothedLevel);
} else {
smoothedLevel = smoothedLevel + alpha(currentMillis, previousSampleUpdateMillis, FALLING_LEVEL_W)
* (magnitude - smoothedLevel);
}
previousSampleUpdateMillis = currentMillis;
sampleCounter = 0;
fftCounter += 1;
// 38KHz / 256 samples per FFT ~= 150 FFTs per second
if (fftCounter == 10) {
fftCounter = 0;
setAdcInput(INPUT_SOURCE_ADJUSTER);
}
}
}
} else {
sampleCounter += 1;
// We need to skip more than just the first sample as it seems that two samples
// can be inaccurate after switching the mux. Probably related to timing and/or
// impedence. We'll live with it.
if (sampleCounter == INPUT_SWITCH_SAMPLES_TO_IGNORE) {
ignoreConversion = false;
sampleCounter = 0;
}
}
}
void turnLightOn(byte light) {
digitalWrite(RELAY_PINS[light], HIGH);
}
void turnLightOff(byte light) {
digitalWrite(RELAY_PINS[light], LOW);
}
void turnOtherLightsOff(byte light) {
for (int i = 0; i < 3; i++) {
if (i != light) {
digitalWrite(RELAY_PINS[i], LOW);
}
}
}
unsigned long toggleLight(byte light) {
if (digitalRead(RELAY_PINS[light])) {
digitalWrite(RELAY_PINS[light], 0);
return BLINK_EXTINGUISHED_LEVEL_UPDATE_INTERVAL;
} else {
digitalWrite(RELAY_PINS[light], 1);
return BLINK_ILLUMINATED_LEVEL_UPDATE_INTERVAL;
}
}
float alpha(unsigned long currentTimeMillis, unsigned long lastSampleTimeMillis, unsigned long readingWindow) {
// Per http://en.wikipedia.org/wiki/Moving_average#Application_to_measuring_computer_performance
return 1.00 - pow(2.71828182845904523536, -1.00
* (((currentTimeMillis - lastSampleTimeMillis)) / (float) readingWindow));
}
/**
* Initializes the ADC system.
*/
void initAdc() {
// Turn off global interrupts.
cli();
// ADC Setup ///////////////////
// Disable digital input buffer on ADC pins to reduce noise.
// See section 24.9.5 of the AVR238P datasheet.
sbi(DIDR0,ADC0D);
sbi(DIDR0,ADC1D);
sbi(DIDR0,ADC2D);
sbi(DIDR0,ADC3D);
sbi(DIDR0,ADC4D);
sbi(DIDR0,ADC5D);
// ADCSRA /////////////
// 1 1 1 0 1 1 0 1
//
// 7 6 5 4 3 2 1 0
// A A A A A A A A
// D D D D D D D D
// E S A I I P P P
// N C T F E S S S
// E 2 1 0
// Turn on the ADC.
// See section 24.9.2 of the AVR238P datasheet.
sbi(ADCSRA, ADEN);
sbi(ADCSRA, ADSC);
// Set the ADC to auto-trigger based on the ADTS bits of the ADCSRV SRF. This enables
// us to choose free-run mode rather than single conversion mode for sampling.
// See sections 24.3 and 24.9.2 of the AVR238P datasheet.
sbi(ADCSRA, ADATE);
// Enable the ADC Conversion Complete Interrupt on conversion completion. Note this is only
// effective if the I bit of the SREG (global interrupt enable) is also enabled.
// See sections 24.9.2 of the AVR238P datasheet.
sbi(ADCSRA, ADIE);
// Set the ADC prescaler select bits to increase the ADC speed. A division factor
// of 32 is chosen to take us to a ADC clock of 500KHz. We lose a fraction of a bit of
// accuracy but get a theoretical effective sampling rate of 38.5 KHz. More than enough
// to capture the frequency range of sounds that we are interested in. There is a drop
// in effective bits in the conversion, although not significant per the datasheet.
// Emperical data from other sources indicate that the drop in effective bits is on the
// order of magnitude of < 0.5 bits; however, it crosses the half bit mark between 9 and
// 10 bits, thus effectively removing an entire effective bit. We will just ignore this
// and use all 10 bits as it does seem to cut down on the noise in the lower frequency bands.
// See sections 24.9.2 of the AVR238P datasheet.
sbi(ADCSRA, ADPS2);
cbi(ADCSRA, ADPS1);
sbi(ADCSRA, ADPS0);
// ADCSRB /////////////
// 0 0 0 0 0 0 0 0
//
// 7 6 5 4 3 2 1 0
// A A A
// D D D
// T T T
// S S S
// 2 1 0
// Set the ADC Auto Trigger Source to be free running mode. The ADC will perform conversions
// continuosly while ADSC of ADCSRA is high and ADC is enabled.
// See section 24.9.4 of the AVR238P datasheet.
cbi(ADCSRB, ADTS2);
cbi(ADCSRB, ADTS1);
cbi(ADCSRB, ADTS0);
// ADMUX ////////////
// See section 24.9.1 of the AVR238P datasheet.
// 0 0 0 0 0 0 0 0
// R R A M M M M
// E E D U U U U
// F F L X X X X
// S S A 3 2 1 0
// 1 0 R
// Set an external reference voltage.
cbi(ADMUX, REFS1);
cbi(ADMUX, REFS0);
// Set the results of a conversion to be left-aligned, MSBs appear in ADCH.
// See sections 24.2 and 24.9.1 of the AVR238P datasheet.
cbi(ADMUX, ADLAR);
// Set the input source for the ADC.
setAdcInput(INPUT_SOURCE_ADJUSTER);
// Turn on global interrupts.
sei();
}
void setAdcInput(byte input) {
ignoreConversion = true;
inputSource = input;
switch (input) {
case INPUT_SOURCE_LEVEL:
// Set ADC0 as the input channel in the ADC muxer.
cbi(ADMUX, MUX3);
cbi(ADMUX, MUX2);
cbi(ADMUX, MUX1);
cbi(ADMUX, MUX0);
break;
case INPUT_SOURCE_ADJUSTER:
// Set ADC5 as the input channel in the ADC muxer.
cbi(ADMUX, MUX3);
sbi(ADMUX, MUX2);
cbi(ADMUX, MUX1);
sbi(ADMUX, MUX0);
break;
}
}