RP2040 with ST7789 240x320 display slow refresh using pushSprite() (220ms)

[mantisrobot]

Hi, this is my setup:

RP2040 CANbed board with 2" 240x320 ST7789 display attached. I am using a TFT_eSprite image to write to then pushing the whole image to the display. my clock settings are:

#define SPI_FREQUENCY 40000000
#define SPI_READ_FREQUENCY 20000000
#define SPI_TOUCH_FREQUENCY 2500000

This is working fine but it takes about 220ms to refresh the display, does this seem right? I was expecting a faster refresh rate than this. I have tried defining the PIO mode but this makes no difference to pushSprite() speed.

Any advise apperciated.

[Bodmer]

Pushing the sprite should be fast (circa 35ms). So the delay is probably due to the complexity of the graphics being drawn, maybe font loading etc.

[mantisrobot]

Thanks for the reply.

Yes that's about what I've calculated. Yet doing a simple program simply filling the sprite with black or white it takes about 200ms + to push to the display.

I set up a really simple test:

#include <TFT_eSPI.h> 

// the setup function runs once when you press reset or power the board
void setup() {
  // initialize digital pin LED_BUILTIN as an output.
  pinMode(LED_PIN, OUTPUT);

  Serial.begin(115200);
  while(!Serial);

  tft.begin();
  tft.fillScreen(TFT_BLACK);    
  tft.setCursor(0, 4, 4);
  tft.setTextColor(TFT_WHITE);
  tft.println("TFT Test");
  sprt.setColorDepth(8);
  sprt.createSprite(TFT_WIDTH,TFT_HEIGHT);
}

// the loop function runs over and over again forever
int flipBit = 0;
void loop() {
  if( flipBit ) sprt.fillScreen(TFT_WHITE);
  else sprt.fillScreen(TFT_BLACK); 

  long start = millis();
  sprt.pushSprite(0,0,TFT_TRANSPARENT);
  Serial.printf("Execution Time = %lu mS\r\n",millis()-start);

  flipBit ^= 1;
  digitalWrite(LED_PIN, !digitalRead(LED_PIN));  // turn the LED on (HIGH is the voltage level)
}

which outputs:

08:57:27.409 -> Execution Time = 214 mS
08:57:27.610 -> Execution Time = 214 mS
08:57:27.828 -> Execution Time = 214 mS
08:57:28.044 -> Execution Time = 215 mS
08:57:28.263 -> Execution Time = 215 mS
08:57:28.479 -> Execution Time = 214 mS

I'll stick a signal analyser on the SPI bus and see if I can tell what's happening.

[mantisrobot]

Here are some capture from my Logic device:

This is a full pushSprite capture with a white sprite 320x240

There are bunches of writes followed by approx 100uS pause.

And closer up, each write is 520nS with a pause 2.5uS

[Bodmer]

There is no fillScreen function for sprites, use fillSprite. Due to class inheritance the screen will be cleared instead, thus the screen will be updated twice per loop in the above sketch. This should be noticeable in the logic analyser output.

Using an 8 bit sprite will be slower as every 8 bit pixel has to be converted to 16 bits and checked to see if is a transparent colour.

Running the cpu at 133MHz automatically reduces the maximum SPI rate to 24MHz, see here. Running at 125MHz cpu clock may increase render speed.

Run the Read_User_Setup sketch to check the SPI frequency set in the users setup file, note that that is not necessarily the frequency implemented as noted in link above. Also valid SPI clock rates are integer divisions of the cpu frequency, so at 125MHz cpu clock a setting of 40MHz in the setup file actually ends up being 32.25MHz.

[mantisrobot]

Hi,

Yes sorry when I wrote my test example I missed the fillScreen / fillSprite issue, I had not been using this in my full code though. However I have re-written the test code and there is no change to refresh rate.

I can confirm I'm running at 125Mhz, I had read the post about clock speed on the RP2040. I have run the test with a 16bit colour depth but still no change in refresh rate.

I'm sure I had it running quite fast at one point then noticed it had slowed right down. I have re-installed the lib fresh just to make sure I hadn't tweaked a setting but still can't figure this out. enabling PIO mode makes no difference.

// the loop function runs over and over again forever
int flipBit = 1;
void loop() 
{

  if( flipBit ) sprt.fillSprite(TFT_WHITE);
  else sprt.fillSprite(TFT_BLACK); 

  long start = millis();
  sprt.pushSprite(0,0,TFT_TRANSPARENT);
  Serial.printf("Execution Time = %lu mS\r\n",millis()-start);

  flipBit ^= 1;
  digitalWrite(LED_PIN, !digitalRead(LED_PIN));  // turn the LED on (HIGH is the voltage level)

}

12:06:22.557 -> Execution Time = 210 mS
12:06:22.743 -> Execution Time = 210 mS
12:06:22.978 -> Execution Time = 210 mS

[mantisrobot]

For simplicity I took the sprite out of the code and I'm just using fillScreen now. So this is taking about 172mS which still seems way off the predicted 35mS

