Backlight PWM help for those using ER-TFTM050-4 LCDs

[JimDrewGH]

So, after contacting East Rising (BUYDISPLAY.COM) with little help and some experimenting (referencing the chipset's datasheet), I finally figured out the mystery of using the built-in PWM driver for this particular display. The external pin that can be driven with PWM does not work properly! It is very sensitive to the frequency vs. duty cycle. I found if you drive the pin 39 (back light control pin) with a 1KHz PWM at anything other than max duty cycle, you get about 60% of the potential brightness. Having pin 39 of these displays as the back light input pin is very inconvenient because you really only need pins 1-16 to be able to have a functioning parallel display. Pins 17-40 are only needed if you want to use a 16 bit wide parallel path and/or the touch screen functions - AND the "BL_ON/OFF" pin 39. I really didn't like having to use a 2x20 cable for this display just to get the back light support, and it turns out that it doesn't work well - AND it is very noisy.

These SSD1963 based displays have an option to use LCD commands to setup and control a PWM signal generated internally to control the back light brighness. This lets you use a 16 pin cable (instead of a 40 pin version) and also gives you very good control of the back light brightness, as well as full brightness potential and with the EMI/RFI greatly reduced because its not going through a potentially long cable (like in my case). To setup the display so you can use the internal commands for control you need to change two jumpers - J3 and J4. By default, the displays come with J3 closed and J4 open. You need to reverse this so that J3 is open and J4 is closed. These are "solder bridge" jumpers. Once you make the change you will need some code in order to enable the back light and control its brightness. The display is kind of weird because it has the ability to ramp up/down the brightness using 3 different stored settings for energy conservation. Conservative seemed to work the best (least amount of flicker), but you can experiment.

Use is simple - just setup the display with 'SetupDisplay()'. This routine sets up the custom registers for the 480 x 272 display. I am sure with some small tweaks (timing registers) that this would also work for the ER-TFTM050-5 which is a 800x400 display. After setting up the display you can set the display brightness between 0 (OFF) and 100% (MAX) by calling 'SetBacklight(xx)'. There is no error checking done here. The actual max brightness is an 8 bit value with 255 being the brightest, but I wanted a percentage instead, which works well. I am also including code that I call FADE IN which ramps the brightness from the current brightness to whatever brightness you want. If the backlight is off (0) then this would fade in from off to some brightness level. There is also FADE OUT that ramps from the current brightness to OFF. These fades are programmed to be fast fade in/out which makes the appearance much nicer than a sudden on or off. You can adjust the prescaler to change the fade in/out speed. You can do things like clear your screen and setup new data while the backlight is off and then fade in to make it reappear. These displays do not handle tearing unless you monitor a pin and write special code just to handle it. I did that and the results were not so great, and I ended up just making these fade in/out routines and switching menu screens this way.

I hope someone finds this useful. Bodmer is welcome to use any/all of this code. I appreciate your hard work - thank you!

void SetupDisplay() {
  tft.init();                                           // init the TFT
  SetBacklight(0);                                      // backlight off
  uint8_t BLBrightness = 100;                           // 100% brightness
  tft.writecommand(0xD4);                               //set threshold for 3 transitions (conservative, normal, & agressive)
  tft.writedata(0x00);                                  // 480 * 272 * 3 * 0.1 / 16 
  tft.writedata(0x09);
  tft.writedata(0x90);
  tft.writedata(0x00);                                  // 480 * 272 * 3 * 0.25 / 16
  tft.writedata(0x17);
  tft.writedata(0xE8);
  tft.writedata(0x00);                                  // 480 * 272 * 3 * 0.6 / 16
  tft.writedata(0x39);
  tft.writedata(0x60);	

  tft.writecommand(0xD0);                               // set Dynamic Backlight Control (DBC)
  tft.writedata(0x25);                                  // transition effect enabled, conservative energy mode, DBC enabled
//  tft.writedata(0x29);                                  // transition effect enabled, normal energy mode, DBC enabled
//  tft.writedata(0x2d);                                  // transition effect enabled, aggressive energy mode, DBC enabled
//  tft.writedata(0x09);                                  // transition effect disabled, normal energy mode, DBC enabled
//  tft.writedata(0x05);                                  // transition effect disabled, conservative energy mode, DBC enabled
}

//----------------------------------------------------------------------------
// set PWM backlight - input value passed in is a percentage of 0 to 100 (OFF to full brightness)

void SetBacklight(uint8_t BLBrightness) {
  tft.writecommand(0xBE);                               // set PWM configuration
  tft.writedata(0x06);                                  // PWMF (0x06 is lib default)
  tft.writedata(0xF0);                                  // PWM  (0x80 is lib default)
  tft.writedata(0x09);                                  // PWM controlled by DBC, PWM enabled
  tft.writedata(BLBrightness * 2.55);                   // <<----- PWM brightness
  tft.writedata(0x00);                                  // minimum brightness (always use 0 so fades work)
  tft.writedata(0x00);                                  // prescaler used for transitions (ignored when not enabled in command 0xD0)
}

//----------------------------------------------------------------------------
// fade in backlight - fades in from current brightness to the value passed in

void DoFadeIn(uint8_t BLBrightness) {
  tft.writecommand(0xBE);                               // set PWM configuration
  tft.writedata(0x06);                                  // PWMF (0x06 is lib default)
  tft.writedata(0xF0);                                  // PWM  (0x80 is lib default)
  tft.writedata(0x09);                                  // PWM controlled by DBC, PWM enabled
  tft.writedata(BLBrightness * 2.55);                   // PWM brightness level
  tft.writedata(0x00);                                  // minimum brightness (always use 0 so fades work)
  tft.writedata(0x04);                                  // prescaler used for transitions (ignored when not enabled in command 0xD0)
}

//----------------------------------------------------------------------------
// fade out PWM backlight - fades out from current brightness to OFF

void DoFadeOut() {
  tft.writecommand(0xBE);                               // set PWM configuration
  tft.writedata(0x06);                                  // PWMF (0x06 is lib default)
  tft.writedata(0xF0);                                  // PWM  (0x80 is lib default)
  tft.writedata(0x09);                                  // PWM controlled by DBC, PWM enabled
  tft.writedata(0x00);                                  // PWM brightness - OFF
  tft.writedata(0x00);                                  // minimum brightness (always use 0 so fades work)
  tft.writedata(0x04);                                  // prescaler used for transitions (ignored when not enabled in command 0xD0)
}

[Bodmer]

Thanks for posting this.

[JimDrewGH]

I wanted to point out that the reason why I called SetBacklight(0) immediately after the tft.init() is because if you don't, the back light is going to come on briefly if you allow even a few milliseconds to go by before switching off the back light. What ends up happening is a brief bright flash of the display back light on power-up. Turning off the back light immediately prevents this irritating flash. :) It would be best really to have a new driver (or edit the existing one), where the back light is setup with it off. This won't hurt anything if you use the external pin to control the brightness (which I can't recommend).

[Rollmops67]

Hello !
Many thanks for this post, it solved my problem with an equivalent display, also from buydisplay.com :
https://www.buydisplay.com/lcd-5-inch-ips-ssd1963-tft-module-touch-screen-display-800x480-mcu-arduino

I had the same problem with a flickering backlight when driven trough pin 39 of the connector, and your post gave my the solution . (and motivation to understand)
Now I have a smooth changing and non flickering backlight .
So thank you again for the time you spent to find this out in the SSD1963's manual, it's usefull for others !

For those interested, here are the modified threshold commands for a 800x480 display :

tft.writecommand(0xD4);                     //set threshold command for 3 transitions (conservative, normal, & agressive)
  tft.writedata(0x00);                        // 800 * 480 * 3 * 0.1 / 16 en hexa 
  tft.writedata(0x23);
  tft.writedata(0x28);
  tft.writedata(0x00);                        // 800 * 480 * 3 * 0.25 / 16 en hexa
  tft.writedata(0x57);
  tft.writedata(0xE4);
  tft.writedata(0x00);                        // 800 * 480 * 3 * 0.6 / 16 en hexa
  tft.writedata(0xD2);
  tft.writedata(0xF0);  

Roland

[JimDrewGH]

Hey, I am glad this helped you! Thanks for the info on the 800x480 display parameters!