// the loop function runs over and over again forever
int flipBit = 1;
void loop() 
{

  long start = millis();
  if( flipBit ) tft.fillScreen(TFT_WHITE);
  else tft.fillScreen(TFT_BLACK); 
  Serial.printf("Execution Time = %lu mS\r\n",millis()-start);

  flipBit ^= 1;
  digitalWrite(LED_PIN, !digitalRead(LED_PIN));  // turn the LED on (HIGH is the voltage level)

}

12:18:15.577 -> Execution Time = 172 mS
12:18:15.748 -> Execution Time = 172 mS
12:18:15.921 -> Execution Time = 172 mS

[mantisrobot]

This is my user config file:

// CANBed (RP2040) (Waveshare ST7789 on SPI bus with 240x240 TFT)
#define USER_SETUP_ID 138

#define ST7789_DRIVER     // Configure all registers
//#define RP2040_PIO_SPI // Leave commented out to use standard RP2040 SPI port interface

#define TFT_WIDTH  240
#define TFT_HEIGHT 320

#define CGRAM_OFFSET      // Library will add offsets required

// For Pico Explorer Base (PR2040)
#define TFT_CS 		24   // Chip Select pin
#define TFT_DC 		23   // Data Command control pin 
#define TFT_RST 	22  // No Reset pin
#define TFT_MOSI 	3
#define TFT_SCLK 	2
#undef TFT_MISO

#define TFT_BL   21            // LED back-light control pin
#define TFT_BACKLIGHT_ON HIGH  // Level to turn ON back-light (HIGH or LOW)


#define LOAD_GLCD   // Font 1. Original Adafruit 8 pixel font needs ~1820 bytes in FLASH
#define LOAD_FONT2  // Font 2. Small 16 pixel high font, needs ~3534 bytes in FLASH, 96 characters
#define LOAD_FONT4  // Font 4. Medium 26 pixel high font, needs ~5848 bytes in FLASH, 96 characters
#define LOAD_FONT6  // Font 6. Large 48 pixel font, needs ~2666 bytes in FLASH, only characters 1234567890:-.apm
#define LOAD_FONT7  // Font 7. 7 segment 48 pixel font, needs ~2438 bytes in FLASH, only characters 1234567890:.
#define LOAD_FONT8  // Font 8. Large 75 pixel font needs ~3256 bytes in FLASH, only characters 1234567890:-.
// #define LOAD_FONT8N // Font 8. Alternative to Font 8 above, slightly narrower, so 3 digits fit a 160 pixel TFT
#define LOAD_GFXFF  // FreeFonts. Include access to the 48 Adafruit_GFX free fonts FF1 to FF48 and custom fonts

#define SMOOTH_FONT

#define SPI_FREQUENCY       40000000
#define SPI_READ_FREQUENCY  20000000
#define SPI_TOUCH_FREQUENCY  2500000

[mantisrobot]

Going back to my SPI timings:

As seen from the transfer in this image when the clock is active it takes about 514nS
So 320250514nS would be about 39mS in line with predictions.

However you can see the delay after each write which is more like 2.214uS per transfer
So 3202402.214uS would be about 170mS which is what I'm getting.

So the low frame rate is down to this delay.. whatever that may be?

[mantisrobot]

OK, I have solved the issue which is board related.

As stated at the top I'm using the Longan RP2040 CANBed board, and after doing some digging around in the TDT_eSPI header files I noticed that the board was using the TFT_eSPI_Generic.h files!

So it seems the Longan boards.txt does not define the architecture ARDUINO_ARCH_RP2040 and thus the faster SPI routines were not being used! It does define ARDUINO_RASPBERRY_PI_PICO so I'm using that to force architecture at the top of the TFT_eSPI.h header, using:

 ****************************************************/
#ifdef ARDUINO_RASPBERRY_PI_PICO
#define ARDUINO_ARCH_RP2040
#endif

I'm now getting tft.fillScreen() in about 40mS

I added the following to the TFT_eSPI.h header as a warning:

// Include the processor specific drivers
#if defined(CONFIG_IDF_TARGET_ESP32S3)
  #include "Processors/TFT_eSPI_ESP32_S3.h"
#elif defined(CONFIG_IDF_TARGET_ESP32C3)
  #include "Processors/TFT_eSPI_ESP32_C3.h"
#elif defined (ESP32)
  #include "Processors/TFT_eSPI_ESP32.h"
#elif defined (ARDUINO_ARCH_ESP8266)
  #include "Processors/TFT_eSPI_ESP8266.h"
#elif defined (STM32)
  #include "Processors/TFT_eSPI_STM32.h"
#elif defined(ARDUINO_ARCH_RP2040)
  #include "Processors/TFT_eSPI_RP2040.h"
#else

  #warning !!!!! GENERIC PROCESSOR USED !!!!!

  #include "Processors/TFT_eSPI_Generic.h"
  #define GENERIC_PROCESSOR
#endif